drugwar2e/DRUGWAR2e.bas

1 REM DRUGWAR2E.BAS - 06/11/2018 - 23h35
2 RV=1.05:GOTO307
3 
4 POKE36,0:POKE37,1:CALL -958:INVERSE:?"                                        ":NORMAL:?:?:RETURN
5 
6 ?:INPUT"PRESS ENTER TO CONTINUE.";X$:RETURN
7 
8 VTAB2:HTAB15:RETURN
9 
10 VTAB2:HTAB16:RETURN
11 
12 VTAB2:HTAB17:RETURN
13 
14 VTAB2:HTAB18:RETURN
15 
16 VTAB2:HTAB19:RETURN
17 
18 INVERSE:GOSUB16:?"JET":NORMAL:RETURN
19 
20 FORJ=1TO2500:NEXT J:K=INT(RND(1)+.5):RETURN
21 
22 FORJ=1TO1000:NEXT J:RETURN
23 
24 FORJ=1TO2000:NEXT J:RETURN
25 
26 ?"YOU CAN AFFORD ";J:?"YOU CAN CARRY  ";F
27 
28 ?:INPUT"HOW MANY? (ENTER 0 CANCEL):";K:IFK=0GOTO65
29 IFK<ACTHENINVERSE:?"STOP CHEATING!":NORMAL:AD=AD+1:GOSUB52:GOSUB24:GOTO65
30 IFK<0THENAD=AD+1:GOSUB52:RETURN
31 IFK>FTHENINVERSE:?"YOU CAN'T CARRY THAT MUCH!":NORMAL:GOTO28
32 IFK>JTHENINVERSE:?"YOU CAN'T AFFORD THAT MUCH!":NORMAL:GOTO28
33 RETURN
34 
35 ?"YOU CAN SELL:";J:?
36 
37 INPUT"HOW MANY? (ENTER 0 TO CANCEL.):";K
38 IFK=0GOTO65
39 IFK>JTHEN?"YOU DON'T HAVE THAT MANY!":GOTO37
40 RETURN
41 
42 F=I-((G*5)+M+N+O+U+T+Q):RETURN
43 
44 INVERSE:GOSUB8:?"BEING CHASED":NORMAL:RETURN
45 
46 SPEED=100:GOSUB10:INVERSE:?"GAME OVER":NORMAL:SPEED=255:RETURN
47 
48 IFP$="THE BRONX"THEN RETURN
49 ?"YOU NEED TO HEAD TO THE BRONX":?"TO TAKE CARE OF THIS BUSINESS."
50 GOSUB24:GOTO65
51 
52 IFAD>=3THENGOTO314
53 RETURN
54 
55 C=INT(RND(1)*12000+16000.5):H=INT(RND(1)*7000+5000.5):A=INT((RND(1)*34+10)*100+.5):Z=INT((RND(1)*42+33)*10+.5):S=INT((RND(1)*15+7)*10+.5):L=INT((RND(1)*4+1)*10+.5):B=INT(RND(1)*20+.5):D=D+1:AC=INT(((RND(1)*3)+1)*-1)
56 
57 IFD>=31GOTO319:RETURN
58 
59 K=(W+E)-V:IFK<0THENK=0:RETURN
60 K=INT(SQR((K/31.5)+.5)):IFK>100THENK=100
61 RETURN
62 
63 W=2000:E=0:V=5000:P$="THE BRONX":G=0:I=100:M=0:N=0:O=0:U=0:T=0:Q=0:GOSUB55:HOME:HTAB16:?"DRUGWAR//E":GOTO65
64 
65 GOSUB4:GOSUB42
66 INVERSE:VTAB2:HTAB4:?"DAY:"D:GOSUB14:?"LOCATION:"P$:NORMAL
67 VTAB4:?"(C)HECK PRICES":?"(T)RENCHCOAT":?"(B)UY":?"(S)ELL":?"(J)ET":?"SEE (L)OAN SHARK":?"(V)ISIT BANK":?
68 INPUT"PLEASE MAKE YOUR SELECTION:";X$
69 IFX$="C"GOTO78
70 IFX$="T"GOTO83
71 IFX$="B"GOTO88
72 IFX$="S"GOTO100
73 IFX$="J"GOTO113
74 IFX$="L"GOTO129
75 IFX$="V"GOTO135
76 GOTO65
77 
78 GOSUB4
79 INVERSE:GOSUB14:?"PRICES":NORMAL
80 ?:?"COCAINE:","$"C:?"HEROIN:","$"H:?"ACID:","$"A:?"WEED:","$"Z:?"SPEED:","$"S:?"LUDES:","$"L:?"WALLET:","$"W
81 GOSUB6:GOTO65
82 
83 GOSUB4
84 INVERSE:GOSUB10:?"TRENCHCOAT":NORMAL
85 ?:?"COCAINE:",M:?"HEROIN:",N:?"ACID:",O:?"WEED:",U:?"SPEED:",T:?"LUDES:",Q:?"FREE SPACE:",F
86 GOSUB6:GOTO65
87 
88 GOSUB4
89 INVERSE:GOSUB16:?"BUY":NORMAL
90 ?:?"WHAT DO YOU WANT TO BUY?":?:?"(C)OCAINE":?"(H)EROIN":?"(A)CID":?"(W)EED":?"(S)PEED":?"(L)UDES"
91 INPUT"ENTER SELECTION:";X$
92 IFX$="C"GOTO142
93 IFX$="H"GOTO144
94 IFX$="A"GOTO146
95 IFX$="W"GOTO148
96 IFX$="S"GOTO150
97 IFX$="L"GOTO152
98 GOTO65
99 
100 GOSUB4:INVERSE:GOSUB14:?"SELL":NORMAL
101 ?:?"WHAT WOULD YOU LIKE TO SELL?":?:?"(C)OCAINE":?"(H)EROIN":?"(A)CID":?"(W)EED":?"(S)PEED":?"(L)UDES"
102 
103 INPUT"ENTER SELECTION:(0 TO CANCEL)";X$
104 IFX$="C"GOTO154
105 IFX$="H"GOTO156
106 IFX$="A"GOTO158
107 IFX$="W"GOTO160
108 IFX$="S"GOTO162
109 IFX$="L"GOTO164
110 IFX$="0"GOTO65
111 ?"INVALID SELECTION!":GOTO103
112 
113 GOSUB4:GOSUB18
114 ?:?"(B)RONX":?"(G)HETTO":?"(C)ENTRAL PARK
115 ?"(M)ANHATTAN":?"CONEY (I)SLAND":?"BROO(K)LYN":?"(O)OPS...STAY!":INPUT"WHERE TO DUDE?";X$
116 IFX$="B"THEN Y$="THE BRONX":GOTO125
117 IFX$="G"THEN Y$="THE GHETTO":GOTO125
118 IFX$="C"THEN Y$="CENTRAL PARK":GOTO125
119 IFX$="M"THEN Y$="MANHATTAN":GOTO125
120 IFX$="I"THEN Y$  ="CONEY ISLAND":GOTO125
121 IFX$="K"THEN Y$="BROOKLYN":GOTO125
122 IFX$="O"THENGOTO65
123 GOTO113
124 
125 IFY$=P$THENGOTO166
126 P$=Y$ :Y$=""
127 GOTO168
128 
129 GOSUB4:INVERSE:GOSUB10:?"LOAN SHARK":NORMAL:?:GOSUB48:?"YOUR DEBT IS:$";V:?"YOU HAVE:$";W:?:INPUT"(R)EPAY, (B)ORROW, (L)EAVE:";X$
130 IFX$="R"THENGOTO284
131 IFX$="B"THENGOTO289
132 IFX$="L"THENGOTO65
133 GOTO129
134 
135 GOSUB4:INVERSE:GOSUB8:?"BANK O'MURICA":NORMAL:?:GOSUB48:?"YOUR BALANCE:$";E:?"YOUR WALLET:$";W:?
136 INPUT"(D)EPOSIT, (W)ITHDRAW, (L)EAVE:";X$
137 IFX$="D"THENGOTO295
138 IFX$="W"THENGOTO302
139 IFX$="L"THENGOTO65
140 GOTO135
141 
142 GOSUB4:INVERSE:GOSUB10:?"BUY COCAINE":NORMAL:?:J=INT(W/C):AC=0:GOSUB26:M=M+K:W=W-(C*K):GOTO65
143 
144 GOSUB4:INVERSE:GOSUB10:?"BUY HEROIN":NORMAL:?:J=INT(W/H):AC=0:GOSUB26:N=N+K:W=W-(H*K):GOTO65
145 
146 GOSUB4:INVERSE:GOSUB12:?"BUY ACID":NORMAL:?:J=INT(W/A):GOSUB26:O=O+K:W=W-(A*K):GOTO65
147 
148 GOSUB4:INVERSE:GOSUB12:?"BUY WEED":NORMAL:?:J=INT(W/Z):GOSUB26:U=U+K:W=W-(Z*K):GOTO65
149 
150 GOSUB4:INVERSE:GOSUB12:?"BUY SPEED":NORMAL:?:J=INT(W/S):GOSUB26:T=T+K:W=W-(S*K):GOTO65
151 
152 GOSUB4:INVERSE:GOSUB12:?"BUY LUDES":NORMAL:?:J=INT(W/L):GOSUB26:Q=Q+K:W=W-(L*K):GOTO65
153 
154 GOSUB4:INVERSE:GOSUB8:?"SELL COCAINE":NORMAL:?:J=M:GOSUB35:M=M-K:W=W+(C*K):GOTO65
155 
156 GOSUB4:INVERSE:GOSUB12:?"SELL HEROIN":NORMAL:?:J=N:GOSUB35:N=N-K:W=W+(H*K):GOTO65
157 
158 GOSUB4:INVERSE:GOSUB12:?"SELL ACID":NORMAL:?:J=O:GOSUB35:O=O-K:W=W+(A*K):GOTO65
159 
160 GOSUB4:INVERSE:GOSUB12:?"SELL WEED":NORMAL:?:J=U:GOSUB35:U=U-K:W=W+(Z*K):GOTO65
161 
162 GOSUB4:INVERSE:GOSUB10:?"SELL SPEED":NORMAL:?:J=T:GOSUB35:T=T-K:W=W+(S*K):GOTO65
163 
164 GOSUB4:INVERSE:GOSUB10:?"SELL LUDES":NORMAL:?:J=Q:GOSUB35:Q=Q-K:W=W+(L*K):GOTO65
165 
166 GOSUB4:GOSUB18:?:?"YOU'RE ALREADY IN:":HTAB15:? P$:GOSUB24:GOTO113
167 
168 GOSUB4:GOSUB55:V=INT(V*1.1+.5):E=INT(E*1.06+.5):INVERSE:GOSUB14:?"SUBWAY":NORMAL:?:?
169 IFB=1GOTO189
170 IFB=2GOTO191
171 IFB=3GOTO193
172 IFB=4GOTO195
173 IFB=5GOTO195
174 IFB=6GOTO197
175 IFB=7GOTO197
176 IFB=8GOTO199
177 IFB=9GOTO201
178 IFB=10GOTO201
179 IFB=11GOTO201
180 IFB=12GOTO254
181 IFB=13GOTO254
182 IFB=14GOTO262
183 IFB=15GOTO266
184 IFB=16OTO271
185 IFB=17GOTO282
186 
187 ?:?"WELCOME TO ";P$:?:GOSUB24:GOTO65
188 
189 ?"RIVAL DEALERS ARE SELLING CHEAP LUDES!":L=2:GOSUB24:GOTO65
190 
191 ?"WEED PRICES HAVE BOTTOMED-OUT!":Z=122:GOSUB24:GOTO65
192 
193 ?"PIGS ARE SELLING CHEAP HEROIN":?"FROM LAST WEEK'S RAID!":H=INT((RND(1)*1150)+850.5):GOSUB24:GOTO65
194 
195 ?"ADDICTS ARE BUYING HEROIN":?"AT OUTRAGEOUS PRICES!":H=INT((RND(1)*25000)+18000.5):GOSUB24:GOTO65
196 
197 ?"PIGS MADE A BIG COKE BUST!":?"PRICES ARE OUTRAGEOUS!!!!":C=INT((RND(1)*60000)+80000.5):GOSUB24:GOTO65
198 
199 ?"YOU GOT MUGGED!":?:J=INT((W/3)*2):?"YOU LOST $";W-J:W=W-J:GOSUB24:GOTO65
200 
201 GOSUB42:IFF<I/2THENGOTO187
202 IFB=9THENB=2
203 IFB=10THENB=4
204 IFB=11THENB=5
205 ?"IT'S THE COPS!":?:?"OFFICER HARDASS AND ";B-1;"OF HIS":?"DEPUTIES ARE AFTER YOU!":?:GOSUB24:GOTO207
206 
207 GOSUB4:GOSUB44:?:?:?"VIEW (G)UNS":?"VIEW (D)AMAGE":?"(N)UMBER OF PIGS":?"(R)UN":?"(F)IGHT":?
208 INPUT"WHAT DO YOU WANT TO DO?";X$
209 IFX$="G"GOTO216
210 IFX$="D"GOTO218
211 IFX$="N"GOTO220
212 IFX$="R"GOTO222
213 IFX$="F"GOTO225
214 GOTO207
215 
216 GOSUB4:GOSUB44:?:?:?"YOU HAVE ";G;"GUNS.:?:GOSUB6:GOTO207
217 
218 GOSUB4:GOSUB44:?:?:?"YOUR HEALTH IS ";BB;".":?:?"0 AND YOU DIE!":?:GOSUB6:GOTO207
219 
220 GOSUB4:GOSUB44:?:?:?"THERE ARE ";B;"PIGS STILL CHASING YOU!":?:?:GOSUB6:GOTO207
221 
222 GOSUB4:GOSUB44:?:?:?"RUNNING...":GOSUB20:IFK=0THEN?"YOU LOST THEM IN AN ALLEY!":GOSUB24:GOTO65
223 ?"YOU CAN'T SHAKE THEM!":?:GOTO232
224 
225 IFG<=0THEN?:?:?"YOU DON'T HAVE ANY GUNS!":GOSUB6:GOTO207
226 GOSUB4:GOSUB44
227 ?:?"YOU SHOOT!":GOSUB20:IFK=0THENGOTO230
228 ?"YOU GOT ONE!":B=B-1:	GOTO232
229 
230 ?"YOU MISSED!"
231 
232 ?:?:IFB<=0THENGOTO243
233 GOSUB22:?"THEY'RE FIRING AT YOU!":GOSUB20:IFK=0THENGOTO237
234 ?"YOU'VE BEEN HIT!":BB=BB-6:IFBB>=0GOTO241
235 GOTO239
236 
237 ?"THEY MISSED!"
238 
239 GOSUB20:GOTO207
240 
241 ?:?"YOU'VE BEEN KILLED!":GOSUB6:GOTO319
242 
243 ?"YOU KILLED ALL OF THEM!":?:GOSUB20
244 J=INT(((RND(1)*1250)+750)+.5):W=W+J
245 ?"YOU FOUND $";J;"ON OFFICER HARDASS'"
246 ?"CARCASS!"
247 IFW>=1200THENGOTO250
248 GOTO65
249 
250 GOSUB24:?:?"WILL YOU PAY $1000 FOR A DOCTOR":INPUT"TO SEW YOU UP? (Y/N)";X$
251 IFX$<>"Y"THENGOTO65
252 W=W-1000:BB=100:GOTO65
253 
254 IFW<500THENGOTO187:GOSUB42:IFF<5THENGOTO187
255 J=INT((RND(1)*2)+.5)
256 IFJ=0THENY$="BARETTA"
257 IFJ=1THENY$="SATURDAY NIGHT SPECIAL"
258 IFJ=2THENY$=".44 MAGNUM"
259 ?"WILL YOU BUY A ";Y$:INPUT"FOR $400? (Y/N)";X$:IFX$<>"Y"THENGOTO65
260 G=G+1:W=W-400:GOTO65
261 
262 ?"THERE'S SOME WEED HERE THAT SMELLS":?"LIKE GOOD STUFF!!":?:INPUT"WILL YOU SMOKE IT? (Y/N)";X$
263 IFX$="Y"THENGOTO316
264 GOTO65
265 
266 IFW<300THENGOTO187
267 ?"WILL YOU BUY A NEW TRENCHCOAT":INPUT"WITH MORE POCKETS FOR $200? (Y/N)";X$
268 IFX$<>"Y"THENGOTO65
269 I=I+10:W=W-200:GOTO65
270 
271 GOSUB42
272 IFF<8THENGOTO187
273 J=INT((RND(1)*7)+1.5):K=INT(RND(1)*5+.5)
274 IFK=0THENQ=Q+J:Y$="LUDES"
275 IFK=1THENT=T+J:Y$="SPEED"
276 IFK=2THENU=U+J:Y$="WEED"
277 IFK=3THENO=O+J:Y$="ACID"
278 IFK=4THENN=N+J:Y$="HEROIN"
279 IFK=5THENM=M+J:Y$="COKE"
280 ?"YOU FOUND "J"UNITS OF "Y$:?"ON A DEAD DUDE IN THE SUBWAY!":?:GOSUB24:GOTO65
281 
282 ?"THE MARKET HAS BEEN FLOODED":?"WITH CHEAP HOME-MADE ACID!":A=INT((RND(1)*550)+250.5):GOSUB24:GOTO65
283 
284 INPUT"REPAY HOW MUCH?";K:IFK=0THEN?"GET OUT OF HERE, LOSER!":GOSUB22:GOTO65
285 IFK>WTHEN?:?"YOU DON'T HAVE THAT MUCH!":GOSUB22:GOTO129
286 IFK>VTHEN?:?"YOU DON'T OWE THAT MUCH!":GOSUB22:GOTO129
287 W=W-K:V=V-K:?:?"THANK YOU.":GOSUB24:GOTO65
288 
289 ?:J=INT((RND(1)*10000)+4000):INPUT"HOW MUCH DO YOU WANT?";K:?:IFK=0GOTO65
290 IFK<0THEN?"TRYING TO CHEAT? DOUBLE DEBT!":AD=AD+3:V=V*2:GOSUB24:GOSUB52:GOTO65
291 IFK>14000THEN?"HE'S NOT THAT STUPID!":GOSUB24:GOTO65
292 IFK>JTHEN?"HE DOESN'T FEEL LIKE IT.":GOSUB22:GOTO65
293 V=V+K:W=W+K:?:?"HERE'S YOUR MONEY.":?:?"REMEMBER, I BREAK THUMBS.":GOSUB24:GOTO65
294 
295 ?:K=INT((RND(1)*100)+1):INPUT"HOW MUCH?";J:IFJ=0GOTO65
296 IFJ>WTHEN?"YOU DON'T HAVE THAT MUCH CASH.":GOTO295
297 IFK=2THENGOTO300
298 IFJ<0THEN?"YOU TRIED TO ROB THE BANK, BUT BARELY":?"MADE IT OUT WITH NOTHING.":AD=AD+3:GOSUB24:GOTO65
299 
300 E=E+J:W=W-J:?:?"THANK YOU FOR YOUR DEPOSIT.":GOSUB24:GOTO65
301 
302 ?:INPUT"HOW MUCH?";J
303 IFJ<0THEN?"TRY MAKING A DEPOSIT.":GOSUB24:GOTO135
304 IFJ>ETHEN?"YOU DON'T HAVE SUFFICIENT FUNDS.":GOTO302
305 E=E-J:W=W+J:?:?"THANK YOU FOR YOUR BUSINESS.":GOSUB24:GOTO65
306 
307 HOME:VTAB2:HTAB10:?"WELCOME TO DRUGWAR//E":HTAB14:?"VERSION ";RV:VTAB8:HTAB3:?"BASED ON THE CLASSIC TI-BASIC CLONE":HTAB2:?"OF JOHN E. DELL'S 1984 IBM/TRS80 GAME.":VTAB12:HTAB6:?"APPLESOFT VERSION BY:JAY MOORE"
308 VTAB19:INPUT"WOULD YOU LIKE INSTRUCTIONS? (Y/N):";X$:J =RND(-1 *(PEEK(78)+256*PEEK(79))):IFX$="Y"THENGOTO311
309 GOTO63
310 
311 HOME:?:?"THIS IS A GAME OF BUYING AND SELLING.":?"YOUR GOAL IS TO PAY OFF YOUR DEBT AND":?"MAKE AS MUCH MONEY AS POSSIBLE IN A ONE":?"MONTH PERIOD. PRICES FLUCTUATE EVERY DAYAND INTEREST ON YOUR LOAN IS CALCULATED AS WELL."
312 ?:?"IF YOU DEAL TOO HEAVILY, YOU'LL ATTRACT THE ATTENTION OF THE POLICE.":?:?"COMMANDS ARE ENTERED USING THE LETTER   HIGHLIGHTED (L)IKE (S)O. Y IS YES AND   ANYTHING COUNTS AS NO.":GOSUB6:GOTO63
313 
314 HOME:HTAB8:VTAB10:?"PUT A QUARTER IN YOUR ASS":GOSUB22:HTAB7:?"'CAUSE YOU PLAYED YOURSELF!":GOSUB24:GOSUB24:VTAB19:HTAB11:?"DON'T CHEAT SO MUCH.":GOSUB24:GOSUB24:GOSUB24:CLEAR:END
315 
316 GOSUB4:INVERSE:GOSUB8:?"SMOKE WEED":NORMAL:SPEED=50:?"YOU HALLUCINATE ON THE WILDEST TRIP":?"OF YOUR LIFE, STUMBLE ON TO THE TRACKS,":?"AND GET CREAMED BY A TRAIN!":?:?
317 HTAB10:?"JUST SAY NO TO DRUGS!":SPEED=255:GOSUB24:GOSUB22:GOTO323
318 
319 GOSUB4:GOSUB59:GOSUB46:?:?"YOUR SCORE ON A SCALE OF 1 TO 100:";K:?
320 INPUT"WOULD YOU LIKE TO PLAY AGAIN? (Y/N)";X$:IFX$="Y"THENGOTO63
321 ?"DON'T FORGET TO WATCH YOUR BACK!":?:?"THANKS FOR PLAYING.":?"HAVE A NICE DAY"
322 
323 GOSUB4:GOSUB46:?:SPEED=50:?"YOU DIED FROM SMOKING WEED.":?:?:GOSUB24:?"SEE? GAMES ARE TOTALLY FAKE.":SPEED=255:?:INPUT"WOULD YOU LIKE TO PLAY AGAIN?";X$:IFX$= "Y"THENGOTO63
324 CLEAR:END
325 REM DRUGWAR//E - VERSION 1.05
326 REM 5-NOV-2018
327 REM COPYRIGHT 2018 JAY MOORE
328 REM GITLAB.COM/DEWDUDE/DRUGWAR2E
329 REM TWITTER:_NQ4T