10 REM DRUGWAR2EV1.BAS - 19/10/2018 - 21h23
20 REM DRUGWAR//E - VERSION 1.0
30 REM 19-OCT-2018
40 REM COPYRIGHT 2018 JAY MOORE
50 REM RELEASED UNDER GPL V3
60 REM DRUGWAR2E.SOURCEFORGE.IO
70 REM TWITTER: _NQ4T
80 GOTO 6630
90 REM->TITLEBAR 
100 HTAB 16 : PRINT "DRUGWAR//E",
110 RETURN
120 REM->WAIT 
130 PRINT CHR$(10)
140 INPUT "PRESS ENTER TO CONTINUE.";X$
150 RETURN
160 REM->JETALTHERE
170 INVERSE:PRINT"                  JET                   ":NORMAL
180 RETURN
190 REM->TIMERA
200 FOR J = 1 TO 500
210 NEXT J
220 K = INT(RND(2)+.5)
230 RETURN
240 REM->TIMERB
250 FOR J = 1 TO 300
260 NEXT J
270 RETURN
280 REM->TIMERC
290 FOR J = 1 TO 1000
300 NEXT J
310 RETURN
320 REM->HOWMUCHBUY 
330 PRINT "YOU CAN AFFORD ";J
340 PRINT "YOU CAN CARRY  ";F
350 REM->HOWMANYBUY	
360 PRINT CHR$(10)
370 INPUT "HOW MANY? (ENTER 0 CANCEL): ";K
380 IF K=0 GOTO 990
390 IF K>F THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 360
400 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 360
410 RETURN
420 REM->HOWMUCHSELL 
430 PRINT "YOU CAN SELL: ";J
440 PRINT CHR$(10)
450 REM->HOWMANYSELL
460 INPUT "HOW MANY? (ENTER 0 TO CANCEL.): ";K
470 IF K>J THEN PRINT "YOU DON'T HAVE THAT MANY!" : GOTO 460
480 IF K=0 GOTO 990
490 RETURN
500 REM->FREESPACE
510 F=INT(I-(M+N+O+U+T+P))
520 RETURN
530 REM->CHASE
540 INVERSE:PRINT"              BEING CHASED              ":NORMAL
550 RETURN
560 REM->GMOD
570 INVERSE:PRINT"                GAME OVER               ":NORMAL
580 RETURN
590 REM->BRONXCHECK
600 IF P$ = "THE BRONX    " THEN RETURN
610 PRINT "YOU NEED TO HEAD TO THE BRONX"
620 PRINT "TO TAKE CARE OF THIS BUSINESS."
630 GOSUB 290
640 GOTO 990
650 REM->DAILY 
660 C=INT(RND(5)*12000+16000.5)
670 H=INT(RND(5)*7000+5000.5)
680 A=INT((RND(5)*34+10)*100+.5)
690 Z=INT((RND(5)*42+33)*10+.5)
700 S=INT((RND(5)*15+7)*10+.5)
710 L=INT((RND(5)*4+1)*10+.5)
720 B=INT(RND(5)*20+.5)
730 D=D+1
740 REM->CHECKDAY 
750 IF D >= 31 GOTO 6980
760 RETURN
770 REM->SCORECALCULATE
780 K=(W+E)-V
790 IF K<0 THEN K=0 : RETURN
800 K=INT(SQR((K/31.5)+.5))
810 IF K>100 THEN K=100
820 RETURN
830 REM->GAMESTART 
840 W=2000
850 E=0
860 V=5000
870 P$="THE BRONX    "
880 G=0
890 I=100
900 M=0
910 N=0
920 O=0
930 U=0
940 T=0
950 Q=0
960 GOSUB 660
970 GOTO 990
980 REM->MENU 
990 HOME
1000 GOSUB 510
1010 GOSUB 100
1020 INVERSE : PRINT "     DAY: "D"      LOCATION: "P$: NORMAL
1030 PRINT CHR$(10)
1040 PRINT "(C)HECK PRICES"
1050 PRINT "(I)NVENTORY"
1060 PRINT "(B)UY"
1070 PRINT "(S)ELL"
1080 PRINT "(J)ET"
1090 PRINT "SEE (L)OAN SHARK"
1100 PRINT "(V)ISIT BANK"
1110 PRINT CHR$(10)
1120 INPUT "PLEASE MAKE YOUR SELECTION: ";X$
1130 IF X$ = "C" GOTO 1220
1140 IF X$ = "I" GOTO 1360
1150 IF X$ = "B" GOTO 1500
1160 IF X$ = "S" GOTO 1710
1170 IF X$ = "J" GOTO 1950
1180 IF X$ = "L" GOTO 2200
1190 IF X$ = "V" GOTO 2340
1200 GOTO 990
1210 REM->PRICES
1220 HOME
1230 GOSUB 100
1240 INVERSE:PRINT"                 PRICES                  ":NORMAL
1250 PRINT CHR$(10)
1260 PRINT"COCAINE:","$"C
1270 PRINT"HEROIN:","$"H
1280 PRINT"ACID:","$"A
1290 PRINT"WEED:","$"Z
1300 PRINT"SPEED:","$"S
1310 PRINT"LUDES:","$"L
1320 PRINT"WALLET:","$"W
1330 GOSUB 130
1340 GOTO 990
1350 REM->INVENTORY
1360 HOME
1370 GOSUB 100
1380 INVERSE:PRINT"               INVENTORY                ":NORMAL
1390 PRINT CHR$(10)
1400 PRINT"COCAINE:",M
1410 PRINT"HEROIN:",N
1420 PRINT"ACID:",O
1430 PRINT"WEED:",U
1440 PRINT"SPEED:",T
1450 PRINT"LUDES:",Q
1460 PRINT"FREE SPACE:",F
1470 GOSUB 130
1480 GOTO 990
1490 REM->BUY
1500 HOME
1510 GOSUB 100
1520 INVERSE:PRINT"                  BUY                   ":NORMAL
1530 PRINT CHR$(10)
1540 PRINT"WHAT DO YOU WANT TO BUY?"
1550 PRINT CHR$(10)
1560 PRINT "(C)OCAINE"
1570 PRINT "(H)EROIN"
1580 PRINT "(A)CID"
1590 PRINT "(W)EED"
1600 PRINT "(S)PEED"
1610 PRINT "(L)UDES"
1620 INPUT "ENTER SELECTION: ";X$
1630 IF X$="C" GOTO 2480
1640 IF X$="H" GOTO 2570
1650 IF X$="A" GOTO 2660
1660 IF X$="W" GOTO 2750
1670 IF X$="S" GOTO 2840
1680 IF X$="L" GOTO 2930
1690 GOTO 990
1700 REM->SELL
1710 HOME
1720 GOSUB 100
1730 INVERSE:PRINT"                 SELL                   ":NORMAL
1740 PRINT CHR$(10)
1750 PRINT "WHAT WOULD YOU LIKE TO SELL?"
1760 PRINT CHR$(10)
1770 PRINT "(C)OCAINE"
1780 PRINT "(H)EROIN"
1790 PRINT "(A)CID"
1800 PRINT "(W)EED"
1810 PRINT "(S)PEED"
1820 PRINT "(L)UDES"
1830 REM->SELLSEL
1840 INPUT "ENTER SELECTION: (0 TO CANCEL)";X$
1850 IF X$="C" GOTO 3020
1860 IF X$="H" GOTO 3120
1870 IF X$="A" GOTO 3220
1880 IF X$="W" GOTO 3320
1890 IF X$="S" GOTO 3420
1900 IF X$="L" GOTO 3520
1910 IF X$="0" GOTO 990
1920 PRINT "INVALID SELECTION!"
1930 GOTO 1840
1940 REM->JET
1950 HOME
1960 GOSUB 100
1970 GOSUB 170
1980 PRINT CHR$(10)
1990 PRINT "(B)RONX"
2000 PRINT "(G)HETTO"
2010 PRINT "(C)ENTRAL PARK
2020 PRINT "(M)ANHATTAN"
2030 PRINT "CONEY (I)SLAND"
2040 PRINT "BROO(K)LYN"
2050 PRINT "(O)OPS...STAY!"
2060 INPUT "WHERE TO DUDE? ";X$
2070 IF X$="B" THEN Y$ = "THE BRONX    " : GOTO 2160
2080 IF X$="G" THEN Y$ = "THE GHETTO   " : GOTO 2160
2090 IF X$="C" THEN Y$ = "CENTRAL PARK " : GOTO 2160
2100 IF X$="M" THEN Y$ = "MANHATTAN    " : GOTO 2160
2110 IF X$="I" THEN Y$   = "CONEY ISLAND " : GOTO 2160
2120 IF X$="K" THEN Y$ = "BROOKLYN     " : GOTO 2160
2130 IF X$="O" THEN GOTO 990
2140 GOTO 1950
2150 REM->JETB
2160 IF Y$=P$ THEN GOTO 3620
2170 P$ = Y$  : Y$ = ""
2180 GOTO 3710
2190 REM->LOAN
2200 HOME
2210 GOSUB 100
2220 INVERSE : PRINT "               LOAN SHARK               ":NORMAL
2230 PRINT CHR$(10)
2240 GOSUB 600
2250 PRINT "YOUR DEBT IS: $";V
2260 PRINT "YOU HAVE: $";W
2270 PRINT CHR$(10)
2280 INPUT "(R)EPAY, (B)ORROW, (L)EAVE: ";X$
2290 IF X$ = "R" THEN GOTO 6270
2300 IF X$ = "B" THEN GOTO 6360
2310 IF X$ = "L" THEN GOTO 990
2320 GOTO 2200
2330 REM->BANK
2340 HOME
2350 GOSUB 100
2360 INVERSE : PRINT"              BANK O'MURICA             ":NORMAL
2370 PRINT CHR$(10)
2380 GOSUB 600
2390 PRINT "YOUR BALANCE: $";E
2400 PRINT "YOUR WALLET: $";W
2410 PRINT CHR$(10)
2420 INPUT "(D)EPOSIT, (W)ITHDRAW, (L)EAVE: ";X$
2430 IF X$ = "D" THEN GOTO 6470
2440 IF X$ = "W" THEN GOTO 6550
2450 IF X$ = "L" THEN GOTO 990
2460 GOTO 2340
2470 REM->COKEBUY
2480 HOME
2490 GOSUB 100
2500 INVERSE:PRINT"               BUY COCAINE              ":NORMAL
2510 PRINT CHR$(10)
2520 J=W/C 
2530 GOSUB 330
2540 M=M+K : W=W-(C*K) 
2550 GOTO 990
2560 REM->HERBUY
2570 HOME
2580 GOSUB 100
2590 INVERSE:PRINT"               BUY HEROIN               ":NORMAL
2600 PRINT CHR$(10)
2610 J=W/H
2620 GOSUB 330
2630 N=N+K : W=W-(H*K)
2640 GOTO 990
2650 REM->ACIDBUY
2660 HOME
2670 GOSUB 100
2680 INVERSE:PRINT"                 BUY ACID               ":NORMAL
2690 PRINT CHR$(10)
2700 J=W/A
2710 GOSUB 330
2720 O=O+K : W=W-(A*K)
2730 GOTO 990
2740 REM->WEEDBUY
2750 HOME
2760 GOSUB 100
2770 INVERSE:PRINT"                 BUY WEED               ":NORMAL
2780 PRINT CHR$(10)
2790 J=W/Z
2800 GOSUB 330
2810 U=U+K : W=W-(Z*K)
2820 GOTO 990
2830 REM->SPDBUY
2840 HOME
2850 GOSUB 100
2860 INVERSE:PRINT"                BUY SPEED               ":NORMAL
2870 PRINT CHR$(10)
2880 J=W/S
2890 GOSUB 330
2900 T=T+K : W=W-(S*K)
2910 GOTO 990
2920 REM->LUDBUY
2930 HOME
2940 GOSUB 100
2950 INVERSE:PRINT"               BUY LUDES                ":NORMAL
2960 PRINT CHR$(10)
2970 J=W/L
2980 GOSUB 330
2990 Q=Q+K : W=W-(L*K)
3000 GOTO 990
3010 REM->COKESELL
3020 HOME
3030 GOSUB 100
3040 INVERSE:PRINT"              SELL COCAINE              ":NORMAL
3050 PRINT CHR$(10)
3060 J=M 
3070 GOSUB 430
3080 M=M-K 
3090 W=W+(C*K) 
3100 GOTO 990
3110 REM->HERSELL
3120 HOME
3130 GOSUB 100
3140 INVERSE:PRINT"               SELL HEROIN              ":NORMAL
3150 PRINT CHR$(10)
3160 J=N
3170 GOSUB 430
3180 N=N-K
3190 W=W+(H*K)
3200 GOTO 990
3210 REM->ACIDSELL
3220 HOME
3230 GOSUB 100
3240 INVERSE:PRINT"                SELL ACID               ":NORMAL
3250 PRINT CHR$(10)
3260 J=O
3270 GOSUB 430
3280 O=O-K
3290 W=W+(A*K)
3300 GOTO 990
3310 REM->WEEDSELL
3320 HOME
3330 GOSUB 100
3340 INVERSE:PRINT"                SELL WEED               ":NORMAL
3350 PRINT CHR$(10)
3360 J=U
3370 GOSUB 430
3380 U=U-K
3390 W=W+(Z*K)
3400 GOTO 990
3410 REM->SPDSELL
3420 HOME
3430 GOSUB 100
3440 INVERSE:PRINT"               SELL SPEED               ":NORMAL
3450 PRINT CHR$(10)
3460 J=T
3470 GOSUB 430
3480 T=T-K
3490 W=W+(S*K)
3500 GOTO 990
3510 REM->LUDSELL
3520 HOME
3530 GOSUB 100
3540 INVERSE:PRINT"                SELL LUDES              ":NORMAL
3550 PRINT CHR$(10)
3560 J=Q
3570 GOSUB 430
3580 Q=Q-K
3590 W=W+(L*K)
3600 GOTO 990
3610 REM->ALREADYTHERE
3620 HOME
3630 GOSUB 100
3640 GOSUB 170
3650 PRINT CHR$(10)
3660 PRINT "YOU'RE ALREADY IN:"
3670 PRINT "            ";P$
3680 GOSUB 290
3690 GOTO 1950
3700 REM->SUBWAY
3710 HOME
3720 GOSUB 660
3730 V=INT(V*1.1+.5) 
3740 E=INT(E*1.06+.5) 
3750 GOSUB 100
3760 INVERSE:PRINT"                 SUBWAY                 ":NORMAL
3770 PRINT CHR$(10)
3780 IF B=1 THEN GOTO 4030
3790 IF B=2 THEN GOTO 4080
3800 IF B=3 THEN GOTO 4130
3810 IF B=4 THEN GOTO 4190
3820 IF B=5 THEN GOTO 4190
3830 IF B=6 THEN GOTO 4250
3840 IF B=7 THEN GOTO 4250
3850 IF B=8 THEN GOTO 4310
3860 IF B=9 THEN GOTO 4410
3870 IF B=10 THEN GOTO 4410
3880 IF B=11 THEN GOTO 4410
3890 IF B=12 THEN GOTO 5750
3900 IF B=13 THEN GOTO 5750
3910 IF B=14 THEN GOTO 5900
3920 IF B=15 THEN GOTO 5970
3930 IF B=16 THEN GOTO 6050
3940 IF B=17 THEN GOTO 6210
3950 REM->NOTHINGHAPPENED
3960 REM->NOTHINGHAPPENS	
3970 PRINT CHR$(10) 
3980 PRINT "WELCOME TO ";P$ 
3990 PRINT CHR$(10)
4000 GOSUB 290
4010 GOTO 990
4020 REM->CHEAPLUDES
4030 PRINT "RIVAL DEALERS ARE SELLING CHEAP LUDES!"
4040 L=2
4050 GOSUB 290
4060 GOTO 990
4070 REM->CHEEPWEED
4080 PRINT "WEED PRICES HAVE BOTTOMED-OUT!"
4090 Z=122
4100 GOSUB 290
4110 GOTO 990
4120 REM->PIGHEROIN
4130 PRINT "PIGS ARE SELLING CHEAP HEROIN"
4140 PRINT "FROM LAST WEEK'S RAID!"
4150 H=INT((RND(9)*1150)+850.5)
4160 GOSUB 290
4170 GOTO 990
4180 REM->HEROINBUST
4190 PRINT "ADDICTS ARE BUYING HEROIN"
4200 PRINT "AT OUTRAGEOUS PRICES!"
4210 H=INT((RND(9)*25000)+18000.5)
4220 GOSUB 290
4230 GOTO 990
4240 REM->COKEBUST
4250 PRINT "PIGS MADE A BIG COKE BUST!"
4260 PRINT "PRICES ARE OUTRAGEOUS!!!!"
4270 C=INT((RND(9)*60000)+80000.5) 
4280 GOSUB 290
4290 GOTO 990
4300 REM->MUGGED
4310 PRINT "YOU GOT MUGGED!"
4320 PRINT CHR$(10)
4330 J=INT(W/3)
4340 J=INT(J*2)
4350 K=INT(W-J)
4360 PRINT "YOU LOST $";K
4370 W=J
4380 GOSUB 290
4390 GOSUB 990
4400 REM->COPS
4410 K=M+N+U+O+T+P 
4420 IF K<50 THEN GOTO 3960
4430 IF B=9 THEN B = 2
4440 IF B=10 THEN B=4
4450 IF B=11 THEN B=5
4460 PRINT "IT'S THE COPS!"
4470 PRINT CHR$(10)
4480 PRINT "OFFICER HARDASS AND ";B-1;" OF HIS"
4490 PRINT "DEPUTIES ARE AFTER YOU!"
4500 PRINT
4510 GOSUB 290
4520 GOTO 4540
4530 REM->POLICE
4540 HOME
4550 GOSUB 100
4560 GOSUB 540
4570 PRINT
4580 PRINT 
4590 PRINT "VIEW (G)UNS"
4600 PRINT "VIEW (D)AMAGE"
4610 PRINT "(N)UMBER OF PIGS"
4620 PRINT "(R)UN"
4630 PRINT "(F)IGHT"
4640 PRINT
4650 INPUT "WHAT DO YOU WANT TO DO? ";X$
4660 IF X$="G" GOTO 4730
4670 IF X$ = "D" GOTO 4830
4680 IF X$ = "N" GOTO 4950
4690 IF X$ = "R" GOTO 5060
4700 IF X$="F" GOTO 5230
4710 GOTO 4540
4720 REM->PGUN
4730 HOME
4740 GOSUB 100
4750 GOSUB 540
4760 PRINT
4770 PRINT 
4780 PRINT "YOU HAVE ";G;" GUNS.
4790 PRINT
4800 GOSUB 130
4810 GOTO 4540
4820 REM->DAMAGE
4830 HOME
4840 GOSUB 100
4850 GOSUB 540
4860 PRINT
4870 PRINT 
4880 PRINT "YOUR CURRENT DAMAGE IS ";BB;"."
4890 PRINT
4900 PRINT "50 AND YOU DIE!"
4910 PRINT
4920 GOSUB 130
4930 GOTO 4540
4940 REM->NCOPS
4950 HOME
4960 GOSUB 100
4970 GOSUB 540
4980 PRINT
4990 PRINT 
5000 PRINT "THERE ARE ";B;" PIGS STILL CHASING YOU!"
5010 PRINT
5020 PRINT
5030 GOSUB 130
5040 GOTO 4540
5050 REM->RUN
5060 HOME
5070 GOSUB 100
5080 GOSUB 540
5090 PRINT
5100 PRINT 
5110 PRINT "RUNNING..."
5120 GOSUB 200
5130 IF K = 0 THEN PRINT "YOU LOST THEM IN AN ALLEY!" : GOTO 5190
5140 PRINT "YOU CAN'T SHAKE THEM!"
5150 PRINT
5160 GOSUB 130
5170 GOTO 4540
5180 REM->LOSERUN
5190 PRINT
5200 GOSUB 130
5210 GOTO 990
5220 REM->FIGHT
5230 IF G<=0 THEN PRINT : PRINT : PRINT "YOU DON'T HAVE ANY GUNS!" : GOSUB 130 : GOTO 4540
5240 HOME
5250 GOSUB 100
5260 GOSUB 540
5270 PRINT
5280 PRINT "YOU SHOOT!"
5290 GOSUB 200
5300 IF K=0 THEN GOTO 5330
5310 PRINT "YOU GOT ONE!" : B = B-1 : GOTO 5350
5320 REM->MISS 
5330 PRINT "YOU MISSED!"
5340 REM->NEXT
5350 PRINT
5360 PRINT
5370 IF B <= 0 THEN GOTO 5570
5380 GOSUB 250
5390 PRINT "THEY'RE FIRING AT YOU!"
5400 GOSUB 200
5410 IF K=0 THEN GOTO 5470
5420 PRINT "YOU'VE BEEN HIT!"
5430 BB=BB+3
5440 IF BB >= 50 GOTO 5520
5450 GOTO 5490
5460 REM->THEYMISS
5470 PRINT "THEY MISSED!"
5480 REM->NEXTA
5490 GOSUB 130
5500 GOTO 4540
5510 REM->DED
5520 PRINT
5530 PRINT "YOU'VE BEEN KILLED!"
5540 GOSUB 130
5550 GOTO 6980
5560 REM->ALLGONE
5570 PRINT "YOU KILLED ALL OF THEM!"
5580 PRINT
5590 GOSUB 200
5600 J=INT(((RND(7)*1250)+750)+.5)
5610 W=W+J
5620 PRINT "YOU FOUND $";J;" ON OFFICER HARDASS'" 
5630 PRINT "CARCASS!"
5640 IF W>=1200 THEN GOTO 5670
5650 GOTO 990
5660 REM->DOCTOR
5670 GOSUB 290
5680 PRINT
5690 PRINT "WILL YOU PAY $1000 FOR A DOCTOR"
5700 INPUT "TO SEW YOU UP? (Y/N)";X$
5710 IF X$ <> "Y" THEN GOTO 990
5720 W=W-1000
5730 BB=0
5740 REM->GUNBUY
5750 IF W < 500 THEN GOTO 3960
5760 GOSUB 510
5770 IF F < 5 THEN GOTO 3960
5780 J=INT((RND(4)*2)+.5)
5790 IF J = 0 THEN Y$ = "BARETTA"
5800 IF J = 1 THEN Y$ = "SATURDAY NIGHT SPECIAL"
5810 IF J = 2 THEN Y$ = ".44 MAGNUM"
5820 PRINT "WILL YOU BUY A ";Y$
5830 INPUT "FOR $400? (Y/N)";X$
5840 IF X$ <> "Y" THEN GOTO 990
5850 G = G+1
5860 W = W-400
5870 I = INT(I-5) 
5880 GOTO 990
5890 REM->DEDWEED 
5900 PRINT "THERE'S SOME WEED HERE THAT SMELLS"
5910 PRINT "LIKE GOOD STUFF!!"
5920 PRINT CHR$(10)
5930 INPUT "WILL YOU SMOKE IT? (Y/N)";X$
5940 IF X$ = "Y" THEN GOTO 6850
5950 GOTO990
5960 REM->NEWCOAT
5970 IF W<300 THEN RETURN 
5980 PRINT "WILL YOU BUY A NEW TRENCHCOAT"
5990 INPUT "WITH MORE POCKETS FOR $200? (Y/N)";X$
6000 IF X$ <> "Y" THEN GOTO 990
6010 I=I+10
6020 W=W-200
6030 GOTO 990
6040 REM->DEDGUY
6050 IF F<8 THEN GOTO 3970
6060 J=INT((RND(3)*7)+1.5)
6070 K=INT(RND(3)*5+.5)
6080 IF K=0 THEN Q=Q+J : Y$ = "LUDES"
6090 IF K=1 THEN T=T+J : Y$ = "SPEED"
6100 IF K=2 THEN U=U+J : Y$ = "WEED"
6110 IF K=3 THEN O=O+J : Y$ = "ACID"
6120 IF K=4 THEN N=N+J : Y$ = "HEROIN"
6130 IF K=5 THEN M=M+J : Y$ = "COCAINE"
6140 PRINT "YOU FOUND ";J;" UNITS OF"
6150 PRINT "         ";Y$
6160 PRINT "ON A DEAD DUDE IN THE SUBWAY!"
6170 PRINT CHR$(10)
6180 GOSUB 290
6190 GOTO 990
6200 REM->HOMEACID
6210 PRINT "THE MARKET HAS BEEN FLOODED"
6220 PRINT "WITH CHEAP HOME-MADE ACID!"
6230 A=INT((RND(4)*550)+250.5)
6240 GOSUB 290
6250 GOTO 990
6260 REM->PAYME
6270 INPUT "REPAY HOW MUCH? ";K
6280 IF K>W THEN PRINT:PRINT "YOU DON'T HAVE THAT MUCH!" : GOSUB 250 : GOTO 2200
6290 IF K>V THEN PRINT:PRINT "YOU DON'T OWE THAT MUCH!" : GOSUB 250 : GOTO 2200
6300 W=W-K
6310 V=V-K
6320 PRINT:PRINT "THANK YOU." 
6330 GOSUB 290
6340 GOTO 990
6350 REM->BORROW
6360 INPUT "HOW MUCH DO YOU WANT? ";K
6370 PRINT
6380 J=INT((RND(10)*10000)+5000)
6390 IF K>14000 THEN PRINT "HE'S NOT THAT STUPID!" : GOSUB 290 : GOTO 990
6400 IF K > J THEN PRINT "HE DOESN'T FEEL LIKE IT." : GOSUB 250 : GOTO 990
6410 V=V+K
6420 W=W+K
6430 PRINT "HERE'S YOUR MONEY." : PRINT CHR$(10) : PRINT "REMEMBER, I BREAK THUMBS."
6440 GOSUB 290
6450 GOTO 990
6460 REM->DEPOSIT
6470 INPUT "HOW MUCH? ";J
6480 IF J>W THEN PRINT "YOU DON'T HAVE THAT MUCH CASH." : GOTO 6470
6490 E=E+J
6500 W=W-J
6510 PRINT "THANK YOU FOR YOUR DEPOSIT."
6520 GOSUB 290
6530 GOTO 990
6540 REM->MYMONEY
6550 INPUT "HOW MUCH? ";J
6560 IF J>E THEN PRINT "YOU DON'T HAVE SUFFICIENT FUNDS." : GOTO 6550
6570 E=E-J
6580 W=W+J
6590 PRINT "THANK YOU FOR YOUR BUSINESS."
6600 GOSUB 290
6610 GOTO 990
6620 REM->INSTRUCTIONS
6630 HOME
6640 VTAB 2:HTAB10:PRINT "WELCOME TO DRUGWAR//E":HTAB15:PRINT"VERSION 1.0"
6650 VTAB 8:HTAB 3:PRINT "BASED ON THE CLASSIC TI-BASIC CLONE":HTAB2:PRINT"OF JOHN E. DELL'S 1984 IBM/TRS80 GAME."
6660 VTAB12:HTAB6:PRINT "APPLESOFT VERSION BY: JAY MOORE"
6670 VTAB19:INPUT "WOULD YOU LIKE INSTRUCTIONS? (Y/N): ";X$
6680 J =RND(-1 *(PEEK(78)+256*PEEK(79)))
6690 IF X$ = "Y" THEN GOTO 6720
6700 GOTO 840
6710 REM->INST
6720 HOME
6730 GOSUB 100
6740 PRINT CHR$(10)
6750 PRINT "THIS IS A GAME OF BUYING AND SELLING."
6760 PRINT "YOUR GOAL IS TO PAY OFF YOUR DEBT AND"
6770 PRINT "MAKE AS MUCH MONEY AS POSSIBLE IN A ONE"
6780 PRINT "MONTH PERIOD. PRICES FLUCTUATE EVERY DAYAND INTEREST ON YOUR LOAN IS CALCULATED AS WELL."
6790 PRINT:PRINT "IF YOU DEAL TOO HEAVILY, YOU'LL ATTRACT THE ATTENTION OF THE POLICE."
6800 PRINT CHR$(10)
6810 PRINT "COMMANDS ARE ENTERED USING THE LETTER   HIGHLIGHTED (L)IKE (S)O. Y IS YES AND   ANYTHING COUNTS AS NO."
6820 GOSUB 130
6830 GOTO 840
6840 REM->WEEDEND
6850 HOME
6860 GOSUB 100
6870 INVERSE : PRINT "              SMOKE WEED                " : NORMAL
6880 PRINT "YOU HALLUCINATE ON THE WILDEST TRIP"
6890 PRINT "OF YOUR LIFE, STUMBLE ON TO THE TRACKS,"
6900 PRINT "AND GET CREAMED BY A TRAIN!"
6910 PRINT CHR$(10)
6920 PRINT CHR$(10)
6930 PRINT "JUST SAY NO TO DRUGS!"
6940 GOSUB 290
6950 GOSUB 250
6960 GOTO 7130
6970 REM->ENDGAME
6980 HOME
6990 GOSUB 100
7000 GOSUB 780
7010 GOSUB 570
7020 PRINT CHR$(10)
7030 PRINT "YOUR SCORE ON A SCALE OF 1 TO 100: ";K
7040 PRINT CHR$(10)
7050 INPUT "WOULD YOU LIKE TO PLAY AGAIN? (Y/N)";X$
7060 IF X$ = "Y" THEN GOTO 840
7070 PRINT "THANKS FOR PLAYING."
7080 PRINT "REMEMBER, WATCH YOUR BACK."
7090 PRINT "HAVE A NICE DAY!"
7100 CLEAR
7110 END
7120 REM->IRONICEND
7130 HOME
7140 GOSUB 100
7150 GOSUB 780
7160 GOSUB 570
7170 PRINT CHR$(10)
7180 PRINT "YOUR FINAL SCORE IS: ";K
7190 PRINT CHR$(10)
7200 GOSUB 290
7210 PRINT "BUT YOU DIED FROM SMOKING WEED?":GOSUB 290:PRINT "IN A"
7220 PRINT "GAME ABOUT DEALING DRUGS?":GOSUB 250: PRINT"BUDDY, NO"
7230 PRINT "SCORE CAN REDEEM THAT STUPIDITY."
7240 PRINT CHR$(10)
7250 INPUT "WOULD YOU LIKE TO PLAY AGAIN? ";X$
7260 IF X$= "Y" THEN GOTO 840
7270 IF X$= "N" THEN PRINT "I DON'T BLAME YOU." : END
7280 PRINT "WHAT? IF YOU'RE THAT DUMB, I'M LEAVING."
7290 CLEAR
7300 END