10 REM DRUGWAR2EB9.BAS - 17/10/2018 - 05h00
20 REM DRUGWAR//E - BETA 9
30 REM COPYRIGHT 2018 JAY MOORE
40 REM RELEASED UNDER GPL V3
50 REM DRUGWAR2E.SOURCEFORGE.IO
60 REM TWITTER: _NQ4T
70 GOTO 6260
80 REM->TITLEBAR 
90 PRINT ,"DRUGWAR//E",
100 RETURN
110 REM->WAIT 
120 PRINT CHR$(10)
130 INPUT "PRESS ENTER TO CONTINUE.";X$
140 RETURN
150 REM->TIMERA
160 FOR N = 1 TO 500
170 NEXT N
180 RETURN
190 REM->TIMERB
200 FOR N = 1 TO 300
210 NEXT N
220 RETURN
230 REM->HOWMUCHBUY 
240 PRINT "YOU CAN AFFORD ";J
250 PRINT "YOU CAN CARRY  ";F
260 REM->HOWMANYBUY	
270 PRINT CHR$(10)
280 INPUT "HOW MANY? (ENTER 0 CANCEL): ";K
290 IF K=0 GOTO 540
300 IF K>F THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 270
310 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 270
320 RETURN
330 REM->HOWMUCHSELL 
340 PRINT "YOU CAN SELL: ";J
350 PRINT CHR$(10)
360 REM->HOWMANYSELL
370 INPUT "HOW MANY? (ENTER 0 TO CANCEL.): ";K
380 IF K>J THEN PRINT "YOU DON'T HAVE THAT MANY!" : GOTO 370
390 IF K=0 GOTO 540
400 RETURN
410 REM->DAILY 
420 C=INT(RND(1)*12000+16000.5)
430 H=INT(RND(1)*7000+5000.5)
440 A=INT((RND(1)*34+10)*100+.5)
450 Z=INT((RND(1)*42+33)*10+.5)
460 S=INT((RND(1)*15+7)*10+.5)
470 L=INT((RND(1)*4+1)*10+.5)
480 B=INT(RND(1)*20+.5)
490 D=D+1
500 REM->CHECKDAY 
510 IF D >= 31 GOTO 6890
520 RETURN
530 REM->MENU 
540 HOME
550 F=I-(M+N+O+U+T+Q) 
560 GOSUB 90
570 INVERSE : PRINT "DAY:";D,P$, : NORMAL
580 PRINT CHR$(10)
590 PRINT "(C)HECK PRICES"
600 PRINT "(I)NVENTORY"
610 PRINT "(B)UY"
620 PRINT "(S)ELL"
630 PRINT "(J)ET"
640 PRINT "SEE (L)OAN SHARK"
650 PRINT "(V)ISIT BANK"
660 INPUT "PLEASE MAKE YOUR SELECTION: ";X$
670 IF X$ = "C" GOTO 760
680 IF X$ = "I" GOTO 900
690 IF X$ = "B" GOTO 1040
700 IF X$ = "S" GOTO 1790
710 IF X$ = "J" GOTO 2630
720 IF X$ = "L" GOTO 5650
730 IF X$ = "V" GOTO 5960
740 GOTO 540
750 REM->PRICES
760 HOME
770 GOSUB 90
780 INVERSE:PRINT"                 PRICES                 ":NORMAL
790 PRINT CHR$(10)
800 PRINT"COCAINE:","$"C
810 PRINT"HEROIN:","$"H
820 PRINT"ACID:","$"A
830 PRINT"WEED:","$"Z
840 PRINT"SPEED:","$"S
850 PRINT"LUDES:","$"L
860 PRINT"WALLET:","$"W
870 GOSUB 120
880 GOTO 540
890 REM->INVENTORY
900 HOME
910 GOSUB 90
920 INVERSE:PRINT"            INVENTORY                   ":NORMAL
930 PRINT CHR$(10)
940 PRINT"COCAINE:",M
950 PRINT"HEROIN:",N
960 PRINT"ACID:",O
970 PRINT"WEED:",U
980 PRINT"SPEED:",T
990 PRINT"LUDES:",Q
1000 PRINT"FREE SPACE:",F
1010 GOSUB 120
1020 GOTO 540
1030 REM->BUY
1040 HOME
1050 GOSUB 90
1060 INVERSE:PRINT"                  BUY                   ":NORMAL
1070 PRINT CHR$(10)
1080 PRINT"WHAT DO YOU WANT TO BUY?"
1090 PRINT CHR$(10)
1100 PRINT "(C)OCAINE"
1110 PRINT "(H)EROIN"
1120 PRINT "(A)CID"
1130 PRINT "(W)EED"
1140 PRINT "(S)PEED"
1150 PRINT "(L)UDES"
1160 INPUT "ENTER SELECTION: ";X$
1170 IF X$="C" GOTO 1250
1180 IF X$="H" GOTO 1340
1190 IF X$="A" GOTO 1430
1200 IF X$="W" GOTO 1520
1210 IF X$="S" GOTO 1610
1220 IF X$="L" GOTO 1700
1230 GOTO 540
1240 REM->COKEBUY
1250 HOME
1260 GOSUB 90
1270 INVERSE:PRINT"             BUY COCAINE                ":NORMAL
1280 PRINT CHR$(10)
1290 J=INT(W/C) 
1300 GOSUB 240
1310 M=M+K : W=W-(C*K) 
1320 GOTO 540
1330 REM->HERBUY
1340 HOME
1350 GOSUB 90
1360 INVERSE:PRINT"              BUY HEROIN                ":NORMAL
1370 PRINT CHR$(10)
1380 J=INT(W/H)
1390 GOSUB 240
1400 N=N+K : W=W-(H*K)
1410 GOTO 540
1420 REM->ACIDBUY
1430 HOME
1440 GOSUB 90
1450 INVERSE:PRINT"                BUY ACID                 ":NORMAL
1460 PRINT CHR$(10)
1470 J=INT(W/A)
1480 GOSUB 240
1490 O=O+K : W=W-(A*K)
1500 GOTO 540
1510 REM->WEEDBUY
1520 HOME
1530 GOSUB 90
1540 INVERSE:PRINT"                BUY WEED                ":NORMAL
1550 PRINT CHR$(10)
1560 J=INT(W/Z)
1570 GOSUB 240
1580 U=U+K : W=W-(Z*K)
1590 GOTO 540
1600 REM->SPDBUY
1610 HOME
1620 GOSUB 90
1630 INVERSE:PRINT"                BUY SPEED               ":NORMAL
1640 PRINT CHR$(10)
1650 J=INT(W/S)
1660 GOSUB 240
1670 T=T+K : W=W-(S*K)
1680 GOTO 540
1690 REM->LUDBUY
1700 HOME
1710 GOSUB 90
1720 INVERSE:PRINT"                BUY LUDES               ":NORMAL
1730 PRINT CHR$(10)
1740 J=INT(W/L)
1750 GOSUB 240
1760 Q=Q+K : W=W-(L*K)
1770 GOTO 540
1780 REM->SELL
1790 HOME
1800 GOSUB 90
1810 INVERSE:PRINT"                   SELL                ":NORMAL
1820 PRINT CHR$(10)
1830 PRINT "WHAT WOULD YOU LIKE TO SELL?"
1840 PRINT CHR$(10)
1850 PRINT "(C)OCAINE"
1860 PRINT "(H)EROIN"
1870 PRINT "(A)CID"
1880 PRINT "(W)EED"
1890 PRINT "(S)PEED"
1900 PRINT "(L)UDES"
1910 REM->SELLSEL
1920 INPUT "ENTER SELECTION: (0 TO CANCEL)";X$
1930 IF X$="C" GOTO 2030
1940 IF X$="H" GOTO 2130
1950 IF X$="A" GOTO 2230
1960 IF X$="W" GOTO 2330
1970 IF X$="S" GOTO 2430
1980 IF X$="L" GOTO 2530
1990 IF X$="0" GOTO 540
2000 PRINT "INVALID SELECTION!"
2010 GOTO 1920
2020 REM->COKESELL
2030 HOME
2040 GOSUB 90
2050 INVERSE:PRINT"             SELL COCAINE               ":NORMAL
2060 PRINT CHR$(10)
2070 J=M 
2080 GOSUB 340
2090 M=M-K 
2100 W=W+(C*K) 
2110 GOTO 540
2120 REM->HERSELL
2130 HOME
2140 GOSUB 90
2150 INVERSE:PRINT"              SELL HEROIN               ":NORMAL
2160 PRINT CHR$(10)
2170 J=N
2180 GOSUB 340
2190 N=N-K
2200 W=W+(H*K)
2210 GOTO 540
2220 REM->ACIDSELL
2230 HOME
2240 GOSUB 90
2250 INVERSE:PRINT"              SELL  ACID                ":NORMAL
2260 PRINT CHR$(10)
2270 J=O
2280 GOSUB 340
2290 O=O-K
2300 W=W+(A*K)
2310 GOTO 540
2320 REM->WEEDSELL
2330 HOME
2340 GOSUB 90
2350 INVERSE:PRINT"              SELL  WEED                ":NORMAL
2360 PRINT CHR$(10)
2370 J=U
2380 GOSUB 340
2390 U=U-K
2400 W=W+(Z*K)
2410 GOTO 540
2420 REM->SPDSELL
2430 HOME
2440 GOSUB 90
2450 INVERSE:PRINT"             SELL  SPEED                ":NORMAL
2460 PRINT CHR$(10)
2470 J=T
2480 GOSUB 340
2490 T=T-K
2500 W=W+(S*K)
2510 GOTO 540
2520 REM->LUDSELL
2530 HOME
2540 GOSUB 90
2550 INVERSE:PRINT"              SELL  LUDES               ":NORMAL
2560 PRINT CHR$(10)
2570 J=Q
2580 GOSUB 340
2590 Q=Q-K
2600 W=W+(L*K)
2610 GOTO 540
2620 REM->JET
2630 HOME
2640 GOSUB 90
2650 INVERSE:PRINT"                   JET                  ":NORMAL
2660 PRINT CHR$(10)
2670 PRINT "(B)RONX"
2680 PRINT "(G)HETTO"
2690 PRINT "(C)ENTRAL PARK
2700 PRINT "(M)ANHATTEN"
2710 PRINT "CONEY (I)SLAND"
2720 PRINT "BROO(K)LYN"
2730 PRINT "(O)OPS...STAY!"
2740 INPUT "WHERE TO DUDE? ";X$
2750 IF X$="B" THEN Y$ = "THE BRONX" : GOTO 2850
2760 IF X$="G" THEN Y$ = "THE GHETTO" : GOTO 2850
2770 IF X$="C" THEN Y$ = "CENTRAL PARK" : GOTO 2850
2780 IF X$="M" THEN Y$ = "MANHATTEN" : GOTO 2850
2790 IF X$="I" THEN Y$ = "CONEY ISLAND" : GOTO 2850
2800 IF X$="K" THEN Y$ = "BROOKLYN" : GOTO 2850
2810 IF X$="O" THEN GOTO 540
2820 IF X$="COPTEST" THEN B = 5 : GOTO 3810
2830 GOTO 2630
2840 REM->JETB
2850 IF Y$=P$ THEN GOTO 2890
2860 P$ = Y$ 
2870 GOTO 2980
2880 REM->ALREADYTHERE
2890 HOME
2900 GOSUB 90
2910 INVERSE:PRINT"                   JET                  ":NORMAL
2920 PRINT CHR$(10)
2930 PRINT "YOU'RE ALREADY IN:"
2940 PRINT "            ";P$
2950 GOSUB 120
2960 GOTO 2630
2970 REM->SUBWAY
2980 HOME
2990 GOSUB 420
3000 V=INT(V*1.1+.5) 
3010 E=INT(E*1.06+.5) 
3020 GOSUB 90
3030 INVERSE:PRINT"                 SUBWAY                 ":NORMAL
3040 PRINT CHR$(10)
3050 IF B=1 THEN GOTO 3300
3060 IF B=2 THEN GOTO 3350
3070 IF B=3 THEN GOTO 3400
3080 IF B=4 THEN GOTO 3460
3090 IF B=5 THEN GOTO 3460
3100 IF B=6 THEN GOTO 3520
3110 IF B=7 THEN GOTO 3520
3120 IF B=8 THEN GOTO 3580
3130 IF B=9 THEN GOTO 3680
3140 IF B=10 THEN GOTO 3680
3150 IF B=11 THEN GOTO 3680
3160 IF B=12 THEN GOTO 5080
3170 IF B=13 THEN GOTO 5080
3180 IF B=14 THEN GOTO 5230
3190 IF B=15 THEN GOTO 5300
3200 IF B=16 THEN GOTO 5380
3210 IF B=17 THEN GOTO 5540
3220 REM->NOTHINGHAPPENED
3230 REM->NOTHINGHAPPENS	
3240 PRINT CHR$(10) 
3250 PRINT "WELCOME TO ";P$ 
3260 PRINT CHR$(10)
3270 INPUT "PRESS ENTER TO CONTINUE. ";X$
3280 GOTO 540
3290 REM->CHEAPLUDES
3300 PRINT "RIVAL DEALERS ARE SELLING CHEAP LUDES!"
3310 L=2
3320 GOSUB 120
3330 GOTO 540
3340 REM->CHEEPWEED
3350 PRINT "WEED PRICES HAVE BOTTOMED-OUT!"
3360 Z=122
3370 GOSUB 120
3380 GOTO 540
3390 REM->PIGHEROIN
3400 PRINT "PIGS ARE SELLING CHEAP HEROIN"
3410 PRINT "FROM LAST WEEK'S RAID!"
3420 H=INT((RND(1)*1150)+850.5)
3430 GOSUB 120
3440 GOTO 540
3450 REM->HEROINBUST
3460 PRINT "ADDICTS ARE BUYING HEROIN"
3470 PRINT "AT OUTRAGEOUS PRICES!"
3480 H=INT((RND(1)*25000)+18000.5)
3490 GOSUB 120
3500 GOTO 540
3510 REM->COKEBUST
3520 PRINT "PIGS MADE A BIG COKE BUST!"
3530 PRINT "PRICES ARE OUTRAGEOUS!!!!"
3540 C=INT((RND(1)*60000)+80000.5) 
3550 GOSUB 120
3560 GOTO 540
3570 REM->MUGGED
3580 PRINT "YOU GOT MUGGED!"
3590 PRINT CHR$(10)
3600 J=INT(W/3)
3610 J=INT(J*2)
3620 K=INT(W-J)
3630 PRINT "YOU LOST $";K
3640 W=J
3650 GOSUB 120
3660 GOSUB 540
3670 REM->COPS
3680 K=M+N+U+O+T+P 
3690 IF K<50 THEN GOTO 3230
3700 IF B=9 THEN B = 2
3710 IF B=10 THEN B=4
3720 IF B=11 THEN B=5
3730 PRINT "IT'S THE COPS!"
3740 PRINT CHR$(10)
3750 PRINT "OFFICER HARDASS AND ";B-1;" OF HIS"
3760 PRINT "DEPUTIES ARE AFTER YOU!"
3770 PRINT
3780 GOSUB 120
3790 GOTO 3810
3800 REM->POLICE
3810 HOME
3820 GOSUB 90
3830 INVERSE:PRINT"              BEING CHASED!" :NORMAL 
3840 PRINT
3850 PRINT 
3860 PRINT "VIEW (G)UNS"
3870 PRINT "VIEW (D)AMAGE"
3880 PRINT "(N)UMBER OF PIGS"
3890 PRINT "(R)UN"
3900 PRINT "(F)IGHT"
3910 PRINT
3920 INPUT "WHAT DO YOU WANT TO DO? ";X$
3930 IF X$="G" GOTO 4000
3940 IF X$ = "D" GOTO 4100
3950 IF X$ = "N" GOTO 4220
3960 IF X$ = "R" GOTO 4330
3970 IF X$="F" GOTO 4510
3980 GOTO 3810
3990 REM->PGUN
4000 HOME
4010 GOSUB 90
4020 INVERSE:PRINT"              BEING CHASED!" :NORMAL 
4030 PRINT
4040 PRINT 
4050 PRINT "YOU HAVE ";G;" GUNS.
4060 PRINT
4070 GOSUB 120
4080 GOTO 3810
4090 REM->DAMAGE
4100 HOME
4110 GOSUB 90
4120 INVERSE:PRINT"              BEING CHASED!" :NORMAL 
4130 PRINT
4140 PRINT 
4150 PRINT "YOUR CURRENT DAMAGE IS ";BB;"."
4160 PRINT
4170 PRINT "50 AND YOU DIE!"
4180 PRINT
4190 GOSUB 120
4200 GOTO 3810
4210 REM->NCOPS
4220 HOME
4230 GOSUB 90
4240 INVERSE:PRINT"              BEING CHASED!" :NORMAL 
4250 PRINT
4260 PRINT 
4270 PRINT "THERE ARE ";B;" PIGS STILL CHASING YOU!"
4280 PRINT
4290 PRINT
4300 GOSUB 120
4310 GOTO 3810
4320 REM->RUN
4330 HOME
4340 GOSUB 90
4350 INVERSE:PRINT"              BEING CHASED!" :NORMAL 
4360 PRINT
4370 PRINT 
4380 PRINT "RUNNING..."
4390 GOSUB 160
4400 K=INT(RND(1)+.5)
4410 IF K = 0 THEN PRINT "YOU LOST THEM IN AN ALLEY!" : GOTO 4470
4420 PRINT "YOU CAN'T SHAKE THEM!"
4430 PRINT
4440 GOSUB 120
4450 GOTO 3810
4460 REM->LOSERUN
4470 PRINT
4480 GOSUB 120
4490 GOTO 540
4500 REM->FIGHT
4510 IF G<=0 THEN PRINT : PRINT : PRINT "YOU DON'T HAVE ANY GUNS!" : GOSUB 120 : GOTO 3810
4520 HOME
4530 GOSUB 90
4540 INVERSE:PRINT"              BEING CHASED!" :NORMAL 
4550 PRINT
4560 PRINT "YOU SHOOT!"
4570 GOSUB 160
4580 K = RND(1)
4590 K = INT(K+.5)
4600 IF K=0 THEN GOTO 4630
4610 PRINT "YOU GOT ONE!" : B = B-1 : GOTO 4650
4620 REM->MISS 
4630 PRINT "YOU MISSED!"
4640 REM->NEXT
4650 PRINT
4660 PRINT
4670 IF B <= 0 THEN GOTO 4890
4680 GOSUB 200
4690 PRINT "THEY'RE FIRING AT YOU!"
4700 GOSUB 160
4710 K = RND(1)
4720 K = INT(K+.5)
4730 IF K=0 THEN GOTO 4790
4740 PRINT "YOU'VE BEEN HIT!"
4750 BB=BB+3
4760 IF BB >= 50 GOTO 4840
4770 GOTO 4810
4780 REM->THEYMISS
4790 PRINT "THEY MISSED!"
4800 REM->NEXTA
4810 GOSUB 120
4820 GOTO 3810
4830 REM->DED
4840 PRINT
4850 PRINT "YOU'VE BEEN KILLED!"
4860 GOSUB 120
4870 GOTO 6890
4880 REM->ALLGONE
4890 PRINT "YOU KILLED ALL OF THEM!"
4900 PRINT
4910 GOSUB 160
4920 J=INT((RND(1)*1250)+750)
4930 W=W+J
4940 PRINT "YOU FOUND $";J;" ON OFFICER HARDASS'" 
4950 PRINT "CARCASS!"
4960 IF W>=1200 THEN GOTO 5000
4970 GOSUB 120
4980 GOTO 540
4990 REM->DOCTOR
5000 GOSUB 160
5010 PRINT
5020 PRINT "WILL YOU PAY $1000 FOR A DOCTOR"
5030 INPUT "TO SEW YOU UP? (Y/N)";X$
5040 IF X$ <> "Y" THEN GOTO 540
5050 W=W-1000
5060 BB=0
5070 REM->GUNBUY
5080 IF W < 500 THEN GOTO 3230
5090 F=INT(I-(M+N+O+U+T+P))
5100 IF F < 5 THEN GOTO 3230
5110 J=INT(RND(1)*2)
5120 IF J = 0 THEN Y$ = "BARETTA"
5130 IF J = 1 THEN Y$ = "SATURDAY NIGHT SPECIAL"
5140 IF J = 2 THEN Y$ = ".44 MAGNUM"
5150 PRINT "WILL YOU BUY A ";Y$
5160 INPUT "FOR $400? (Y/N)";X$
5170 IF X$ <> "Y" THEN GOTO 540
5180 G = INT(G+1)
5190 W = INT(W-400)
5200 I = INT(I-5) 
5210 GOTO 540
5220 REM->DEDWEED 
5230 PRINT "THERE'S SOME WEED HERE THAT SMELLS"
5240 PRINT "LIKE GOOD STUFF!!"
5250 PRINT CHR$(10)
5260 INPUT "WILL YOU SMOKE IT? (Y/N)";X$
5270 IF X$ = "Y" THEN GOTO 6700
5280 GOTO540
5290 REM->NEWCOAT
5300 IF W<300 THEN RETURN 
5310 PRINT "WILL YOU BUY A NEW TRENCHCOAT"
5320 INPUT "WITH MORE POCKETS FOR $200? (Y/N)";X$
5330 IF X$ <> "Y" THEN GOTO 540
5340 I=INT(I+10)
5350 W=INT(W-200)
5360 GOTO 540
5370 REM->DEDGUY
5380 IF F<8 THEN GOTO 3240
5390 J=INT((RND(1)*7)+1.5)
5400 K=INT(RND(1)*5+.5)
5410 IF K=0 THEN Q=Q+J : Y$ = "LUDES"
5420 IF K=1 THEN T=T+J : Y$ = "SPEED"
5430 IF K=2 THEN U=U+J : Y$ = "WEED"
5440 IF K=3 THEN O=O+J : Y$ = "ACID"
5450 IF K=4 THEN N=N+J : Y$ = "HEROIN"
5460 IF K=5 THEN M=M+J : Y$ = "COCAINE"
5470 PRINT "YOU FOUND ";J;" UNITS OF"
5480 PRINT "         ";Y$
5490 PRINT "ON A DEAD DUDE IN THE SUBWAY!"
5500 PRINT CHR$(10)
5510 GOSUB 120
5520 GOTO 540
5530 REM->HOMEACID
5540 PRINT "THE MARKET HAS BEEN FLOODED"
5550 PRINT "WITH CHEAP HOME-MADE ACID!"
5560 A=INT((RND(1)*550)+250.5)
5570 GOSUB 120
5580 GOTO 540
5590 REM->NOTBRONX
5600 PRINT "YOU NEED TO HEAD TO THE BRONX"
5610 PRINT "TO TAKE CARE OF THIS BUSINESS."
5620 GOSUB 120
5630 GOTO 540
5640 REM->LOAN
5650 HOME
5660 GOSUB 90
5670 INVERSE : PRINT "         LOAN SHARK         ":NORMAL
5680 PRINT CHR$(10)
5690 IF P$ <> "THE BRONX" THEN GOTO 5600
5700 PRINT "YOUR DEBT IS: $";V
5710 PRINT "YOU HAVE: $";W
5720 PRINT CHR$(10)
5730 INPUT "(R)EPAY, (B)ORROW, (L)EAVE: ";X$
5740 IF X$ = "R" THEN GOTO 5790
5750 IF X$ = "B" THEN GOTO 5880
5760 IF X$ = "L" THEN GOTO 540
5770 GOTO 5650
5780 REM->PAYME
5790 INPUT "REPAY HOW MUCH? ";K
5800 IF K>W THEN PRINT "YOU DON'T HAVE THAT MUCH!" : INPUT "PRESS ENTER TO CONTINUE. ";X$ : GOTO 5650
5810 IF K>V THEN PRINT "YOU DON'T OWE THAT MUCH!" : INPUT"PRESS ENTER TO CONTINE. ";X$ : GOTO 5650
5820 W=W-K
5830 V=V-K
5840 PRINT "THANK YOU." 
5850 GOSUB 120
5860 GOTO 540
5870 REM->BORROW
5880 INPUT "HOW MUCH DO YOU WANT? ";K
5890 IF K>5000 THEN PRINT "HE'S NOT THAT STUPID!" : GOTO 5880
5900 V=V+K
5910 W=W+K
5920 PRINT "HERE'S YOUR MONEY." : PRINT CHR$(10) : PRINT "REMEMBER, I BREAK THUMBS."
5930 GOSUB 120
5940 GOTO 540
5950 REM->BANK
5960 HOME
5970 GOSUB 90
5980 INVERSE : PRINT "         BANK O'MURICA         ":NORMAL
5990 PRINT CHR$(10)
6000 IF P$ <> "THE BRONX" THEN GOTO 5600
6010 PRINT "YOUR BALANCE: $";E
6020 PRINT "YOUR WALLET: $";W
6030 PRINT CHR$(10)
6040 INPUT "(D)EPOSIT, (W)ITHDRAW, (L)EAVE: ";X$
6050 IF X$ = "D" THEN GOTO 6100
6060 IF X$ = "W" THEN GOTO 6180
6070 IF X$ = "L" THEN GOTO 540
6080 GOTO 5960
6090 REM->DEPOSIT
6100 INPUT "HOW MUCH? ";J
6110 IF J>W THEN PRINT "YOU DON'T HAVE THAT MUCH CASH." : GOTO 6100
6120 E=E+J
6130 W=W-J
6140 PRINT "THANK YOU FOR YOUR DEPOSIT."
6150 GOSUB 120
6160 GOTO 540
6170 REM->MYMONEY
6180 INPUT "HOW MUCH? ";J
6190 IF J>E THEN PRINT "YOU DON'T HAVE SUFFICIENT FUNDS." : GOTO 6180
6200 E=E-J
6210 W=W+J
6220 PRINT "THANK YOU FOR YOUR BUSINESS."
6230 GOSUB 120
6240 GOTO 540
6250 REM->INSTRUCTIONS
6260 HOME
6270 GOSUB 90
6280 PRINT CHR$(10)
6290 PRINT "WELCOME TO DRUGWAR//E BETA 9"
6300 PRINT CHR$(10)
6310 PRINT CHR$(10)
6320 INPUT "WOULD YOU LIKE INSTRUCTIONS? (Y/N): ";X$
6330 REM->INSERRORHANDLER 
6340 IF X$ = "Y" THEN GOTO 6530
6350 GOTO 6370
6360 REM->GAMESTART 
6370 W=200000
6380 E=0
6390 V=5000
6400 D=0 
6410 P$="THE BRONX"
6420 G=1
6430 I=100
6440 M=0
6450 N=0
6460 O=0
6470 U=0
6480 T=0
6490 Q=0
6500 GOSUB 420
6510 GOTO 540
6520 REM->INST
6530 HOME
6540 GOSUB 90
6550 PRINT CHR$(10)
6560 PRINT "THIS IS A GAME OF BUYING AND SELLING."
6570 PRINT "YOUR GOAL IS TO PAY OFF YOUR DEBT AND"
6580 PRINT "MAKE AS MUCH MONEY AS POSSIBLE IN A ONE"
6590 PRINT "MONTH PERIOD. PRICES FLUCTUATE EVERY DAY"
6600 PRINT "AND INTEREST ON YOUR LOAN IS CALCULATED"
6610 PRINT "AS WELL. IF YOU DEAL TOO HEAVILY, YOU'LL"
6620 PRINT "ATTRACT THE ATTENTION OF THE POLICE.
6630 PRINT CHR$(10)
6640 PRINT "COMMANDS ARE USUALLY THE FIRST LETTER"
6650 PRINT "OF WHAT YOU WANT TO DO. Y = YES AND"
6660 PRINT "N = NO."
6670 INPUT "PRESS ENTER TO CONTINUE.";X$
6680 GOTO 6370
6690 REM->WEEDEND
6700 HOME
6710 GOSUB 90
6720 INVERSE : PRINT "       SMOKE WEED          " : NORMAL
6730 PRINT "YOU HALLUCINATE ON THE WILDEST TRIP"
6740 PRINT "OF YOUR LIFE, STUMBLE ON TO THE TRACKS,"
6750 PRINT "AND GET CREAMED BY A TRAIN!"
6760 PRINT CHR$(10)
6770 PRINT CHR$(10)
6780 PRINT "JUST SAY NO TO DRUGS!"
6790 GOSUB 120
6800 GOTO 7040
6810 REM->SCORECALCULATE
6820 K=(W+E)-V
6830 IF K<0 THEN K=0 : RETURN
6840 K=SQR((K/31.5)+.5)
6850 K=INT(K)
6860 IF K>100 THEN K=100
6870 RETURN
6880 REM->ENDGAME
6890 HOME
6900 GOSUB 90
6910 GOSUB 6820
6920 INVERSE : PRINT "       GAME OVER          " : NORMAL
6930 PRINT CHR$(10)
6940 PRINT "YOUR SCORE ON A SCALE OF 1 TO 100: ";K
6950 PRINT CHR$(10)
6960 INPUT "WOULD YOU LIKE TO PLAY AGAIN? (Y/N)";X$
6970 IF X$ = "Y" THEN GOTO 6370
6980 PRINT "THANKS FOR PLAYING."
6990 PRINT "REMEMBER, WATCH YOUR BACK."
7000 PRINT "HAVE A NICE DAY!"
7010 CLEAR
7020 END
7030 REM->IRONICEND
7040 HOME
7050 GOSUB 90
7060 GOSUB 6820
7070 INVERSE : PRINT "       GAME OVER          " : NORMAL
7080 PRINT CHR$(10)
7090 PRINT "YOUR FINAL SCORE IS: ";K
7100 PRINT CHR$(10)
7110 PRINT "BUT YOU DIED FROM SMOKING WEED? IN A"
7120 PRINT "GAME ABOUT DEALING DRUGS? BUDDY, NO"
7130 PRINT "SCORE CAN REDEEM THAT STUPIDITY."
7140 PRINT CHR$(10)
7150 INPUT "WOULD YOU LIKE TO PLAY AGAIN? ";X$
7160 IF X$= "Y" THEN GOTO 6370
7170 IF X$= "N" THEN PRINT "I DON'T BLAME YOU." : END
7180 PRINT "WHAT? IF YOU'RE THAT DUMB, I'M LEAVING."
7190 CLEAR
7200 END