diff --git a/DRUGWAR2eV104.bas b/DRUGWAR2eV104.bas
new file mode 100644
index 0000000..443f135
--- /dev/null
+++ b/DRUGWAR2eV104.bas
@@ -0,0 +1,497 @@
+10 REM DRUGWAR2EV104.BAS - 29/10/2018 - 18h15
+20 REM DRUGWAR//E - VERSION 1.04
+30 REM 29-OCT-2018
+40 REM COPYRIGHT 2018 JAY MOORE
+50 REM RELEASED UNDER GPL V3
+60 REM DRUGWAR2E.SOURCEFORGE.IO
+70 REM TWITTER: _NQ4T
+80 RV=1.04
+90 GOTO 4450
+100 REM->HOME
+110 POKE 36,0 : POKE 37, 1 : CALL -958
+120 INVERSE:?"                                        ":NORMAL:?:?:RETURN
+130 REM->TITLEBAR 
+140 HOME:HTAB 16 : ? "DRUGWAR//E":GOSUB 110:GOTO 730
+150 REM->WAIT 
+160 ?
+170 INPUT "PRESS ENTER TO CONTINUE.";X$
+180 RETURN
+190 REM->TWOFIFTEEN
+200 VTAB 2 : HTAB 15:RETURN
+210 REM->TWOSIXTEEN
+220 VTAB 2:HTAB 16:RETURN
+230 REM->TWOSEVENTEEN
+240 VTAB 2:HTAB 17:RETURN
+250 REM->TWOEIGHTEEN
+260 VTAB 2: HTAB 18:RETURN
+270 REM->TWONINETEEN
+280 VTAB 2:HTAB 19:RETURN
+290 REM->JETALTHERE
+300 INVERSE:GOSUB 280:?"JET":NORMAL:RETURN
+310 REM->TIMERA
+320 FOR J = 1 TO 2500:NEXT J:K = INT(RND(2)+.5):RETURN
+330 REM->TIMERB
+340 FOR J = 1 TO 1000:NEXT J:RETURN
+350 REM->TIMERC
+360 FOR J = 1 TO 2000:NEXT J:RETURN
+370 REM->HOWMUCHBUY 
+380 ? "YOU CAN AFFORD ";J:? "YOU CAN CARRY  ";F
+390 REM->HOWMANYBUY	
+400 ?:INPUT "HOW MANY? (ENTER 0 CANCEL): ";K
+410 IF K=0 GOTO 730
+420 IF K>F THEN INVERSE : ? "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 400
+430 IF K>J THEN INVERSE : ? "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 400
+440 RETURN
+450 REM->HOWMUCHSELL 
+460 ? "YOU CAN SELL: ";J:?
+470 REM->HOWMANYSELL
+480 INPUT "HOW MANY? (ENTER 0 TO CANCEL.): ";K
+490 IF K>J THEN ? "YOU DON'T HAVE THAT MANY!" : GOTO 480
+500 IF K=0 GOTO 730
+510 RETURN
+520 REM->FREESPACE
+530 F=I-((G*5)+M+N+O+U+T+Q):RETURN
+540 REM->CHASE
+550 INVERSE:GOSUB 200: ?"BEING CHASED":NORMAL:RETURN
+560 REM->GMOD
+570 SPEED=100:GOSUB 220:INVERSE:?"GAME OVER":NORMAL:SPEED=255:RETURN
+580 REM->BRONXCHECK
+590 IF P$ = "THE BRONX" THEN RETURN
+600 ? "YOU NEED TO HEAD TO THE BRONX":? "TO TAKE CARE OF THIS BUSINESS."
+610 GOSUB 360:GOTO 730
+620 REM->DAILY 
+630 C=INT(RND(5)*12000+16000.5):H=INT(RND(5)*7000+5000.5):A=INT((RND(5)*34+10)*100+.5):Z=INT((RND(5)*42+33)*10+.5):S=INT((RND(5)*15+7)*10+.5):L=INT((RND(5)*4+1)*10+.5):B=INT(RND(5)*20+.5):D=D+1
+640 REM->CHECKDAY 
+650 IF D >= 31 GOTO 4750:RETURN
+660 REM->SCORECALCULATE
+670 K=(W+E)-V:IF K<0 THEN K=0 : RETURN
+680 K=INT(SQR((K/31.5)+.5)):IF K>100 THEN K=100
+690 RETURN
+700 REM->GAMESTART 
+710 W=2000:E=0:V=5000:P$="THE BRONX":G=0:I=100:M=0:N=0:O=0:U=0:T=0:Q=0:GOSUB 630:GOTO 140
+720 REM->MENU 
+730 GOSUB 110:GOSUB 530
+740 INVERSE : VTAB 2:HTAB 4:? "DAY: "D : GOSUB 260:?"LOCATION: "P$ :NORMAL
+750 VTAB4:? "(C)HECK PRICES":? "(T)RENCHCOAT":? "(B)UY":? "(S)ELL":? "(J)ET":? "SEE (L)OAN SHARK":? "(V)ISIT BANK":?
+760 INPUT "PLEASE MAKE YOUR SELECTION: ";X$
+770 IF X$ = "C" GOTO 860
+780 IF X$ = "T" GOTO 980
+790 IF X$ = "B" GOTO 1100
+800 IF X$ = "S" GOTO 1280
+810 IF X$ = "J" GOTO 1490
+820 IF X$ = "L" GOTO 1730
+830 IF X$ = "V" GOTO 1860
+840 GOTO 730
+850 REM->PRICES
+860 GOSUB 110
+870 INVERSE:GOSUB 260:?"PRICES":NORMAL
+880 ?:?"COCAINE:","$"C
+890 ?"HEROIN:","$"H
+900 ?"ACID:","$"A
+910 ?"WEED:","$"Z
+920 ?"SPEED:","$"S
+930 ?"LUDES:","$"L
+940 ?"WALLET:","$"W
+950 GOSUB 160
+960 GOTO 730
+970 REM->INVENTORY
+980 GOSUB 110
+990 INVERSE:GOSUB 220 :?"TRENCHCOAT":NORMAL
+1000 ?:?"COCAINE:",M
+1010 ?"HEROIN:",N
+1020 ?"ACID:",O
+1030 ?"WEED:",U
+1040 ?"SPEED:",T
+1050 ?"LUDES:",Q
+1060 ?"FREE SPACE:",F
+1070 GOSUB 160
+1080 GOTO 730
+1090 REM->BUY
+1100 GOSUB 110
+1110 INVERSE:GOSUB 280: ?"BUY":NORMAL
+1120 ?:?"WHAT DO YOU WANT TO BUY?":?
+1130 ? "(C)OCAINE"
+1140 ? "(H)EROIN"
+1150 ? "(A)CID"
+1160 ? "(W)EED"
+1170 ? "(S)PEED"
+1180 ? "(L)UDES"
+1190 INPUT "ENTER SELECTION: ";X$
+1200 IF X$="C" GOTO 1980
+1210 IF X$="H" GOTO 2050
+1220 IF X$="A" GOTO 2120
+1230 IF X$="W" GOTO 2190
+1240 IF X$="S" GOTO 2260
+1250 IF X$="L" GOTO 2330
+1260 GOTO 730
+1270 REM->SELL
+1280 GOSUB 110
+1290 INVERSE: GOSUB 260: ?"SELL":NORMAL
+1300 ?:? "WHAT WOULD YOU LIKE TO SELL?":?
+1310 ? "(C)OCAINE"
+1320 ? "(H)EROIN"
+1330 ? "(A)CID"
+1340 ? "(W)EED"
+1350 ? "(S)PEED"
+1360 ? "(L)UDES"
+1370 REM->SELLSEL
+1380 INPUT "ENTER SELECTION: (0 TO CANCEL)";X$
+1390 IF X$="C" GOTO 2400
+1400 IF X$="H" GOTO 2470
+1410 IF X$="A" GOTO 2540
+1420 IF X$="W" GOTO 2610
+1430 IF X$="S" GOTO 2680
+1440 IF X$="L" GOTO 2750
+1450 IF X$="0" GOTO 730
+1460 ? "INVALID SELECTION!"
+1470 GOTO 1380
+1480 REM->JET
+1490 GOSUB 110
+1500 GOSUB 300
+1510 ?
+1520 ? "(B)RONX"
+1530 ? "(G)HETTO"
+1540 ? "(C)ENTRAL PARK
+1550 ? "(M)ANHATTAN"
+1560 ? "CONEY (I)SLAND"
+1570 ? "BROO(K)LYN"
+1580 ? "(O)OPS...STAY!"
+1590 INPUT "WHERE TO DUDE? ";X$
+1600 IF X$="B" THEN Y$ = "THE BRONX" : GOTO 1690
+1610 IF X$="G" THEN Y$ = "THE GHETTO" : GOTO 1690
+1620 IF X$="C" THEN Y$ = "CENTRAL PARK" : GOTO 1690
+1630 IF X$="M" THEN Y$ = "MANHATTAN" : GOTO 1690
+1640 IF X$="I" THEN Y$   = "CONEY ISLAND" : GOTO 1690
+1650 IF X$="K" THEN Y$ = "BROOKLYN" : GOTO 1690
+1660 IF X$="O" THEN GOTO 730
+1670 GOTO 1490
+1680 REM->JETB
+1690 IF Y$=P$ THEN GOTO 2820
+1700 P$ = Y$  : Y$ = ""
+1710 GOTO 2900
+1720 REM->LOAN
+1730 GOSUB 110
+1740 INVERSE : GOSUB 220:? "LOAN SHARK":NORMAL
+1750 ?
+1760 GOSUB 590
+1770 ? "YOUR DEBT IS: $";V
+1780 ? "YOU HAVE: $";W
+1790 ?
+1800 INPUT "(R)EPAY, (B)ORROW, (L)EAVE: ";X$
+1810 IF X$ = "R" THEN GOTO 4150
+1820 IF X$ = "B" THEN GOTO 4220
+1830 IF X$ = "L" THEN GOTO 730
+1840 GOTO 1730
+1850 REM->BANK
+1860 GOSUB 110
+1870 INVERSE : GOSUB 200: ?"BANK O'MURICA":NORMAL
+1880 ? : GOSUB 590
+1890 ? "YOUR BALANCE: $";E
+1900 ? "YOUR WALLET: $";W:?
+1910 INPUT "(D)EPOSIT, (W)ITHDRAW, (L)EAVE: ";X$
+1920 IF X$ = "D" THEN GOTO 4310
+1930 IF X$ = "W" THEN GOTO 4380
+1940 IF X$ = "L" THEN GOTO 730
+1950 IF X$ = EG$ THEN GOTO @EGG
+1960 GOTO 1860
+1970 REM->COKEBUY
+1980 GOSUB 110
+1990 INVERSE:GOSUB 220: ?"BUY COCAINE":NORMAL
+2000 ? :J=INT(W/C) 
+2010 GOSUB 380
+2020 M=M+K : W=W-(C*K) 
+2030 GOTO 730
+2040 REM->HERBUY
+2050 GOSUB 110
+2060 INVERSE:GOSUB 220: ?"BUY HEROIN":NORMAL
+2070 ? : J=INT(W/H)
+2080 GOSUB 380
+2090 N=N+K : W=W-(H*K)
+2100 GOTO 730
+2110 REM->ACIDBUY
+2120 GOSUB 110
+2130 INVERSE:GOSUB 240:?"BUY ACID":NORMAL
+2140 ? : J=INT(W/A)
+2150 GOSUB 380
+2160 O=O+K : W=W-(A*K)
+2170 GOTO 730
+2180 REM->WEEDBUY
+2190 GOSUB 110
+2200 INVERSE:GOSUB 240: ?"BUY WEED":NORMAL
+2210 ? : J=INT(W/Z)
+2220 GOSUB 380
+2230 U=U+K : W=W-(Z*K)
+2240 GOTO 730
+2250 REM->SPDBUY
+2260 GOSUB 110
+2270 INVERSE:GOSUB 240: ?"BUY SPEED":NORMAL
+2280 ? : J=INT(W/S)
+2290 GOSUB 380
+2300 T=T+K : W=W-(S*K)
+2310 GOTO 730
+2320 REM->LUDBUY
+2330 GOSUB 110
+2340 INVERSE:GOSUB 240: ?"BUY LUDES":NORMAL
+2350 ? : J=INT(W/L)
+2360 GOSUB 380
+2370 Q=Q+K : W=W-(L*K)
+2380 GOTO 730
+2390 REM->COKESELL
+2400 GOSUB 110
+2410 INVERSE:GOSUB 200:?"SELL COCAINE":NORMAL
+2420 ? : J=M 
+2430 GOSUB 460
+2440 M=M-K  : W=W+(C*K) 
+2450 GOTO 730
+2460 REM->HERSELL
+2470 GOSUB 110
+2480 INVERSE:GOSUB 240:?"SELL HEROIN":NORMAL
+2490 ?:J=N
+2500 GOSUB 460
+2510 N=N-K:W=W+(H*K)
+2520 GOTO 730
+2530 REM->ACIDSELL
+2540 GOSUB 110
+2550 INVERSE:GOSUB 240: ?"SELL ACID":NORMAL
+2560 ?:J=O
+2570 GOSUB 460
+2580 O=O-K:W=W+(A*K)
+2590 GOTO 730
+2600 REM->WEEDSELL
+2610 GOSUB 110
+2620 INVERSE:GOSUB 240:?"SELL WEED":NORMAL
+2630 ?:J=U
+2640 GOSUB 460
+2650 U=U-K:W=W+(Z*K)
+2660 GOTO 730
+2670 REM->SPDSELL
+2680 GOSUB 110
+2690 INVERSE:GOSUB 220:?"SELL SPEED":NORMAL
+2700 ?:J=T
+2710 GOSUB 460
+2720 T=T-K:W=W+(S*K)
+2730 GOTO 730
+2740 REM->LUDSELL
+2750 GOSUB 110
+2760 INVERSE:GOSUB 220:?"SELL LUDES":NORMAL
+2770 ?:J=Q
+2780 GOSUB 460
+2790 Q=Q-K:W=W+(L*K)
+2800 GOTO 730
+2810 REM->ALREADYTHERE
+2820 GOSUB 110
+2830 GOSUB 300
+2840 ?
+2850 ? "YOU'RE ALREADY IN:"
+2860 ? "            ";P$
+2870 GOSUB 360
+2880 GOTO 1490
+2890 REM->SUBWAY
+2900 GOSUB 110:GOSUB 630:V=INT(V*1.1+.5):E=INT(E*1.06+.5) :INVERSE:GOSUB 260:?"SUBWAY":NORMAL:?:?
+2910 IF B=1 THEN GOTO 3120
+2920 IF B=2 THEN GOTO 3140
+2930 IF B=3 THEN GOTO 3160
+2940 IF B=4 THEN GOTO 3180
+2950 IF B=5 THEN GOTO 3180
+2960 IF B=6 THEN GOTO 3200
+2970 IF B=7 THEN GOTO 3200
+2980 IF B=8 THEN GOTO 3220
+2990 IF B=9 THEN GOTO 3240
+3000 IF B=10 THEN GOTO 3240
+3010 IF B=11 THEN GOTO 3240
+3020 IF B=12 THEN GOTO 3810
+3030 IF B=13 THEN GOTO 3810
+3040 IF B=14 THEN GOTO 3890
+3050 IF B=15 THEN GOTO 3940
+3060 IF B=16 THEN GOTO 3990
+3070 IF B=17 THEN GOTO 4100
+3080 REM->NOTHINGHAPPENED
+3090 REM->NOTHINGHAPPENS	
+3100 ?:? "WELCOME TO ";P$:?:GOSUB 360:GOTO 730
+3110 REM->CHEAPLUDES
+3120 ? "RIVAL DEALERS ARE SELLING CHEAP LUDES!":L=2:GOSUB 360:GOTO 730
+3130 REM->CHEEPWEED
+3140 ? "WEED PRICES HAVE BOTTOMED-OUT!":Z=122:GOSUB 360:GOTO 730
+3150 REM->PIGHEROIN
+3160 ? "PIGS ARE SELLING CHEAP HEROIN":? "FROM LAST WEEK'S RAID!":H=INT((RND(9)*1150)+850.5):GOSUB 360:GOTO 730
+3170 REM->HEROINBUST
+3180 ? "ADDICTS ARE BUYING HEROIN":? "AT OUTRAGEOUS PRICES!":H=INT((RND(9)*25000)+18000.5):GOSUB 360:GOTO 730
+3190 REM->COKEBUST
+3200 ? "PIGS MADE A BIG COKE BUST!":? "PRICES ARE OUTRAGEOUS!!!!":C=INT((RND(9)*60000)+80000.5):GOSUB 360:GOTO 730
+3210 REM->MUGGED
+3220 ? "YOU GOT MUGGED!":?:J=INT((W/3)*2):? "YOU LOST $";W-J:W=W-J:GOSUB 360:GOTO 730
+3230 REM->COPS
+3240 K=M+N+U+O+T+P:IF K<50 THEN GOTO 3090
+3250 IF B=9 THEN B = 2
+3260 IF B=10 THEN B=4
+3270 IF B=11 THEN B=5
+3280 ? "IT'S THE COPS!":?:? "OFFICER HARDASS AND ";B-1;" OF HIS":? "DEPUTIES ARE AFTER YOU!":?:GOSUB 360:GOTO 3300
+3290 REM->POLICE
+3300 GOSUB 110:GOSUB 550:?:? :? "VIEW (G)UNS":? "VIEW (D)AMAGE":? "(N)UMBER OF PIGS":? "(R)UN":? "(F)IGHT":?
+3310 INPUT "WHAT DO YOU WANT TO DO? ";X$
+3320 IF X$="G" GOTO 3390
+3330 IF X$ = "D" GOTO 3410
+3340 IF X$ = "N" GOTO 3430
+3350 IF X$ = "R" GOTO 3450
+3360 IF X$="F" GOTO 3500
+3370 GOTO 3300
+3380 REM->PGUN
+3390 GOSUB 110:GOSUB 550:?:? :? "YOU HAVE ";G;" GUNS.:?:GOSUB 160:GOTO 3300
+3400 REM->DAMAGE
+3410 GOSUB 110:GOSUB 550:?:? :? "YOUR HEALTH IS ";BB;".":?:? "0 AND YOU DIE!":?:GOSUB 160:GOTO 3300
+3420 REM->NCOPS
+3430 GOSUB 110:GOSUB 550:?:?:? "THERE ARE ";B;" PIGS STILL CHASING YOU!":?:?:GOSUB 160:GOTO 3300
+3440 REM->RUN
+3450 GOSUB 110:GOSUB 550:?:?:? "RUNNING...":GOSUB 320:IF K = 0 THEN ? "YOU LOST THEM IN AN ALLEY!" : GOTO 3480
+3460 ? "YOU CAN'T SHAKE THEM!":?:GOSUB 160:GOTO 3300
+3470 REM->LOSERUN
+3480 ?:GOSUB 160:GOTO 730
+3490 REM->FIGHT
+3500 IF G<=0 THEN ? : ? : ? "YOU DON'T HAVE ANY GUNS!" : GOSUB 160 : GOTO 3300
+3510 GOSUB 110:GOSUB 550
+3520 ?:? "YOU SHOOT!":GOSUB 320:IF K=0 THEN GOTO 3550
+3530 ? "YOU GOT ONE!" : B = B-1 : 	GOTO 3570
+3540 REM->MISS 
+3550 ? "YOU MISSED!"
+3560 REM->NEXT
+3570 ?:?:IF B <= 0 THEN GOTO 3680
+3580 GOSUB 340:? "THEY'RE FIRING AT YOU!":GOSUB 320:IF K=0 THEN GOTO 3620
+3590 ? "YOU'VE BEEN HIT!":BB=BB-6:IF BB >= 0 GOTO 3660
+3600 GOTO 3640
+3610 REM->THEYMISS
+3620 ? "THEY MISSED!"
+3630 REM->NEXTA
+3640 GOSUB 320:GOTO 3300
+3650 REM->DED
+3660 ?:? "YOU'VE BEEN KILLED!":GOSUB 160:GOTO 4750
+3670 REM->ALLGONE
+3680 ? "YOU KILLED ALL OF THEM!":?:GOSUB 320
+3690 J=INT(((RND(7)*1250)+750)+.5):W=W+J
+3700 ? "YOU FOUND $";J;" ON OFFICER HARDASS'" 
+3710 ? "CARCASS!"
+3720 IF W>=1200 THEN GOTO 3750
+3730 GOTO 730
+3740 REM->DOCTOR
+3750 GOSUB 360
+3760 ?:? "WILL YOU PAY $1000 FOR A DOCTOR"
+3770 INPUT "TO SEW YOU UP? (Y/N)";X$
+3780 IF X$ <> "Y" THEN GOTO 730
+3790 W=W-1000:BB=100:GOTO 730
+3800 REM->GUNBUY
+3810 IF W < 500 THEN GOTO 3090:GOSUB 530:IF F < 5 THEN GOTO 3090
+3820 J=INT((RND(4)*2)+.5)
+3830 IF J = 0 THEN Y$ = "BARETTA"
+3840 IF J = 1 THEN Y$ = "SATURDAY NIGHT SPECIAL"
+3850 IF J = 2 THEN Y$ = ".44 MAGNUM"
+3860 ? "WILL YOU BUY A ";Y$:INPUT "FOR $400? (Y/N)";X$:IF X$ <> "Y" THEN GOTO 730
+3870 G = G+1:W = W-400:GOTO 730
+3880 REM->DEDWEED 
+3890 ? "THERE'S SOME WEED HERE THAT SMELLS":? "LIKE GOOD STUFF!!":?
+3900 INPUT "WILL YOU SMOKE IT? (Y/N)";X$
+3910 IF X$ = "Y" THEN GOTO 4630
+3920 GOTO730
+3930 REM->NEWCOAT
+3940 IF W<300 THEN GOTO 3100
+3950 ? "WILL YOU BUY A NEW TRENCHCOAT":INPUT "WITH MORE POCKETS FOR $200? (Y/N)";X$
+3960 IF X$ <> "Y" THEN GOTO 730
+3970 I=I+10:W=W-200:GOTO 730
+3980 REM->DEDGUY
+3990 GOSUB 530
+4000 IF F<8 THEN GOTO 3100
+4010 J=INT((RND(3)*7)+1.5):K=INT(RND(3)*5+.5)
+4020 IF K=0 THEN Q=Q+J : Y$ = "LUDES"
+4030 IF K=1 THEN T=T+J : Y$ = "SPEED"
+4040 IF K=2 THEN U=U+J : Y$ = "WEED"
+4050 IF K=3 THEN O=O+J : Y$ = "ACID"
+4060 IF K=4 THEN N=N+J : Y$ = "HEROIN"
+4070 IF K=5 THEN M=M+J : Y$ = "COKE"
+4080 ? "YOU FOUND "J" UNITS OF "Y$:? "ON A DEAD DUDE IN THE SUBWAY!":?:GOSUB 360:GOTO 730
+4090 REM->HOMEACID
+4100 ? "THE MARKET HAS BEEN FLOODED"
+4110 ? "WITH CHEAP HOME-MADE ACID!"
+4120 A=INT((RND(4)*550)+250.5)
+4130 GOSUB 360:GOTO 730
+4140 REM->PAYME
+4150 INPUT "REPAY HOW MUCH? ";K
+4160 IF K>W THEN ?:? "YOU DON'T HAVE THAT MUCH!" : GOSUB 340 : GOTO 1730
+4170 IF K>V THEN ?:? "YOU DON'T OWE THAT MUCH!" : GOSUB 340 : GOTO 1730
+4180 W=W-K : V=V-K
+4190 ?:? "THANK YOU." 
+4200 GOSUB 360:GOTO 730
+4210 REM->BORROW
+4220 ?
+4230 INPUT "HOW MUCH DO YOU WANT? ";K
+4240 ? : J=INT((RND(10)*10000)+4000)
+4250 IF K>14000 THEN ? "HE'S NOT THAT STUPID!" : GOSUB 360 : GOTO 730
+4260 IF K > J THEN ? "HE DOESN'T FEEL LIKE IT." : GOSUB 340 : GOTO 730
+4270 V=V+K : W=W+K
+4280 ?:? "HERE'S YOUR MONEY." : ? : ? "REMEMBER, I BREAK THUMBS."
+4290 GOSUB 360:GOTO 730
+4300 REM->DEPOSIT
+4310 ?
+4320 INPUT "HOW MUCH? ";J
+4330 IF J>W THEN ? "YOU DON'T HAVE THAT MUCH CASH." : GOTO 4310
+4340 E=E+J:W=W-J
+4350 ?:? "THANK YOU FOR YOUR DEPOSIT."
+4360 GOSUB 360:GOTO 730
+4370 REM->MYMONEY
+4380 ?
+4390 INPUT "HOW MUCH? ";J
+4400 IF J>E THEN ? "YOU DON'T HAVE SUFFICIENT FUNDS." : GOTO 4380
+4410 E=E-J:W=W+J
+4420 ?:? "THANK YOU FOR YOUR BUSINESS."
+4430 GOSUB 360:GOTO 730
+4440 REM->INSTRUCTIONS
+4450 HOME:VTAB 2:HTAB10:? "WELCOME TO DRUGWAR//E":HTAB14:?"VERSION ";RV
+4460 VTAB 8:HTAB 3:? "BASED ON THE CLASSIC TI-BASIC CLONE":HTAB 2:? "OF JOHN E. DELL'S 1984 IBM/TRS80 GAME."
+4470 VTAB 12:HTAB 6:? "APPLESOFT VERSION BY: JAY MOORE":VTAB 19:INPUT "WOULD YOU LIKE INSTRUCTIONS? (Y/N): ";X$
+4480 J =RND(-1 *(PEEK(78)+256*PEEK(79))):IF X$ = "Y" THEN GOTO 4510
+4490 GOTO 710
+4500 REM->INST
+4510 HOME
+4520 ?
+4530 ? "THIS IS A GAME OF BUYING AND SELLING."
+4540 ? "YOUR GOAL IS TO PAY OFF YOUR DEBT AND"
+4550 ? "MAKE AS MUCH MONEY AS POSSIBLE IN A ONE"
+4560 ? "MONTH PERIOD. PRICES FLUCTUATE EVERY DAYAND INTEREST ON YOUR LOAN IS CALCULATED AS WELL."
+4570 ?:? "IF YOU DEAL TOO HEAVILY, YOU'LL ATTRACT THE ATTENTION OF THE POLICE."
+4580 ?
+4590 ? "COMMANDS ARE ENTERED USING THE LETTER   HIGHLIGHTED (L)IKE (S)O. Y IS YES AND   ANYTHING COUNTS AS NO."
+4600 GOSUB 160
+4610 GOTO 710
+4620 REM->WEEDEND
+4630 GOSUB 110
+4640 INVERSE : GOSUB 200: ? "SMOKE WEED" : NORMAL
+4650 SPEED = 50 :? "YOU HALLUCINATE ON THE WILDEST TRIP"
+4660 ? "OF YOUR LIFE, STUMBLE ON TO THE TRACKS,"
+4670 ? "AND GET CREAMED BY A TRAIN!"
+4680 ?
+4690 ?
+4700 HTAB 10:? "JUST SAY NO TO DRUGS!":SPEED=255
+4710 GOSUB 360
+4720 GOSUB 340
+4730 GOTO 4890
+4740 REM->ENDGAME
+4750 GOSUB 110
+4760 GOSUB 670
+4770 GOSUB 570
+4780 ?
+4790 ? "YOUR SCORE ON A SCALE OF 1 TO 100: ";K
+4800 ?
+4810 INPUT "WOULD YOU LIKE TO PLAY AGAIN? (Y/N)";X$
+4820 IF X$ = "Y" THEN GOTO 710
+4830 ? "THANKS FOR PLAYING."
+4840 ? "REMEMBER, WATCH YOUR BACK."
+4850 ? "HAVE A NICE DAY!"
+4860 CLEAR
+4870 END
+4880 REM->IRONICEND
+4890 GOSUB 110
+4900 GOSUB 570
+4910 ?
+4920 SPEED = 50 : ? "YOU DIED FROM SMOKING WEED."
+4930 ?:?:GOSUB 360: ?"SEE? GAMES ARE TOTALLY FAKE." : SPEED = 255:?
+4940 INPUT "WOULD YOU LIKE TO PLAY AGAIN? ";X$
+4950 IF X$= "Y" THEN GOTO 710
+4960 CLEAR
+4970 END