You cannot select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

750 lines
17 KiB
QBasic

10 REM DRUGWAR2EV103.BAS - 20/10/2018 - 20h50
20 REM DRUGWAR//E - VERSION 1.03
30 REM 20-OCT-2018
40 REM COPYRIGHT 2018 JAY MOORE
50 REM RELEASED UNDER GPL V3
60 REM DRUGWAR2E.SOURCEFORGE.IO
70 REM TWITTER: _NQ4T
80 RV=1.03
90 GOTO 6870
100 REM->TITLEBAR
110 HTAB 16 : PRINT "DRUGWAR//E"
120 INVERSE:PRINT" ":NORMAL
130 RETURN
140 REM->WAIT
150 PRINT CHR$(10)
160 INPUT "PRESS ENTER TO CONTINUE.";X$
170 RETURN
180 REM->TWOFIFTEEN
190 VTAB 2 : HTAB 15
200 RETURN
210 REM->TWOSIXTEEN
220 VTAB 2:HTAB 16
230 RETURN
240 REM->TWOSEVENTEEN
250 VTAB 2:HTAB 17
260 RETURN
270 REM->TWOEIGHTEEN
280 VTAB 2: HTAB 18
290 RETURN
300 REM->TWONINETEEN
310 VTAB 2:HTAB 19
320 RETURN
330 REM->JETALTHERE
340 INVERSE:GOSUB 310:PRINT"JET":NORMAL
350 RETURN
360 REM->TIMERA
370 FOR J = 1 TO 2500
380 NEXT J
390 K = INT(RND(2)+.5)
400 RETURN
410 REM->TIMERB
420 FOR J = 1 TO 1000
430 NEXT J
440 RETURN
450 REM->TIMERC
460 FOR J = 1 TO 2000
470 NEXT J
480 RETURN
490 REM->HOWMUCHBUY
500 PRINT "YOU CAN AFFORD ";J
510 PRINT "YOU CAN CARRY ";F
520 REM->HOWMANYBUY
530 PRINT CHR$(10)
540 INPUT "HOW MANY? (ENTER 0 CANCEL): ";K
550 IF K=0 GOTO 1160
560 IF K>F THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 530
570 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 530
580 RETURN
590 REM->HOWMUCHSELL
600 PRINT "YOU CAN SELL: ";J
610 PRINT CHR$(10)
620 REM->HOWMANYSELL
630 INPUT "HOW MANY? (ENTER 0 TO CANCEL.): ";K
640 IF K>J THEN PRINT "YOU DON'T HAVE THAT MANY!" : GOTO 630
650 IF K=0 GOTO 1160
660 RETURN
670 REM->FREESPACE
680 F=I-((G*5)+M+N+O+U+T+Q)
690 RETURN
700 REM->CHASE
710 INVERSE:GOSUB 190: PRINT"BEING CHASED":NORMAL
720 RETURN
730 REM->GMOD
740 SPEED=100:GOSUB 220:INVERSE:PRINT"GAME OVER":NORMAL:SPEED=255
750 RETURN
760 REM->BRONXCHECK
770 IF P$ = "THE BRONX" THEN RETURN
780 PRINT "YOU NEED TO HEAD TO THE BRONX"
790 PRINT "TO TAKE CARE OF THIS BUSINESS."
800 GOSUB 460
810 GOTO 1160
820 REM->DAILY
830 C=INT(RND(5)*12000+16000.5)
840 H=INT(RND(5)*7000+5000.5)
850 A=INT((RND(5)*34+10)*100+.5)
860 Z=INT((RND(5)*42+33)*10+.5)
870 S=INT((RND(5)*15+7)*10+.5)
880 L=INT((RND(5)*4+1)*10+.5)
890 B=INT(RND(5)*20+.5)
900 D=D+1
910 REM->CHECKDAY
920 IF D >= 31 GOTO 7220
930 RETURN
940 REM->SCORECALCULATE
950 K=(W+E)-V
960 IF K<0 THEN K=0 : RETURN
970 K=INT(SQR((K/31.5)+.5))
980 IF K>100 THEN K=100
990 RETURN
1000 REM->GAMESTART
1010 W=2000
1020 E=0
1030 V=5000
1040 P$="THE BRONX"
1050 G=0
1060 I=100
1070 M=0
1080 N=0
1090 O=0
1100 U=0
1110 T=0
1120 Q=0
1130 GOSUB 830
1140 GOTO 1160
1150 REM->MENU
1160 HOME
1170 GOSUB 680
1180 GOSUB 110
1190 INVERSE : VTAB 2:HTAB 4:PRINT "DAY: "D : VTAB 2:HTAB 18:PRINT"LOCATION: "P$ :NORMAL
1200 PRINT CHR$(10)
1210 PRINT "(C)HECK PRICES"
1220 PRINT "(T)RENCHCOAT"
1230 PRINT "(B)UY"
1240 PRINT "(S)ELL"
1250 PRINT "(J)ET"
1260 PRINT "SEE (L)OAN SHARK"
1270 PRINT "(V)ISIT BANK"
1280 PRINT CHR$(10)
1290 INPUT "PLEASE MAKE YOUR SELECTION: ";X$
1300 IF X$ = "C" GOTO 1390
1310 IF X$ = "T" GOTO 1530
1320 IF X$ = "B" GOTO 1670
1330 IF X$ = "S" GOTO 1880
1340 IF X$ = "J" GOTO 2120
1350 IF X$ = "L" GOTO 2370
1360 IF X$ = "V" GOTO 2510
1370 GOTO 1160
1380 REM->PRICES
1390 HOME
1400 GOSUB 110
1410 INVERSE:GOSUB 280:PRINT"PRICES":NORMAL
1420 PRINT CHR$(10)
1430 PRINT"COCAINE:","$"C
1440 PRINT"HEROIN:","$"H
1450 PRINT"ACID:","$"A
1460 PRINT"WEED:","$"Z
1470 PRINT"SPEED:","$"S
1480 PRINT"LUDES:","$"L
1490 PRINT"WALLET:","$"W
1500 GOSUB 150
1510 GOTO 1160
1520 REM->INVENTORY
1530 HOME
1540 GOSUB 110
1550 INVERSE:GOSUB 220 :PRINT"TRENCHCOAT":NORMAL
1560 PRINT CHR$(10)
1570 PRINT"COCAINE:",M
1580 PRINT"HEROIN:",N
1590 PRINT"ACID:",O
1600 PRINT"WEED:",U
1610 PRINT"SPEED:",T
1620 PRINT"LUDES:",Q
1630 PRINT"FREE SPACE:",F
1640 GOSUB 150
1650 GOTO 1160
1660 REM->BUY
1670 HOME
1680 GOSUB 110
1690 INVERSE:GOSUB 310: PRINT"BUY":NORMAL
1700 PRINT CHR$(10)
1710 PRINT"WHAT DO YOU WANT TO BUY?"
1720 PRINT CHR$(10)
1730 PRINT "(C)OCAINE"
1740 PRINT "(H)EROIN"
1750 PRINT "(A)CID"
1760 PRINT "(W)EED"
1770 PRINT "(S)PEED"
1780 PRINT "(L)UDES"
1790 INPUT "ENTER SELECTION: ";X$
1800 IF X$="C" GOTO 2660
1810 IF X$="H" GOTO 2750
1820 IF X$="A" GOTO 2840
1830 IF X$="W" GOTO 2930
1840 IF X$="S" GOTO 3020
1850 IF X$="L" GOTO 3110
1860 GOTO 1160
1870 REM->SELL
1880 HOME
1890 GOSUB 110
1900 INVERSE: GOSUB 280: PRINT"SELL":NORMAL
1910 PRINT CHR$(10)
1920 PRINT "WHAT WOULD YOU LIKE TO SELL?"
1930 PRINT CHR$(10)
1940 PRINT "(C)OCAINE"
1950 PRINT "(H)EROIN"
1960 PRINT "(A)CID"
1970 PRINT "(W)EED"
1980 PRINT "(S)PEED"
1990 PRINT "(L)UDES"
2000 REM->SELLSEL
2010 INPUT "ENTER SELECTION: (0 TO CANCEL)";X$
2020 IF X$="C" GOTO 3200
2030 IF X$="H" GOTO 3300
2040 IF X$="A" GOTO 3400
2050 IF X$="W" GOTO 3500
2060 IF X$="S" GOTO 3600
2070 IF X$="L" GOTO 3700
2080 IF X$="0" GOTO 1160
2090 PRINT "INVALID SELECTION!"
2100 GOTO 2010
2110 REM->JET
2120 HOME
2130 GOSUB 110
2140 GOSUB 340
2150 PRINT CHR$(10)
2160 PRINT "(B)RONX"
2170 PRINT "(G)HETTO"
2180 PRINT "(C)ENTRAL PARK
2190 PRINT "(M)ANHATTAN"
2200 PRINT "CONEY (I)SLAND"
2210 PRINT "BROO(K)LYN"
2220 PRINT "(O)OPS...STAY!"
2230 INPUT "WHERE TO DUDE? ";X$
2240 IF X$="B" THEN Y$ = "THE BRONX" : GOTO 2330
2250 IF X$="G" THEN Y$ = "THE GHETTO" : GOTO 2330
2260 IF X$="C" THEN Y$ = "CENTRAL PARK" : GOTO 2330
2270 IF X$="M" THEN Y$ = "MANHATTAN" : GOTO 2330
2280 IF X$="I" THEN Y$ = "CONEY ISLAND" : GOTO 2330
2290 IF X$="K" THEN Y$ = "BROOKLYN" : GOTO 2330
2300 IF X$="O" THEN GOTO 1160
2310 GOTO 2120
2320 REM->JETB
2330 IF Y$=P$ THEN GOTO 3800
2340 P$ = Y$ : Y$ = ""
2350 GOTO 3890
2360 REM->LOAN
2370 HOME
2380 GOSUB 110
2390 INVERSE : GOSUB 220:PRINT "LOAN SHARK":NORMAL
2400 PRINT CHR$(10)
2410 GOSUB 770
2420 PRINT "YOUR DEBT IS: $";V
2430 PRINT "YOU HAVE: $";W
2440 PRINT CHR$(10)
2450 INPUT "(R)EPAY, (B)ORROW, (L)EAVE: ";X$
2460 IF X$ = "R" THEN GOTO 6450
2470 IF X$ = "B" THEN GOTO 6540
2480 IF X$ = "L" THEN GOTO 1160
2490 GOTO 2370
2500 REM->BANK
2510 HOME
2520 GOSUB 110
2530 INVERSE : GOSUB 190: PRINT"BANK O'MURICA":NORMAL
2540 PRINT CHR$(10)
2550 GOSUB 770
2560 PRINT "YOUR BALANCE: $";E
2570 PRINT "YOUR WALLET: $";W
2580 PRINT CHR$(10)
2590 INPUT "(D)EPOSIT, (W)ITHDRAW, (L)EAVE: ";X$
2600 IF X$ = "D" THEN GOTO 6670
2610 IF X$ = "W" THEN GOTO 6770
2620 IF X$ = "L" THEN GOTO 1160
2630 IF X$ = EG$ THEN GOTO @EGG
2640 GOTO 2510
2650 REM->COKEBUY
2660 HOME
2670 GOSUB 110
2680 INVERSE:GOSUB 220: PRINT"BUY COCAINE":NORMAL
2690 PRINT CHR$(10)
2700 J=INT(W/C)
2710 GOSUB 500
2720 M=M+K : W=W-(C*K)
2730 GOTO 1160
2740 REM->HERBUY
2750 HOME
2760 GOSUB 110
2770 INVERSE:GOSUB 220: PRINT"BUY HEROIN":NORMAL
2780 PRINT CHR$(10)
2790 J=INT(W/H)
2800 GOSUB 500
2810 N=N+K : W=W-(H*K)
2820 GOTO 1160
2830 REM->ACIDBUY
2840 HOME
2850 GOSUB 110
2860 INVERSE:GOSUB 250:PRINT"BUY ACID":NORMAL
2870 PRINT CHR$(10)
2880 J=INT(W/A)
2890 GOSUB 500
2900 O=O+K : W=W-(A*K)
2910 GOTO 1160
2920 REM->WEEDBUY
2930 HOME
2940 GOSUB 110
2950 INVERSE:GOSUB 250: PRINT"BUY WEED":NORMAL
2960 PRINT CHR$(10)
2970 J=INT(W/Z)
2980 GOSUB 500
2990 U=U+K : W=W-(Z*K)
3000 GOTO 1160
3010 REM->SPDBUY
3020 HOME
3030 GOSUB 110
3040 INVERSE:GOSUB 250: PRINT"BUY SPEED":NORMAL
3050 PRINT CHR$(10)
3060 J=INT(W/S)
3070 GOSUB 500
3080 T=T+K : W=W-(S*K)
3090 GOTO 1160
3100 REM->LUDBUY
3110 HOME
3120 GOSUB 110
3130 INVERSE:GOSUB 250: PRINT"BUY LUDES":NORMAL
3140 PRINT CHR$(10)
3150 J=INT(W/L)
3160 GOSUB 500
3170 Q=Q+K : W=W-(L*K)
3180 GOTO 1160
3190 REM->COKESELL
3200 HOME
3210 GOSUB 110
3220 INVERSE:GOSUB 190:PRINT"SELL COCAINE":NORMAL
3230 PRINT CHR$(10)
3240 J=M
3250 GOSUB 600
3260 M=M-K
3270 W=W+(C*K)
3280 GOTO 1160
3290 REM->HERSELL
3300 HOME
3310 GOSUB 110
3320 INVERSE:GOSUB 250:PRINT"SELL HEROIN":NORMAL
3330 PRINT CHR$(10)
3340 J=N
3350 GOSUB 600
3360 N=N-K
3370 W=W+(H*K)
3380 GOTO 1160
3390 REM->ACIDSELL
3400 HOME
3410 GOSUB 110
3420 INVERSE:GOSUB 250: PRINT"SELL ACID":NORMAL
3430 PRINT CHR$(10)
3440 J=O
3450 GOSUB 600
3460 O=O-K
3470 W=W+(A*K)
3480 GOTO 1160
3490 REM->WEEDSELL
3500 HOME
3510 GOSUB 110
3520 INVERSE:GOSUB 250:PRINT"SELL WEED":NORMAL
3530 PRINT CHR$(10)
3540 J=U
3550 GOSUB 600
3560 U=U-K
3570 W=W+(Z*K)
3580 GOTO 1160
3590 REM->SPDSELL
3600 HOME
3610 GOSUB 110
3620 INVERSE:GOSUB 220:PRINT"SELL SPEED":NORMAL
3630 PRINT CHR$(10)
3640 J=T
3650 GOSUB 600
3660 T=T-K
3670 W=W+(S*K)
3680 GOTO 1160
3690 REM->LUDSELL
3700 HOME
3710 GOSUB 110
3720 INVERSE:GOSUB 220:PRINT"SELL LUDES":NORMAL
3730 PRINT CHR$(10)
3740 J=Q
3750 GOSUB 600
3760 Q=Q-K
3770 W=W+(L*K)
3780 GOTO 1160
3790 REM->ALREADYTHERE
3800 HOME
3810 GOSUB 110
3820 GOSUB 340
3830 PRINT CHR$(10)
3840 PRINT "YOU'RE ALREADY IN:"
3850 PRINT " ";P$
3860 GOSUB 460
3870 GOTO 2120
3880 REM->SUBWAY
3890 HOME
3900 GOSUB 830
3910 V=INT(V*1.1+.5)
3920 E=INT(E*1.06+.5)
3930 GOSUB 110
3940 INVERSE:GOSUB 280:PRINT"SUBWAY":NORMAL
3950 PRINT CHR$(10)
3960 IF B=1 THEN GOTO 4210
3970 IF B=2 THEN GOTO 4260
3980 IF B=3 THEN GOTO 4310
3990 IF B=4 THEN GOTO 4370
4000 IF B=5 THEN GOTO 4370
4010 IF B=6 THEN GOTO 4430
4020 IF B=7 THEN GOTO 4430
4030 IF B=8 THEN GOTO 4490
4040 IF B=9 THEN GOTO 4590
4050 IF B=10 THEN GOTO 4590
4060 IF B=11 THEN GOTO 4590
4070 IF B=12 THEN GOTO 5930
4080 IF B=13 THEN GOTO 5930
4090 IF B=14 THEN GOTO 6070
4100 IF B=15 THEN GOTO 6140
4110 IF B=16 THEN GOTO 6220
4120 IF B=17 THEN GOTO 6390
4130 REM->NOTHINGHAPPENED
4140 REM->NOTHINGHAPPENS
4150 PRINT CHR$(10)
4160 PRINT "WELCOME TO ";P$
4170 PRINT CHR$(10)
4180 GOSUB 460
4190 GOTO 1160
4200 REM->CHEAPLUDES
4210 PRINT "RIVAL DEALERS ARE SELLING CHEAP LUDES!"
4220 L=2
4230 GOSUB 460
4240 GOTO 1160
4250 REM->CHEEPWEED
4260 PRINT "WEED PRICES HAVE BOTTOMED-OUT!"
4270 Z=122
4280 GOSUB 460
4290 GOTO 1160
4300 REM->PIGHEROIN
4310 PRINT "PIGS ARE SELLING CHEAP HEROIN"
4320 PRINT "FROM LAST WEEK'S RAID!"
4330 H=INT((RND(9)*1150)+850.5)
4340 GOSUB 460
4350 GOTO 1160
4360 REM->HEROINBUST
4370 PRINT "ADDICTS ARE BUYING HEROIN"
4380 PRINT "AT OUTRAGEOUS PRICES!"
4390 H=INT((RND(9)*25000)+18000.5)
4400 GOSUB 460
4410 GOTO 1160
4420 REM->COKEBUST
4430 PRINT "PIGS MADE A BIG COKE BUST!"
4440 PRINT "PRICES ARE OUTRAGEOUS!!!!"
4450 C=INT((RND(9)*60000)+80000.5)
4460 GOSUB 460
4470 GOTO 1160
4480 REM->MUGGED
4490 PRINT "YOU GOT MUGGED!"
4500 PRINT CHR$(10)
4510 J=INT(W/3)
4520 J=INT(J*2)
4530 K=INT(W-J)
4540 PRINT "YOU LOST $";K
4550 W=J
4560 GOSUB 460
4570 GOSUB 1160
4580 REM->COPS
4590 K=M+N+U+O+T+P
4600 IF K<50 THEN GOTO 4140
4610 IF B=9 THEN B = 2
4620 IF B=10 THEN B=4
4630 IF B=11 THEN B=5
4640 PRINT "IT'S THE COPS!"
4650 PRINT CHR$(10)
4660 PRINT "OFFICER HARDASS AND ";B-1;" OF HIS"
4670 PRINT "DEPUTIES ARE AFTER YOU!"
4680 PRINT
4690 GOSUB 460
4700 GOTO 4720
4710 REM->POLICE
4720 HOME
4730 GOSUB 110
4740 GOSUB 710
4750 PRINT
4760 PRINT
4770 PRINT "VIEW (G)UNS"
4780 PRINT "VIEW (D)AMAGE"
4790 PRINT "(N)UMBER OF PIGS"
4800 PRINT "(R)UN"
4810 PRINT "(F)IGHT"
4820 PRINT
4830 INPUT "WHAT DO YOU WANT TO DO? ";X$
4840 IF X$="G" GOTO 4910
4850 IF X$ = "D" GOTO 5010
4860 IF X$ = "N" GOTO 5130
4870 IF X$ = "R" GOTO 5240
4880 IF X$="F" GOTO 5410
4890 GOTO 4720
4900 REM->PGUN
4910 HOME
4920 GOSUB 110
4930 GOSUB 710
4940 PRINT
4950 PRINT
4960 PRINT "YOU HAVE ";G;" GUNS.
4970 PRINT
4980 GOSUB 150
4990 GOTO 4720
5000 REM->DAMAGE
5010 HOME
5020 GOSUB 110
5030 GOSUB 710
5040 PRINT
5050 PRINT
5060 PRINT "YOUR CURRENT DAMAGE IS ";BB;"."
5070 PRINT
5080 PRINT "50 AND YOU DIE!"
5090 PRINT
5100 GOSUB 150
5110 GOTO 4720
5120 REM->NCOPS
5130 HOME
5140 GOSUB 110
5150 GOSUB 710
5160 PRINT
5170 PRINT
5180 PRINT "THERE ARE ";B;" PIGS STILL CHASING YOU!"
5190 PRINT
5200 PRINT
5210 GOSUB 150
5220 GOTO 4720
5230 REM->RUN
5240 HOME
5250 GOSUB 110
5260 GOSUB 710
5270 PRINT
5280 PRINT
5290 PRINT "RUNNING..."
5300 GOSUB 370
5310 IF K = 0 THEN PRINT "YOU LOST THEM IN AN ALLEY!" : GOTO 5370
5320 PRINT "YOU CAN'T SHAKE THEM!"
5330 PRINT
5340 GOSUB 150
5350 GOTO 4720
5360 REM->LOSERUN
5370 PRINT
5380 GOSUB 150
5390 GOTO 1160
5400 REM->FIGHT
5410 IF G<=0 THEN PRINT : PRINT : PRINT "YOU DON'T HAVE ANY GUNS!" : GOSUB 150 : GOTO 4720
5420 HOME
5430 GOSUB 110
5440 GOSUB 710
5450 PRINT
5460 PRINT "YOU SHOOT!"
5470 GOSUB 370
5480 IF K=0 THEN GOTO 5510
5490 PRINT "YOU GOT ONE!" : B = B-1 : GOTO 5530
5500 REM->MISS
5510 PRINT "YOU MISSED!"
5520 REM->NEXT
5530 PRINT
5540 PRINT
5550 IF B <= 0 THEN GOTO 5750
5560 GOSUB 420
5570 PRINT "THEY'RE FIRING AT YOU!"
5580 GOSUB 370
5590 IF K=0 THEN GOTO 5650
5600 PRINT "YOU'VE BEEN HIT!"
5610 BB=BB+3
5620 IF BB >= 50 GOTO 5700
5630 GOTO 5670
5640 REM->THEYMISS
5650 PRINT "THEY MISSED!"
5660 REM->NEXTA
5670 GOSUB 150
5680 GOTO 4720
5690 REM->DED
5700 PRINT
5710 PRINT "YOU'VE BEEN KILLED!"
5720 GOSUB 150
5730 GOTO 7220
5740 REM->ALLGONE
5750 PRINT "YOU KILLED ALL OF THEM!"
5760 PRINT
5770 GOSUB 370
5780 J=INT(((RND(7)*1250)+750)+.5)
5790 W=W+J
5800 PRINT "YOU FOUND $";J;" ON OFFICER HARDASS'"
5810 PRINT "CARCASS!"
5820 IF W>=1200 THEN GOTO 5850
5830 GOTO 1160
5840 REM->DOCTOR
5850 GOSUB 460
5860 PRINT
5870 PRINT "WILL YOU PAY $1000 FOR A DOCTOR"
5880 INPUT "TO SEW YOU UP? (Y/N)";X$
5890 IF X$ <> "Y" THEN GOTO 1160
5900 W=W-1000
5910 BB=0
5920 REM->GUNBUY
5930 IF W < 500 THEN GOTO 4140
5940 GOSUB 680
5950 IF F < 5 THEN GOTO 4140
5960 J=INT((RND(4)*2)+.5)
5970 IF J = 0 THEN Y$ = "BARETTA"
5980 IF J = 1 THEN Y$ = "SATURDAY NIGHT SPECIAL"
5990 IF J = 2 THEN Y$ = ".44 MAGNUM"
6000 PRINT "WILL YOU BUY A ";Y$
6010 INPUT "FOR $400? (Y/N)";X$
6020 IF X$ <> "Y" THEN GOTO 1160
6030 G = G+1
6040 W = W-400
6050 GOTO 1160
6060 REM->DEDWEED
6070 PRINT "THERE'S SOME WEED HERE THAT SMELLS"
6080 PRINT "LIKE GOOD STUFF!!"
6090 PRINT CHR$(10)
6100 INPUT "WILL YOU SMOKE IT? (Y/N)";X$
6110 IF X$ = "Y" THEN GOTO 7090
6120 GOTO1160
6130 REM->NEWCOAT
6140 IF W<300 THEN GOTO 4150
6150 PRINT "WILL YOU BUY A NEW TRENCHCOAT"
6160 INPUT "WITH MORE POCKETS FOR $200? (Y/N)";X$
6170 IF X$ <> "Y" THEN GOTO 1160
6180 I=I+10
6190 W=W-200
6200 GOTO 1160
6210 REM->DEDGUY
6220 GOSUB 680
6230 IF F<8 THEN GOTO 4150
6240 J=INT((RND(3)*7)+1.5)
6250 K=INT(RND(3)*5+.5)
6260 IF K=0 THEN Q=Q+J : Y$ = "LUDES"
6270 IF K=1 THEN T=T+J : Y$ = "SPEED"
6280 IF K=2 THEN U=U+J : Y$ = "WEED"
6290 IF K=3 THEN O=O+J : Y$ = "ACID"
6300 IF K=4 THEN N=N+J : Y$ = "HEROIN"
6310 IF K=5 THEN M=M+J : Y$ = "COCAINE"
6320 PRINT "YOU FOUND ";J;" UNITS OF"
6330 PRINT " ";Y$
6340 PRINT "ON A DEAD DUDE IN THE SUBWAY!"
6350 PRINT CHR$(10)
6360 GOSUB 460
6370 GOTO 1160
6380 REM->HOMEACID
6390 PRINT "THE MARKET HAS BEEN FLOODED"
6400 PRINT "WITH CHEAP HOME-MADE ACID!"
6410 A=INT((RND(4)*550)+250.5)
6420 GOSUB 460
6430 GOTO 1160
6440 REM->PAYME
6450 INPUT "REPAY HOW MUCH? ";K
6460 IF K>W THEN PRINT:PRINT "YOU DON'T HAVE THAT MUCH!" : GOSUB 420 : GOTO 2370
6470 IF K>V THEN PRINT:PRINT "YOU DON'T OWE THAT MUCH!" : GOSUB 420 : GOTO 2370
6480 W=W-K
6490 V=V-K
6500 PRINT:PRINT "THANK YOU."
6510 GOSUB 460
6520 GOTO 1160
6530 REM->BORROW
6540 PRINT CHR$(10)
6550 INPUT "HOW MUCH DO YOU WANT? ";K
6560 PRINT
6570 J=INT((RND(10)*10000)+5000)
6580 IF K>14000 THEN PRINT "HE'S NOT THAT STUPID!" : GOSUB 460 : GOTO 1160
6590 IF K > J THEN PRINT "HE DOESN'T FEEL LIKE IT." : GOSUB 420 : GOTO 1160
6600 V=V+K
6610 W=W+K
6620 PRINT CHR$(10)
6630 PRINT "HERE'S YOUR MONEY." : PRINT CHR$(10) : PRINT "REMEMBER, I BREAK THUMBS."
6640 GOSUB 460
6650 GOTO 1160
6660 REM->DEPOSIT
6670 PRINT CHR$(10)
6680 INPUT "HOW MUCH? ";J
6690 IF J>W THEN PRINT "YOU DON'T HAVE THAT MUCH CASH." : GOTO 6670
6700 E=E+J
6710 W=W-J
6720 PRINT CHR$(10)
6730 PRINT "THANK YOU FOR YOUR DEPOSIT."
6740 GOSUB 460
6750 GOTO 1160
6760 REM->MYMONEY
6770 PRINT CHR$(10)
6780 INPUT "HOW MUCH? ";J
6790 IF J>E THEN PRINT "YOU DON'T HAVE SUFFICIENT FUNDS." : GOTO 6770
6800 E=E-J
6810 W=W+J
6820 PRINT CHR$(10)
6830 PRINT "THANK YOU FOR YOUR BUSINESS."
6840 GOSUB 460
6850 GOTO 1160
6860 REM->INSTRUCTIONS
6870 HOME
6880 VTAB 2:HTAB10:PRINT "WELCOME TO DRUGWAR//E":HTAB14:PRINT"VERSION ";RV
6890 VTAB 8:HTAB 3:PRINT "BASED ON THE CLASSIC TI-BASIC CLONE":HTAB2:PRINT"OF JOHN E. DELL'S 1984 IBM/TRS80 GAME."
6900 VTAB12:HTAB6:PRINT "APPLESOFT VERSION BY: JAY MOORE"
6910 VTAB19:INPUT "WOULD YOU LIKE INSTRUCTIONS? (Y/N): ";X$
6920 J =RND(-1 *(PEEK(78)+256*PEEK(79)))
6930 IF X$ = "Y" THEN GOTO 6960
6940 GOTO 1010
6950 REM->INST
6960 HOME
6970 GOSUB 110
6980 PRINT CHR$(10)
6990 PRINT "THIS IS A GAME OF BUYING AND SELLING."
7000 PRINT "YOUR GOAL IS TO PAY OFF YOUR DEBT AND"
7010 PRINT "MAKE AS MUCH MONEY AS POSSIBLE IN A ONE"
7020 PRINT "MONTH PERIOD. PRICES FLUCTUATE EVERY DAYAND INTEREST ON YOUR LOAN IS CALCULATED AS WELL."
7030 PRINT:PRINT "IF YOU DEAL TOO HEAVILY, YOU'LL ATTRACT THE ATTENTION OF THE POLICE."
7040 PRINT CHR$(10)
7050 PRINT "COMMANDS ARE ENTERED USING THE LETTER HIGHLIGHTED (L)IKE (S)O. Y IS YES AND ANYTHING COUNTS AS NO."
7060 GOSUB 150
7070 GOTO 1010
7080 REM->WEEDEND
7090 HOME
7100 GOSUB 110
7110 INVERSE : GOSUB 190: PRINT "SMOKE WEED" : NORMAL
7120 SPEED = 50 :PRINT "YOU HALLUCINATE ON THE WILDEST TRIP"
7130 PRINT "OF YOUR LIFE, STUMBLE ON TO THE TRACKS,"
7140 PRINT "AND GET CREAMED BY A TRAIN!"
7150 PRINT CHR$(10)
7160 PRINT CHR$(10)
7170 HTAB 10:PRINT "JUST SAY NO TO DRUGS!":SPEED=255
7180 GOSUB 460
7190 GOSUB 420
7200 GOTO 7370
7210 REM->ENDGAME
7220 HOME
7230 GOSUB 110
7240 GOSUB 950
7250 GOSUB 740
7260 PRINT CHR$(10)
7270 PRINT "YOUR SCORE ON A SCALE OF 1 TO 100: ";K
7280 PRINT CHR$(10)
7290 INPUT "WOULD YOU LIKE TO PLAY AGAIN? (Y/N)";X$
7300 IF X$ = "Y" THEN GOTO 1010
7310 PRINT "THANKS FOR PLAYING."
7320 PRINT "REMEMBER, WATCH YOUR BACK."
7330 PRINT "HAVE A NICE DAY!"
7340 CLEAR
7350 END
7360 REM->IRONICEND
7370 HOME
7380 GOSUB 110
7390 GOSUB 740
7400 PRINT CHR$(10)
7410 SPEED = 50 : PRINT "YOU DIED FROM SMOKING WEED."
7420 PRINT CHR$(10)
7430 PRINT CHR$(10)
7440 GOSUB 460: PRINT"SEE? GAMES ARE TOTALLY FAKE." : SPEED = 255
7450 PRINT CHR$(10)
7460 INPUT "WOULD YOU LIKE TO PLAY AGAIN? ";X$
7470 IF X$= "Y" THEN GOTO 1010
7480 CLEAR
7490 END