10 REM DRUGWAR2EV101.BAS - 20/10/2018 - 14h39
20 REM DRUGWAR//E - VERSION 1.01
30 REM 19-OCT-2018
40 REM COPYRIGHT 2018 JAY MOORE
50 REM RELEASED UNDER GPL V3
60 REM DRUGWAR2E.SOURCEFORGE.IO
70 REM TWITTER: _NQ4T
80 GOTO 6850
90 REM->TITLEBAR 
100 HTAB 16 : PRINT "DRUGWAR//E"
110 INVERSE:PRINT"                                        ":NORMAL
120 RETURN
130 REM->WAIT 
140 PRINT CHR$(10)
150 INPUT "PRESS ENTER TO CONTINUE.";X$
160 RETURN
170 REM->TWOFIFTEEN
180 VTAB 2 : HTAB 15
190 RETURN
200 REM->TWOSIXTEEN
210 VTAB 2:HTAB 16
220 RETURN
230 REM->TWOSEVENTEEN
240 VTAB 2:HTAB 17
250 RETURN
260 REM->TWOEIGHTEEN
270 VTAB 2: HTAB 18
280 RETURN
290 REM->TWONINETEEN
300 VTAB 2:HTAB 19
310 RETURN
320 REM->JETALTHERE
330 INVERSE:GOSUB 300:PRINT"JET":NORMAL
340 RETURN
350 REM->TIMERA
360 FOR J = 1 TO 2500
370 NEXT J
380 K = INT(RND(2)+.5)
390 RETURN
400 REM->TIMERB
410 FOR J = 1 TO 1000
420 NEXT J
430 RETURN
440 REM->TIMERC
450 FOR J = 1 TO 2000
460 NEXT J
470 RETURN
480 REM->HOWMUCHBUY 
490 PRINT "YOU CAN AFFORD ";J
500 PRINT "YOU CAN CARRY  ";F
510 REM->HOWMANYBUY	
520 PRINT CHR$(10)
530 INPUT "HOW MANY? (ENTER 0 CANCEL): ";K
540 IF K=0 GOTO 1150
550 IF K>F THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 520
560 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 520
570 RETURN
580 REM->HOWMUCHSELL 
590 PRINT "YOU CAN SELL: ";J
600 PRINT CHR$(10)
610 REM->HOWMANYSELL
620 INPUT "HOW MANY? (ENTER 0 TO CANCEL.): ";K
630 IF K>J THEN PRINT "YOU DON'T HAVE THAT MANY!" : GOTO 620
640 IF K=0 GOTO 1150
650 RETURN
660 REM->FREESPACE
670 F=INT(I-((G*5)-M+N+O+U+T+P))
680 RETURN
690 REM->CHASE
700 INVERSE:GOSUB 180: PRINT"BEING CHASED":NORMAL
710 RETURN
720 REM->GMOD
730 SPEED=100:GOSUB 210:INVERSE:PRINT"GAME OVER":NORMAL:SPEED=255
740 RETURN
750 REM->BRONXCHECK
760 IF P$ = "THE BRONX" THEN RETURN
770 PRINT "YOU NEED TO HEAD TO THE BRONX"
780 PRINT "TO TAKE CARE OF THIS BUSINESS."
790 GOSUB 450
800 GOTO 1150
810 REM->DAILY 
820 C=INT(RND(5)*12000+16000.5)
830 H=INT(RND(5)*7000+5000.5)
840 A=INT((RND(5)*34+10)*100+.5)
850 Z=INT((RND(5)*42+33)*10+.5)
860 S=INT((RND(5)*15+7)*10+.5)
870 L=INT((RND(5)*4+1)*10+.5)
880 B=INT(RND(5)*20+.5)
890 D=D+1
900 REM->CHECKDAY 
910 IF D >= 31 GOTO 7200
920 RETURN
930 REM->SCORECALCULATE
940 K=(W+E)-V
950 IF K<0 THEN K=0 : RETURN
960 K=INT(SQR((K/31.5)+.5))
970 IF K>100 THEN K=100
980 RETURN
990 REM->GAMESTART 
1000 W=2000
1010 E=0
1020 V=5000
1030 P$="THE BRONX"
1040 G=0
1050 I=100
1060 M=0
1070 N=0
1080 O=0
1090 U=0
1100 T=0
1110 Q=0
1120 GOSUB 820
1130 GOTO 1150
1140 REM->MENU 
1150 HOME
1160 GOSUB 670
1170 GOSUB 100
1180 INVERSE : VTAB 2:HTAB 4:PRINT "DAY: "D : VTAB 2:HTAB 18:PRINT"LOCATION: "P$ :NORMAL
1190 PRINT CHR$(10)
1200 PRINT "(C)HECK PRICES"
1210 PRINT "(T)RENCHCOAT"
1220 PRINT "(B)UY"
1230 PRINT "(S)ELL"
1240 PRINT "(J)ET"
1250 PRINT "SEE (L)OAN SHARK"
1260 PRINT "(V)ISIT BANK"
1270 PRINT CHR$(10)
1280 INPUT "PLEASE MAKE YOUR SELECTION: ";X$
1290 IF X$ = "C" GOTO 1380
1300 IF X$ = "T" GOTO 1520
1310 IF X$ = "B" GOTO 1660
1320 IF X$ = "S" GOTO 1870
1330 IF X$ = "J" GOTO 2110
1340 IF X$ = "L" GOTO 2360
1350 IF X$ = "V" GOTO 2500
1360 GOTO 1150
1370 REM->PRICES
1380 HOME
1390 GOSUB 100
1400 INVERSE:GOSUB 270:PRINT"PRICES":NORMAL
1410 PRINT CHR$(10)
1420 PRINT"COCAINE:","$"C
1430 PRINT"HEROIN:","$"H
1440 PRINT"ACID:","$"A
1450 PRINT"WEED:","$"Z
1460 PRINT"SPEED:","$"S
1470 PRINT"LUDES:","$"L
1480 PRINT"WALLET:","$"W
1490 GOSUB 140
1500 GOTO 1150
1510 REM->INVENTORY
1520 HOME
1530 GOSUB 100
1540 INVERSE:GOSUB 210 :PRINT"TRENCHCOAT":NORMAL
1550 PRINT CHR$(10)
1560 PRINT"COCAINE:",M
1570 PRINT"HEROIN:",N
1580 PRINT"ACID:",O
1590 PRINT"WEED:",U
1600 PRINT"SPEED:",T
1610 PRINT"LUDES:",Q
1620 PRINT"FREE SPACE:",F
1630 GOSUB 140
1640 GOTO 1150
1650 REM->BUY
1660 HOME
1670 GOSUB 100
1680 INVERSE:GOSUB 300: PRINT"BUY":NORMAL
1690 PRINT CHR$(10)
1700 PRINT"WHAT DO YOU WANT TO BUY?"
1710 PRINT CHR$(10)
1720 PRINT "(C)OCAINE"
1730 PRINT "(H)EROIN"
1740 PRINT "(A)CID"
1750 PRINT "(W)EED"
1760 PRINT "(S)PEED"
1770 PRINT "(L)UDES"
1780 INPUT "ENTER SELECTION: ";X$
1790 IF X$="C" GOTO 2650
1800 IF X$="H" GOTO 2740
1810 IF X$="A" GOTO 2830
1820 IF X$="W" GOTO 2920
1830 IF X$="S" GOTO 3010
1840 IF X$="L" GOTO 3100
1850 GOTO 1150
1860 REM->SELL
1870 HOME
1880 GOSUB 100
1890 INVERSE: GOSUB 270: PRINT"SELL":NORMAL
1900 PRINT CHR$(10)
1910 PRINT "WHAT WOULD YOU LIKE TO SELL?"
1920 PRINT CHR$(10)
1930 PRINT "(C)OCAINE"
1940 PRINT "(H)EROIN"
1950 PRINT "(A)CID"
1960 PRINT "(W)EED"
1970 PRINT "(S)PEED"
1980 PRINT "(L)UDES"
1990 REM->SELLSEL
2000 INPUT "ENTER SELECTION: (0 TO CANCEL)";X$
2010 IF X$="C" GOTO 3190
2020 IF X$="H" GOTO 3290
2030 IF X$="A" GOTO 3390
2040 IF X$="W" GOTO 3490
2050 IF X$="S" GOTO 3590
2060 IF X$="L" GOTO 3690
2070 IF X$="0" GOTO 1150
2080 PRINT "INVALID SELECTION!"
2090 GOTO 2000
2100 REM->JET
2110 HOME
2120 GOSUB 100
2130 GOSUB 330
2140 PRINT CHR$(10)
2150 PRINT "(B)RONX"
2160 PRINT "(G)HETTO"
2170 PRINT "(C)ENTRAL PARK
2180 PRINT "(M)ANHATTAN"
2190 PRINT "CONEY (I)SLAND"
2200 PRINT "BROO(K)LYN"
2210 PRINT "(O)OPS...STAY!"
2220 INPUT "WHERE TO DUDE? ";X$
2230 IF X$="B" THEN Y$ = "THE BRONX" : GOTO 2320
2240 IF X$="G" THEN Y$ = "THE GHETTO" : GOTO 2320
2250 IF X$="C" THEN Y$ = "CENTRAL PARK" : GOTO 2320
2260 IF X$="M" THEN Y$ = "MANHATTAN" : GOTO 2320
2270 IF X$="I" THEN Y$   = "CONEY ISLAND" : GOTO 2320
2280 IF X$="K" THEN Y$ = "BROOKLYN" : GOTO 2320
2290 IF X$="O" THEN GOTO 1150
2300 GOTO 2110
2310 REM->JETB
2320 IF Y$=P$ THEN GOTO 3790
2330 P$ = Y$  : Y$ = ""
2340 GOTO 3880
2350 REM->LOAN
2360 HOME
2370 GOSUB 100
2380 INVERSE : GOSUB 210:PRINT "LOAN SHARK":NORMAL
2390 PRINT CHR$(10)
2400 GOSUB 760
2410 PRINT "YOUR DEBT IS: $";V
2420 PRINT "YOU HAVE: $";W
2430 PRINT CHR$(10)
2440 INPUT "(R)EPAY, (B)ORROW, (L)EAVE: ";X$
2450 IF X$ = "R" THEN GOTO 6430
2460 IF X$ = "B" THEN GOTO 6520
2470 IF X$ = "L" THEN GOTO 1150
2480 GOTO 2360
2490 REM->BANK
2500 HOME
2510 GOSUB 100
2520 INVERSE : GOSUB 180: PRINT"BANK O'MURICA":NORMAL
2530 PRINT CHR$(10)
2540 GOSUB 760
2550 PRINT "YOUR BALANCE: $";E
2560 PRINT "YOUR WALLET: $";W
2570 PRINT CHR$(10)
2580 INPUT "(D)EPOSIT, (W)ITHDRAW, (L)EAVE: ";X$
2590 IF X$ = "D" THEN GOTO 6650
2600 IF X$ = "W" THEN GOTO 6750
2610 IF X$ = "L" THEN GOTO 1150
2620 IF X$ = EG$ THEN GOTO @EGG
2630 GOTO 2500
2640 REM->COKEBUY
2650 HOME
2660 GOSUB 100
2670 INVERSE:GOSUB 210: PRINT"BUY COCAINE":NORMAL
2680 PRINT CHR$(10)
2690 J=INT(W/C) 
2700 GOSUB 490
2710 M=M+K : W=W-(C*K) 
2720 GOTO 1150
2730 REM->HERBUY
2740 HOME
2750 GOSUB 100
2760 INVERSE:GOSUB 210: PRINT"BUY HEROIN":NORMAL
2770 PRINT CHR$(10)
2780 J=INT(W/H)
2790 GOSUB 490
2800 N=N+K : W=W-(H*K)
2810 GOTO 1150
2820 REM->ACIDBUY
2830 HOME
2840 GOSUB 100
2850 INVERSE:GOSUB 240:PRINT"BUY ACID":NORMAL
2860 PRINT CHR$(10)
2870 J=INT(W/A)
2880 GOSUB 490
2890 O=O+K : W=W-(A*K)
2900 GOTO 1150
2910 REM->WEEDBUY
2920 HOME
2930 GOSUB 100
2940 INVERSE:GOSUB 240: PRINT"BUY WEED":NORMAL
2950 PRINT CHR$(10)
2960 J=INT(W/Z)
2970 GOSUB 490
2980 U=U+K : W=W-(Z*K)
2990 GOTO 1150
3000 REM->SPDBUY
3010 HOME
3020 GOSUB 100
3030 INVERSE:GOSUB 240: PRINT"BUY SPEED":NORMAL
3040 PRINT CHR$(10)
3050 J=INT(W/S)
3060 GOSUB 490
3070 T=T+K : W=W-(S*K)
3080 GOTO 1150
3090 REM->LUDBUY
3100 HOME
3110 GOSUB 100
3120 INVERSE:GOSUB 240: PRINT"BUY LUDES":NORMAL
3130 PRINT CHR$(10)
3140 J=INT(W/L)
3150 GOSUB 490
3160 Q=Q+K : W=W-(L*K)
3170 GOTO 1150
3180 REM->COKESELL
3190 HOME
3200 GOSUB 100
3210 INVERSE:GOSUB 180:PRINT"SELL COCAINE":NORMAL
3220 PRINT CHR$(10)
3230 J=M 
3240 GOSUB 590
3250 M=M-K 
3260 W=W+(C*K) 
3270 GOTO 1150
3280 REM->HERSELL
3290 HOME
3300 GOSUB 100
3310 INVERSE:GOSUB 240:PRINT"SELL HEROIN":NORMAL
3320 PRINT CHR$(10)
3330 J=N
3340 GOSUB 590
3350 N=N-K
3360 W=W+(H*K)
3370 GOTO 1150
3380 REM->ACIDSELL
3390 HOME
3400 GOSUB 100
3410 INVERSE:GOSUB 240: PRINT"SELL ACID":NORMAL
3420 PRINT CHR$(10)
3430 J=O
3440 GOSUB 590
3450 O=O-K
3460 W=W+(A*K)
3470 GOTO 1150
3480 REM->WEEDSELL
3490 HOME
3500 GOSUB 100
3510 INVERSE:GOSUB 240:PRINT"SELL WEED":NORMAL
3520 PRINT CHR$(10)
3530 J=U
3540 GOSUB 590
3550 U=U-K
3560 W=W+(Z*K)
3570 GOTO 1150
3580 REM->SPDSELL
3590 HOME
3600 GOSUB 100
3610 INVERSE:GOSUB 210:PRINT"SELL SPEED":NORMAL
3620 PRINT CHR$(10)
3630 J=T
3640 GOSUB 590
3650 T=T-K
3660 W=W+(S*K)
3670 GOTO 1150
3680 REM->LUDSELL
3690 HOME
3700 GOSUB 100
3710 INVERSE:GOSUB 210:PRINT"SELL LUDES":NORMAL
3720 PRINT CHR$(10)
3730 J=Q
3740 GOSUB 590
3750 Q=Q-K
3760 W=W+(L*K)
3770 GOTO 1150
3780 REM->ALREADYTHERE
3790 HOME
3800 GOSUB 100
3810 GOSUB 330
3820 PRINT CHR$(10)
3830 PRINT "YOU'RE ALREADY IN:"
3840 PRINT "            ";P$
3850 GOSUB 450
3860 GOTO 2110
3870 REM->SUBWAY
3880 HOME
3890 GOSUB 820
3900 V=INT(V*1.1+.5) 
3910 E=INT(E*1.06+.5) 
3920 GOSUB 100
3930 INVERSE:GOSUB 270:PRINT"SUBWAY":NORMAL
3940 PRINT CHR$(10)
3950 IF B=1 THEN GOTO 4200
3960 IF B=2 THEN GOTO 4250
3970 IF B=3 THEN GOTO 4300
3980 IF B=4 THEN GOTO 4360
3990 IF B=5 THEN GOTO 4360
4000 IF B=6 THEN GOTO 4420
4010 IF B=7 THEN GOTO 4420
4020 IF B=8 THEN GOTO 4480
4030 IF B=9 THEN GOTO 4580
4040 IF B=10 THEN GOTO 4580
4050 IF B=11 THEN GOTO 4580
4060 IF B=12 THEN GOTO 5920
4070 IF B=13 THEN GOTO 5920
4080 IF B=14 THEN GOTO 6060
4090 IF B=15 THEN GOTO 6130
4100 IF B=16 THEN GOTO 6210
4110 IF B=17 THEN GOTO 6370
4120 REM->NOTHINGHAPPENED
4130 REM->NOTHINGHAPPENS	
4140 PRINT CHR$(10) 
4150 PRINT "WELCOME TO ";P$ 
4160 PRINT CHR$(10)
4170 GOSUB 450
4180 GOTO 1150
4190 REM->CHEAPLUDES
4200 PRINT "RIVAL DEALERS ARE SELLING CHEAP LUDES!"
4210 L=2
4220 GOSUB 450
4230 GOTO 1150
4240 REM->CHEEPWEED
4250 PRINT "WEED PRICES HAVE BOTTOMED-OUT!"
4260 Z=122
4270 GOSUB 450
4280 GOTO 1150
4290 REM->PIGHEROIN
4300 PRINT "PIGS ARE SELLING CHEAP HEROIN"
4310 PRINT "FROM LAST WEEK'S RAID!"
4320 H=INT((RND(9)*1150)+850.5)
4330 GOSUB 450
4340 GOTO 1150
4350 REM->HEROINBUST
4360 PRINT "ADDICTS ARE BUYING HEROIN"
4370 PRINT "AT OUTRAGEOUS PRICES!"
4380 H=INT((RND(9)*25000)+18000.5)
4390 GOSUB 450
4400 GOTO 1150
4410 REM->COKEBUST
4420 PRINT "PIGS MADE A BIG COKE BUST!"
4430 PRINT "PRICES ARE OUTRAGEOUS!!!!"
4440 C=INT((RND(9)*60000)+80000.5) 
4450 GOSUB 450
4460 GOTO 1150
4470 REM->MUGGED
4480 PRINT "YOU GOT MUGGED!"
4490 PRINT CHR$(10)
4500 J=INT(W/3)
4510 J=INT(J*2)
4520 K=INT(W-J)
4530 PRINT "YOU LOST $";K
4540 W=J
4550 GOSUB 450
4560 GOSUB 1150
4570 REM->COPS
4580 K=M+N+U+O+T+P 
4590 IF K<50 THEN GOTO 4130
4600 IF B=9 THEN B = 2
4610 IF B=10 THEN B=4
4620 IF B=11 THEN B=5
4630 PRINT "IT'S THE COPS!"
4640 PRINT CHR$(10)
4650 PRINT "OFFICER HARDASS AND ";B-1;" OF HIS"
4660 PRINT "DEPUTIES ARE AFTER YOU!"
4670 PRINT
4680 GOSUB 450
4690 GOTO 4710
4700 REM->POLICE
4710 HOME
4720 GOSUB 100
4730 GOSUB 700
4740 PRINT
4750 PRINT 
4760 PRINT "VIEW (G)UNS"
4770 PRINT "VIEW (D)AMAGE"
4780 PRINT "(N)UMBER OF PIGS"
4790 PRINT "(R)UN"
4800 PRINT "(F)IGHT"
4810 PRINT
4820 INPUT "WHAT DO YOU WANT TO DO? ";X$
4830 IF X$="G" GOTO 4900
4840 IF X$ = "D" GOTO 5000
4850 IF X$ = "N" GOTO 5120
4860 IF X$ = "R" GOTO 5230
4870 IF X$="F" GOTO 5400
4880 GOTO 4710
4890 REM->PGUN
4900 HOME
4910 GOSUB 100
4920 GOSUB 700
4930 PRINT
4940 PRINT 
4950 PRINT "YOU HAVE ";G;" GUNS.
4960 PRINT
4970 GOSUB 140
4980 GOTO 4710
4990 REM->DAMAGE
5000 HOME
5010 GOSUB 100
5020 GOSUB 700
5030 PRINT
5040 PRINT 
5050 PRINT "YOUR CURRENT DAMAGE IS ";BB;"."
5060 PRINT
5070 PRINT "50 AND YOU DIE!"
5080 PRINT
5090 GOSUB 140
5100 GOTO 4710
5110 REM->NCOPS
5120 HOME
5130 GOSUB 100
5140 GOSUB 700
5150 PRINT
5160 PRINT 
5170 PRINT "THERE ARE ";B;" PIGS STILL CHASING YOU!"
5180 PRINT
5190 PRINT
5200 GOSUB 140
5210 GOTO 4710
5220 REM->RUN
5230 HOME
5240 GOSUB 100
5250 GOSUB 700
5260 PRINT
5270 PRINT 
5280 PRINT "RUNNING..."
5290 GOSUB 360
5300 IF K = 0 THEN PRINT "YOU LOST THEM IN AN ALLEY!" : GOTO 5360
5310 PRINT "YOU CAN'T SHAKE THEM!"
5320 PRINT
5330 GOSUB 140
5340 GOTO 4710
5350 REM->LOSERUN
5360 PRINT
5370 GOSUB 140
5380 GOTO 1150
5390 REM->FIGHT
5400 IF G<=0 THEN PRINT : PRINT : PRINT "YOU DON'T HAVE ANY GUNS!" : GOSUB 140 : GOTO 4710
5410 HOME
5420 GOSUB 100
5430 GOSUB 700
5440 PRINT
5450 PRINT "YOU SHOOT!"
5460 GOSUB 360
5470 IF K=0 THEN GOTO 5500
5480 PRINT "YOU GOT ONE!" : B = B-1 : GOTO 5520
5490 REM->MISS 
5500 PRINT "YOU MISSED!"
5510 REM->NEXT
5520 PRINT
5530 PRINT
5540 IF B <= 0 THEN GOTO 5740
5550 GOSUB 410
5560 PRINT "THEY'RE FIRING AT YOU!"
5570 GOSUB 360
5580 IF K=0 THEN GOTO 5640
5590 PRINT "YOU'VE BEEN HIT!"
5600 BB=BB+3
5610 IF BB >= 50 GOTO 5690
5620 GOTO 5660
5630 REM->THEYMISS
5640 PRINT "THEY MISSED!"
5650 REM->NEXTA
5660 GOSUB 140
5670 GOTO 4710
5680 REM->DED
5690 PRINT
5700 PRINT "YOU'VE BEEN KILLED!"
5710 GOSUB 140
5720 GOTO 7200
5730 REM->ALLGONE
5740 PRINT "YOU KILLED ALL OF THEM!"
5750 PRINT
5760 GOSUB 360
5770 J=INT(((RND(7)*1250)+750)+.5)
5780 W=W+J
5790 PRINT "YOU FOUND $";J;" ON OFFICER HARDASS'" 
5800 PRINT "CARCASS!"
5810 IF W>=1200 THEN GOTO 5840
5820 GOTO 1150
5830 REM->DOCTOR
5840 GOSUB 450
5850 PRINT
5860 PRINT "WILL YOU PAY $1000 FOR A DOCTOR"
5870 INPUT "TO SEW YOU UP? (Y/N)";X$
5880 IF X$ <> "Y" THEN GOTO 1150
5890 W=W-1000
5900 BB=0
5910 REM->GUNBUY
5920 IF W < 500 THEN GOTO 4130
5930 GOSUB 670
5940 IF F < 5 THEN GOTO 4130
5950 J=INT((RND(4)*2)+.5)
5960 IF J = 0 THEN Y$ = "BARETTA"
5970 IF J = 1 THEN Y$ = "SATURDAY NIGHT SPECIAL"
5980 IF J = 2 THEN Y$ = ".44 MAGNUM"
5990 PRINT "WILL YOU BUY A ";Y$
6000 INPUT "FOR $400? (Y/N)";X$
6010 IF X$ <> "Y" THEN GOTO 1150
6020 G = G+1
6030 W = W-400
6040 GOTO 1150
6050 REM->DEDWEED 
6060 PRINT "THERE'S SOME WEED HERE THAT SMELLS"
6070 PRINT "LIKE GOOD STUFF!!"
6080 PRINT CHR$(10)
6090 INPUT "WILL YOU SMOKE IT? (Y/N)";X$
6100 IF X$ = "Y" THEN GOTO 7070
6110 GOTO1150
6120 REM->NEWCOAT
6130 IF W<300 THEN GOTO 4140
6140 PRINT "WILL YOU BUY A NEW TRENCHCOAT"
6150 INPUT "WITH MORE POCKETS FOR $200? (Y/N)";X$
6160 IF X$ <> "Y" THEN GOTO 1150
6170 I=I+10
6180 W=W-200
6190 GOTO 1150
6200 REM->DEDGUY
6210 IF F<8 THEN GOTO 4140
6220 J=INT((RND(3)*7)+1.5)
6230 K=INT(RND(3)*5+.5)
6240 IF K=0 THEN Q=Q+J : Y$ = "LUDES"
6250 IF K=1 THEN T=T+J : Y$ = "SPEED"
6260 IF K=2 THEN U=U+J : Y$ = "WEED"
6270 IF K=3 THEN O=O+J : Y$ = "ACID"
6280 IF K=4 THEN N=N+J : Y$ = "HEROIN"
6290 IF K=5 THEN M=M+J : Y$ = "COCAINE"
6300 PRINT "YOU FOUND ";J;" UNITS OF"
6310 PRINT "         ";Y$
6320 PRINT "ON A DEAD DUDE IN THE SUBWAY!"
6330 PRINT CHR$(10)
6340 GOSUB 450
6350 GOTO 1150
6360 REM->HOMEACID
6370 PRINT "THE MARKET HAS BEEN FLOODED"
6380 PRINT "WITH CHEAP HOME-MADE ACID!"
6390 A=INT((RND(4)*550)+250.5)
6400 GOSUB 450
6410 GOTO 1150
6420 REM->PAYME
6430 INPUT "REPAY HOW MUCH? ";K
6440 IF K>W THEN PRINT:PRINT "YOU DON'T HAVE THAT MUCH!" : GOSUB 410 : GOTO 2360
6450 IF K>V THEN PRINT:PRINT "YOU DON'T OWE THAT MUCH!" : GOSUB 410 : GOTO 2360
6460 W=W-K
6470 V=V-K
6480 PRINT:PRINT "THANK YOU." 
6490 GOSUB 450
6500 GOTO 1150
6510 REM->BORROW
6520 PRINT CHR$(10)
6530 INPUT "HOW MUCH DO YOU WANT? ";K
6540 PRINT
6550 J=INT((RND(10)*10000)+5000)
6560 IF K>14000 THEN PRINT "HE'S NOT THAT STUPID!" : GOSUB 450 : GOTO 1150
6570 IF K > J THEN PRINT "HE DOESN'T FEEL LIKE IT." : GOSUB 410 : GOTO 1150
6580 V=V+K
6590 W=W+K
6600 PRINT CHR$(10)
6610 PRINT "HERE'S YOUR MONEY." : PRINT CHR$(10) : PRINT "REMEMBER, I BREAK THUMBS."
6620 GOSUB 450
6630 GOTO 1150
6640 REM->DEPOSIT
6650 PRINT CHR$(10)
6660 INPUT "HOW MUCH? ";J
6670 IF J>W THEN PRINT "YOU DON'T HAVE THAT MUCH CASH." : GOTO 6650
6680 E=E+J
6690 W=W-J
6700 PRINT CHR$(10)
6710 PRINT "THANK YOU FOR YOUR DEPOSIT."
6720 GOSUB 450
6730 GOTO 1150
6740 REM->MYMONEY
6750 PRINT CHR$(10)
6760 INPUT "HOW MUCH? ";J
6770 IF J>E THEN PRINT "YOU DON'T HAVE SUFFICIENT FUNDS." : GOTO 6750
6780 E=E-J
6790 W=W+J
6800 PRINT CHR$(10)
6810 PRINT "THANK YOU FOR YOUR BUSINESS."
6820 GOSUB 450
6830 GOTO 1150
6840 REM->INSTRUCTIONS
6850 HOME
6860 VTAB 2:HTAB10:PRINT "WELCOME TO DRUGWAR//E":HTAB14:PRINT"VERSION 1.01"
6870 VTAB 8:HTAB 3:PRINT "BASED ON THE CLASSIC TI-BASIC CLONE":HTAB2:PRINT"OF JOHN E. DELL'S 1984 IBM/TRS80 GAME."
6880 VTAB12:HTAB6:PRINT "APPLESOFT VERSION BY: JAY MOORE"
6890 VTAB19:INPUT "WOULD YOU LIKE INSTRUCTIONS? (Y/N): ";X$
6900 J =RND(-1 *(PEEK(78)+256*PEEK(79)))
6910 IF X$ = "Y" THEN GOTO 6940
6920 GOTO 1000
6930 REM->INST
6940 HOME
6950 GOSUB 100
6960 PRINT CHR$(10)
6970 PRINT "THIS IS A GAME OF BUYING AND SELLING."
6980 PRINT "YOUR GOAL IS TO PAY OFF YOUR DEBT AND"
6990 PRINT "MAKE AS MUCH MONEY AS POSSIBLE IN A ONE"
7000 PRINT "MONTH PERIOD. PRICES FLUCTUATE EVERY DAYAND INTEREST ON YOUR LOAN IS CALCULATED AS WELL."
7010 PRINT:PRINT "IF YOU DEAL TOO HEAVILY, YOU'LL ATTRACT THE ATTENTION OF THE POLICE."
7020 PRINT CHR$(10)
7030 PRINT "COMMANDS ARE ENTERED USING THE LETTER   HIGHLIGHTED (L)IKE (S)O. Y IS YES AND   ANYTHING COUNTS AS NO."
7040 GOSUB 140
7050 GOTO 1000
7060 REM->WEEDEND
7070 HOME
7080 GOSUB 100
7090 INVERSE : GOSUB @TWOSFIFTEEN: PRINT "SMOKE WEED" : NORMAL
7100 SPEED = 50 :PRINT "YOU HALLUCINATE ON THE WILDEST TRIP"
7110 PRINT "OF YOUR LIFE, STUMBLE ON TO THE TRACKS,"
7120 PRINT "AND GET CREAMED BY A TRAIN!"
7130 PRINT CHR$(10)
7140 PRINT CHR$(10)
7150 HTAB 10:PRINT "JUST SAY NO TO DRUGS!":SPEED=255
7160 GOSUB 450
7170 GOSUB 410
7180 GOTO 7350
7190 REM->ENDGAME
7200 HOME
7210 GOSUB 100
7220 GOSUB 940
7230 GOSUB 730
7240 PRINT CHR$(10)
7250 PRINT "YOUR SCORE ON A SCALE OF 1 TO 100: ";K
7260 PRINT CHR$(10)
7270 INPUT "WOULD YOU LIKE TO PLAY AGAIN? (Y/N)";X$
7280 IF X$ = "Y" THEN GOTO 1000
7290 PRINT "THANKS FOR PLAYING."
7300 PRINT "REMEMBER, WATCH YOUR BACK."
7310 PRINT "HAVE A NICE DAY!"
7320 CLEAR
7330 END
7340 REM->IRONICEND
7350 HOME
7360 GOSUB 100
7370 GOSUB 730
7380 PRINT CHR$(10)
7390 SPEED = 50 : PRINT "YOU DIED FROM SMOKING WEED."
7400 PRINT CHR$(10)
7410 PRINT CHR$(10)
7420 GOSUB 450: PRINT"SEE? GAMES ARE TOTALLY FAKE." : SPEED = 255
7430 PRINT CHR$(10)
7440 INPUT "WOULD YOU LIKE TO PLAY AGAIN? ";X$
7450 IF X$= "Y" THEN GOTO 1000
7460 CLEAR
7470 END