You cannot select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
618 lines
19 KiB
QBasic
618 lines
19 KiB
QBasic
10 REM DRUGWAR.BAS - 08/10/2018 - 23h57
|
|
20 GOTO 5040:REM GO->INSTRUCTIONS
|
|
30 REM->TITLEBAR
|
|
40 PRINT " DRUGWAR//E "
|
|
50 RETURN
|
|
60 REM->WAIT
|
|
70 PRINT CHR$(10)
|
|
80 INPUT "PRESS ENTER TO CONTINUE.";X$
|
|
90 RETURN
|
|
100 REM->HOWMUCHBUY
|
|
110 PRINT "YOU CAN AFFORD ";J
|
|
120 PRINT "YOU CAN CARRY ";FS
|
|
130 PRINT CHR$(10)
|
|
140 INPUT "HOW MANY? (ENTER 0 CANCEL): ";K
|
|
150 GOSUB 260:REM GO->NOBUYSELL
|
|
160 RETURN
|
|
170 REM->HOWMUCHSELL
|
|
180 PRINT "YOU CAN SELL: ";J
|
|
190 PRINT CHR$(10)
|
|
200 REM->HOWMANYSELL
|
|
210 INPUT "HOW MANY? (ENTER 0 TO CANCEL.): ";K
|
|
220 IF K>J THEN PRINT "YOU DON'T HAVE THAT MANY!" : GOTO 210:REM GO->HOWMANYSELL
|
|
230 GOSUB 260:REM GO->NOBUYSELL
|
|
240 RETURN
|
|
250 REM->NOBUYSELL
|
|
260 IF K=0 GOTO 1710:REM GO->MENU
|
|
270 RETURN
|
|
280 REM->STATUSBAR
|
|
290 INVERSE:PRINT "DAY: ";D,P$:NORMAL
|
|
300 PRINT CHR$(10)
|
|
310 RETURN
|
|
320 REM->FREESPACE
|
|
330 FS=INT(IN-(CI+HI+AI+WI+SI+LI)+(GN*5))
|
|
340 RETURN
|
|
350 REM->DAILY
|
|
360 C=INT(RND(1)*12000+16000.5)
|
|
370 H=INT(RND(1)*7000+5000.5)
|
|
380 A=INT((RND(1)*34+10)*100+.5)
|
|
390 W=INT((RND(1)*42+33)*10+.5)
|
|
400 S=INT((RND(1)*15+7)*10+.5)
|
|
410 L=INT((RND(1)*4+1)*10+.5)
|
|
420 B=INT(RND(1)*20+.5)
|
|
430 D=D+1
|
|
440 GOSUB 460:REM GO->INTEREST
|
|
450 REM->INTEREST
|
|
460 IF D = 1 THEN RETURN
|
|
470 LS=INT(LS*1.1+.5)
|
|
480 SA=INT(SA*1.06+.5)
|
|
490 RETURN
|
|
500 REM->CHECKDAY
|
|
510 IF D >= 31 GOTO 5700:REM GO->ENDGAME
|
|
520 RETURN
|
|
530 REM->SUBWAYEVENTS
|
|
540 IF B=1 THEN GOTO 730:REM GO->CHEAPLUDES
|
|
550 IF B=2 THEN GOTO 780:REM GO->CHEEPWEED
|
|
560 IF B=3 THEN GOTO 830:REM GO->PIGHEROIN
|
|
570 IF B=4 THEN GOTO 890:REM GO->HEROINBUST
|
|
580 IF B=5 THEN GOTO 890:REM GO->HEROINBUST
|
|
590 IF B=6 THEN GOTO 950:REM GO->COKEBUST
|
|
600 IF B=7 THEN GOTO 950:REM GO->COKEBUST
|
|
610 IF B=8 THEN GOTO 1010:REM GO->MUGGED
|
|
620 IF B=9 THEN GOTO 1110:REM GO->COPS
|
|
630 IF B=10 THEN GOTO 1110:REM GO->COPS
|
|
640 IF B=11 THEN GOTO 1110:REM GO->COPS
|
|
650 IF B=12 THEN GOTO 1200:REM GO->GUNBUY
|
|
660 IF B=13 THEN GOTO 1200:REM GO->GUNBUY
|
|
670 IF B=14 THEN GOTO 1340:REM GO->DEDWEED
|
|
680 IF B=15 THEN GOTO 1410:REM GO->NEWCOAT
|
|
690 IF B=16 THEN GOTO 1490:REM GO->DEDGUY
|
|
700 IF B=17 THEN GOTO 1650:REM GO->HOMEACID
|
|
710 RETURN
|
|
720 REM->CHEAPLUDES
|
|
730 PRINT "RIVAL DEALERS ARE SELLING CHEAP LUDES!"
|
|
740 L=2
|
|
750 GOSUB 70:REM GO->WAIT
|
|
760 GOTO 1710:REM GO->MENU
|
|
770 REM->CHEEPWEED
|
|
780 PRINT "WEED PRICES HAVE BOTTOMED-OUT!"
|
|
790 W=122
|
|
800 GOSUB 70:REM GO->WAIT
|
|
810 GOTO 1710:REM GO->MENU
|
|
820 REM->PIGHEROIN
|
|
830 PRINT "PIGS ARE SELLING CHEAP HEROIN"
|
|
840 PRINT "FROM LAST WEEK'S RAID!"
|
|
850 H=INT((RND(1)*1150)+850.5)
|
|
860 GOSUB 70:REM GO->WAIT
|
|
870 GOTO 1710:REM GO->MENU
|
|
880 REM->HEROINBUST
|
|
890 PRINT "ADDICTS ARE BUYING HEROIN"
|
|
900 PRINT "AT OUTRAGEOUS PRICES!"
|
|
910 H=INT((RND(1)*25000)+18000.5)
|
|
920 GOSUB 70:REM GO->WAIT
|
|
930 GOTO 1710:REM GO->MENU
|
|
940 REM->COKEBUST
|
|
950 PRINT "PIGS MADE A BIG COKE BUST!"
|
|
960 PRINT "PRICES ARE OUTRAGEOUS!!!!"
|
|
970 C=INT((RND(1)*60000)+80000.5)
|
|
980 GOSUB 70:REM GO->WAIT
|
|
990 GOTO 1710:REM GO->MENU
|
|
1000 REM->MUGGED
|
|
1010 PRINT "YOU GOT MUGGED!"
|
|
1020 PRINT CHR$(10)
|
|
1030 MS=INT(WA/3)
|
|
1040 MS=INT(MS*2)
|
|
1050 ML=INT(WA-MS)
|
|
1060 PRINT "YOU LOST $";ML
|
|
1070 WA=MS
|
|
1080 GOSUB 70:REM GO->WAIT
|
|
1090 GOSUB 1710:REM GO->MENU
|
|
1100 REM->COPS
|
|
1110 WE=CI+HI+WI+AI+SI+LI
|
|
1120 IF WE<50 THEN RETURN
|
|
1130 PRINT "IT'S THE COPS!"
|
|
1140 PRINT CHR$(10)
|
|
1150 PRINT "JUST KIDDING!"
|
|
1160 PRINT "COPS HAVEN'T BEEN CODED YET."
|
|
1170 GOSUB 70:REM GO->WAIT
|
|
1180 GOTO 1710:REM GO->MENU
|
|
1190 REM->GUNBUY
|
|
1200 IF WA < 500 THEN RETURN
|
|
1210 GOSUB 330:REM GO->FREESPACE
|
|
1220 IF FS < 5 THEN RETURN
|
|
1230 GX=INT(RND(1)*2)
|
|
1240 IF GX = 0 THEN AX$ = "BARETTA"
|
|
1250 IF GX = 1 THEN AX$ = "SATURDAY NIGHT SPECIAL"
|
|
1260 IF GX = 2 THEN AX$ = ".44 MAGNUM"
|
|
1270 PRINT "WILL YOU BUY A ";AX$
|
|
1280 INPUT "FOR $400? (Y/N)";RE$
|
|
1290 IF RE$ <> "Y" THEN GOTO 1710:REM GO->MENU
|
|
1300 GN = INT(GN+1)
|
|
1310 WA = INT(WA-400)
|
|
1320 GOTO 1710:REM GO->MENU
|
|
1330 REM->DEDWEED
|
|
1340 PRINT "THERE'S SOME WEED HERE THAT SMELLS"
|
|
1350 PRINT "LIKE GOOD STUFF!!"
|
|
1360 PRINT CHR$(10)
|
|
1370 INPUT "WILL YOU SMOKE IT? (Y/N)";X$
|
|
1380 IF X$ = "Y" THEN GOTO 5510:REM GO->WEEDEND
|
|
1390 RETURN
|
|
1400 REM->NEWCOAT
|
|
1410 IF WA<300 THEN RETURN
|
|
1420 PRINT "WILL YOU BUY A NEW TRENCHCOAT"
|
|
1430 INPUT "WITH MORE POCKETS FOR $200? (Y/N)";X$
|
|
1440 IF X$ <> "Y" THEN GOTO 1710:REM GO->MENU
|
|
1450 IN=INT(IN+10)
|
|
1460 WA=INT(WA-200)
|
|
1470 GOTO 1710:REM GO->MENU
|
|
1480 REM->DEDGUY
|
|
1490 IF FS<8 THEN RETURN
|
|
1500 DG=INT((RND(1)*7)+1.5)
|
|
1510 XG=INT(RND(1)*5+.5)
|
|
1520 IF XG=0 THEN LI=LI+DG : SS$ = "LUDES"
|
|
1530 IF XG=1 THEN SI=SI+DG : SS$ = "SPEED"
|
|
1540 IF XG=2 THEN WI=WI+DG : SS$ = "WEED"
|
|
1550 IF XG=3 THEN AI=AI+DG : SS$ = "ACID"
|
|
1560 IF XG=4 THEN HI=HI+DG : SS$ = "HEROIN"
|
|
1570 IF XG=5 THEN CI=CI+DG : SS$ = "COCAINE"
|
|
1580 PRINT "YOU FOUND ";DG;" UNITS OF"
|
|
1590 PRINT " ";SS$
|
|
1600 PRINT "ON A DEAD DUDE IN THE SUBWAY!"
|
|
1610 PRINT CHR$(10)
|
|
1620 GOSUB 70:REM GO->WAIT
|
|
1630 GOTO 1710:REM GO->MENU
|
|
1640 REM->HOMEACID
|
|
1650 PRINT "THE MARKET HAS BEEN FLOODED"
|
|
1660 PRINT "WITH CHEAP HOME-MADE ACID!"
|
|
1670 A=INT((RND(1)*550)+250.5)
|
|
1680 GOSUB 70:REM GO->WAIT
|
|
1690 GOTO 1710:REM GO->MENU
|
|
1700 REM->MENU
|
|
1710 HOME
|
|
1720 GOSUB 40:REM GO->TITLEBAR
|
|
1730 GOSUB 330:REM GO->FREESPACE
|
|
1740 INVERSE : PRINT " DAY:";D;" ";PH$ : NORMAL
|
|
1750 PRINT "(C)HECK PRICES"
|
|
1760 PRINT "(I)NVENTORY"
|
|
1770 PRINT "(B)UY"
|
|
1780 PRINT "(S)ELL"
|
|
1790 PRINT "(J)ET"
|
|
1800 PRINT "SEE (L)OAN SHARK"
|
|
1810 PRINT "(V)ISIT BANK"
|
|
1820 INPUT "PLEASE MAKE YOUR SELECTION: ";T$
|
|
1830 IF T$ = "C" GOTO 1930:REM GO->PRICES
|
|
1840 IF T$ = "I" GOTO 2070:REM GO->INVENTORY
|
|
1850 IF T$ = "B" GOTO 2210:REM GO->BUY
|
|
1860 IF T$ = "S" GOTO 3080:REM GO->SELL
|
|
1870 IF T$ = "J" GOTO 3920:REM GO->JET
|
|
1880 IF T$ = "L" GOTO 4430:REM GO->LOAN
|
|
1890 IF T$ = "V" GOTO 4740:REM GO->BANK
|
|
1900 PRINT "INVALID SELECTION"
|
|
1910 GOTO 1710:REM GO->MENU
|
|
1920 REM->PRICES
|
|
1930 HOME
|
|
1940 GOSUB 40:REM GO->TITLEBAR
|
|
1950 INVERSE:PRINT" PRICES ":NORMAL
|
|
1960 PRINT CHR$(10)
|
|
1970 PRINT"COCAINE:","$"C
|
|
1980 PRINT"HEROIN:","$"H
|
|
1990 PRINT"ACID:","$"A
|
|
2000 PRINT"WEED:","$"W
|
|
2010 PRINT"SPEED:","$"S
|
|
2020 PRINT"LUDES:","$"L
|
|
2030 PRINT"WALLET:","$"WA
|
|
2040 GOSUB 70:REM GO->WAIT
|
|
2050 GOTO 1710:REM GO->MENU
|
|
2060 REM->INVENTORY
|
|
2070 HOME
|
|
2080 GOSUB 40:REM GO->TITLEBAR
|
|
2090 INVERSE:PRINT" INVENTORY ":NORMAL
|
|
2100 PRINT CHR$(10)
|
|
2110 PRINT"COCAINE:",CI
|
|
2120 PRINT"HEROIN:",HI
|
|
2130 PRINT"ACID:",AI
|
|
2140 PRINT"WEED:",WI
|
|
2150 PRINT"SPEED:",SI
|
|
2160 PRINT"LUDES:",LI
|
|
2170 PRINT"FREE SPACE:",FS
|
|
2180 GOSUB 70:REM GO->WAIT
|
|
2190 GOTO 1710:REM GO->MENU
|
|
2200 REM->BUY
|
|
2210 HOME
|
|
2220 GOSUB 40:REM GO->TITLEBAR
|
|
2230 INVERSE:PRINT" BUY ":NORMAL
|
|
2240 PRINT CHR$(10)
|
|
2250 PRINT"WHAT DO YOU WANT TO BUY?"
|
|
2260 PRINT CHR$(10)
|
|
2270 PRINT "(C)OCAINE"
|
|
2280 PRINT "(H)EROIN"
|
|
2290 PRINT "(A)CID"
|
|
2300 PRINT "(W)EED"
|
|
2310 PRINT "(S)PEED"
|
|
2320 PRINT "(L)UDES"
|
|
2330 INPUT "ENTER SELECTION: ";DB$
|
|
2340 IF DB$="C" GOTO 2420:REM GO->COKEBUY
|
|
2350 IF DB$="H" GOTO 2530:REM GO->HERBUY
|
|
2360 IF DB$="A" GOTO 2640:REM GO->ACIDBUY
|
|
2370 IF DB$="W" GOTO 2750:REM GO->WEEDBUY
|
|
2380 IF DB$="S" GOTO 2860:REM GO->SPDBUY
|
|
2390 IF DB$="L" GOTO 2970:REM GO->LUDBUY
|
|
2400 GOTO 1710:REM GO->MENU
|
|
2410 REM->COKEBUY
|
|
2420 HOME
|
|
2430 GOSUB 40:REM GO->TITLEBAR
|
|
2440 INVERSE:PRINT" BUY COCAINE ":NORMAL
|
|
2450 PRINT CHR$(10)
|
|
2460 J=INT(WA/C)
|
|
2470 GOSUB 110:REM GO->HOWMUCHBUY
|
|
2480 IF K>FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 2420:REM GO->COKEBUY
|
|
2490 IF K<=J THEN CI=CI+K : WA=WA-(C*K)
|
|
2500 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 2420:REM GO->COKEBUY
|
|
2510 GOTO 1710:REM GO->MENU
|
|
2520 REM->HERBUY
|
|
2530 HOME
|
|
2540 GOSUB 40:REM GO->TITLEBAR
|
|
2550 INVERSE:PRINT" BUY HEROIN ":NORMAL
|
|
2560 PRINT CHR$(10)
|
|
2570 J=INT(WA/H)
|
|
2580 GOSUB 110:REM GO->HOWMUCHBUY
|
|
2590 IF K>FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 2530:REM GO->HERBUY
|
|
2600 IF K<=J THEN HI=HI+K : WA=WA-(H*K)
|
|
2610 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 2530:REM GO->HERBUY
|
|
2620 GOTO 1710:REM GO->MENU
|
|
2630 REM->ACIDBUY
|
|
2640 HOME
|
|
2650 GOSUB 40:REM GO->TITLEBAR
|
|
2660 INVERSE:PRINT" BUY ACID ":NORMAL
|
|
2670 PRINT CHR$(10)
|
|
2680 J=INT(WA/A)
|
|
2690 GOSUB 110:REM GO->HOWMUCHBUY
|
|
2700 IF K>FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 2640:REM GO->ACIDBUY
|
|
2710 IF K<=J THEN AI=AI+K : WA=WA-(A*K)
|
|
2720 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 2640:REM GO->ACIDBUY
|
|
2730 GOTO 1710:REM GO->MENU
|
|
2740 REM->WEEDBUY
|
|
2750 HOME
|
|
2760 GOSUB 40:REM GO->TITLEBAR
|
|
2770 INVERSE:PRINT" BUY WEED ":NORMAL
|
|
2780 PRINT CHR$(10)
|
|
2790 J=INT(WA/W)
|
|
2800 GOSUB 110:REM GO->HOWMUCHBUY
|
|
2810 IF K>FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 2750:REM GO->WEEDBUY
|
|
2820 IF K<=J THEN WI=WI+K : WA=WA-(W*K)
|
|
2830 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 2750:REM GO->WEEDBUY
|
|
2840 GOTO 1710:REM GO->MENU
|
|
2850 REM->SPDBUY
|
|
2860 HOME
|
|
2870 GOSUB 40:REM GO->TITLEBAR
|
|
2880 INVERSE:PRINT" BUY SPEED ":NORMAL
|
|
2890 PRINT CHR$(10)
|
|
2900 J=INT(WA/S)
|
|
2910 GOSUB 110:REM GO->HOWMUCHBUY
|
|
2920 IF K>FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 2860:REM GO->SPDBUY
|
|
2930 IF K<=J THEN SI=SI+K : WA=WA-(S*K)
|
|
2940 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 2860:REM GO->SPDBUY
|
|
2950 GOTO 1710:REM GO->MENU
|
|
2960 REM->LUDBUY
|
|
2970 HOME
|
|
2980 GOSUB 40:REM GO->TITLEBAR
|
|
2990 INVERSE:PRINT" BUY LUDES ":NORMAL
|
|
3000 PRINT CHR$(10)
|
|
3010 J=INT(WA/L)
|
|
3020 GOSUB 110:REM GO->HOWMUCHBUY
|
|
3030 IF K>FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 2970:REM GO->LUDBUY
|
|
3040 IF K<=J THEN LI=LI+K : WA=WA-(L*K)
|
|
3050 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 2970:REM GO->LUDBUY
|
|
3060 GOTO 1710:REM GO->MENU
|
|
3070 REM->SELL
|
|
3080 HOME
|
|
3090 GOSUB 40:REM GO->TITLEBAR
|
|
3100 INVERSE:PRINT" SELL ":NORMAL
|
|
3110 PRINT CHR$(10)
|
|
3120 PRINT "WHAT WOULD YOU LIKE TO SELL?"
|
|
3130 PRINT CHR$(10)
|
|
3140 PRINT "(C)OCAINE"
|
|
3150 PRINT "(H)EROIN"
|
|
3160 PRINT "(A)CID"
|
|
3170 PRINT "(W)EED"
|
|
3180 PRINT "(S)PEED"
|
|
3190 PRINT "(L)UDES"
|
|
3200 REM->SELLSEL
|
|
3210 INPUT "ENTER SELECTION: (0 TO CANCEL)";DB$
|
|
3220 IF DB$="C" GOTO 3320:REM GO->COKESELL
|
|
3230 IF DB$="H" GOTO 3420:REM GO->HERSELL
|
|
3240 IF DB$="A" GOTO 3520:REM GO->ACIDSELL
|
|
3250 IF DB$="W" GOTO 3620:REM GO->WEEDSELL
|
|
3260 IF DB$="S" GOTO 3720:REM GO->SPDSELL
|
|
3270 IF DB$="L" GOTO 3820:REM GO->LUDSELL
|
|
3280 IF DB$="0" GOTO 1710:REM GO->MENU
|
|
3290 PRINT "INVALID SELECTION!"
|
|
3300 GOTO 3210:REM GO->SELLSEL
|
|
3310 REM->COKESELL
|
|
3320 HOME
|
|
3330 GOSUB 40:REM GO->TITLEBAR
|
|
3340 INVERSE:PRINT" SELL COCAINE ":NORMAL
|
|
3350 PRINT CHR$(10)
|
|
3360 J=CI
|
|
3370 GOSUB 180:REM GO->HOWMUCHSELL
|
|
3380 CI=CI-K
|
|
3390 WA=WA+(C*K)
|
|
3400 GOTO 1710:REM GO->MENU
|
|
3410 REM->HERSELL
|
|
3420 HOME
|
|
3430 GOSUB 40:REM GO->TITLEBAR
|
|
3440 INVERSE:PRINT" SELL HEROIN ":NORMAL
|
|
3450 PRINT CHR$(10)
|
|
3460 J=HI
|
|
3470 GOSUB 180:REM GO->HOWMUCHSELL
|
|
3480 HI=HI-K
|
|
3490 WA=WA+(H*K)
|
|
3500 GOTO 1710:REM GO->MENU
|
|
3510 REM->ACIDSELL
|
|
3520 HOME
|
|
3530 GOSUB 40:REM GO->TITLEBAR
|
|
3540 INVERSE:PRINT" SELL ACID ":NORMAL
|
|
3550 PRINT CHR$(10)
|
|
3560 J=AI
|
|
3570 GOSUB 180:REM GO->HOWMUCHSELL
|
|
3580 AI=AI-K
|
|
3590 WA=WA+(A*K)
|
|
3600 GOTO 1710:REM GO->MENU
|
|
3610 REM->WEEDSELL
|
|
3620 HOME
|
|
3630 GOSUB 40:REM GO->TITLEBAR
|
|
3640 INVERSE:PRINT" SELL WEED ":NORMAL
|
|
3650 PRINT CHR$(10)
|
|
3660 J=WI
|
|
3670 GOSUB 180:REM GO->HOWMUCHSELL
|
|
3680 WI=WI-K
|
|
3690 WA=WA+(W*K)
|
|
3700 GOTO 1710:REM GO->MENU
|
|
3710 REM->SPDSELL
|
|
3720 HOME
|
|
3730 GOSUB 40:REM GO->TITLEBAR
|
|
3740 INVERSE:PRINT" SELL SPEED ":NORMAL
|
|
3750 PRINT CHR$(10)
|
|
3760 J=SI
|
|
3770 GOSUB 180:REM GO->HOWMUCHSELL
|
|
3780 SI=SI-K
|
|
3790 WA=WA+(S*K)
|
|
3800 GOTO 1710:REM GO->MENU
|
|
3810 REM->LUDSELL
|
|
3820 HOME
|
|
3830 GOSUB 40:REM GO->TITLEBAR
|
|
3840 INVERSE:PRINT" SELL LUDES ":NORMAL
|
|
3850 PRINT CHR$(10)
|
|
3860 J=LI
|
|
3870 GOSUB 180:REM GO->HOWMUCHSELL
|
|
3880 LI=LI-K
|
|
3890 WA=WA+(L*K)
|
|
3900 GOTO 1710:REM GO->MENU
|
|
3910 REM->JET
|
|
3920 HOME
|
|
3930 GOSUB 40:REM GO->TITLEBAR
|
|
3940 INVERSE:PRINT" JET ":NORMAL
|
|
3950 PRINT CHR$(10)
|
|
3960 PRINT "(B)RONX"
|
|
3970 PRINT "(G)HETTO"
|
|
3980 PRINT "(C)ENTRAL PARK
|
|
3990 PRINT "(M)ANHATTEN"
|
|
4000 PRINT "CONEY (I)SLAND"
|
|
4010 PRINT "BROO(K)LYN"
|
|
4020 PRINT "(O)OPS...STAY!"
|
|
4030 INPUT "WHERE TO DUDE? ";JT$
|
|
4040 IF JT$="B" THEN PQ$ = "THE BRONX" : GOTO 4130:REM GO->JETB
|
|
4050 IF JT$="G" THEN PQ$ = "THE GHETTO" : GOTO 4130:REM GO->JETB
|
|
4060 IF JT$="C" THEN PQ$ = "CENTRAL PARK" : GOTO 4130:REM GO->JETB
|
|
4070 IF JT$="M" THEN PQ$ = "MANHATTEN" : GOTO 4130:REM GO->JETB
|
|
4080 IF JT$="I" THEN PQ$ = "CONEY ISLAND" : GOTO 4130:REM GO->JETB
|
|
4090 IF JT$="K" THEN PQ$ = "BROOKLYN" : GOTO 4130:REM GO->JETB
|
|
4100 IF JT$="O" THEN GOTO 1710:REM GO->MENU
|
|
4110 GOTO 3920:REM GO->JET
|
|
4120 REM->JETB
|
|
4130 IF PQ$=PH$ THEN GOTO 4170:REM GO->ALREADYTHERE
|
|
4140 PH$ = PQ$
|
|
4150 GOTO 4260:REM GO->SUBWAY
|
|
4160 REM->ALREADYTHERE
|
|
4170 HOME
|
|
4180 GOSUB 40:REM GO->TITLEBAR
|
|
4190 INVERSE:PRINT" JET ":NORMAL
|
|
4200 PRINT CHR$(10)
|
|
4210 PRINT "YOU'RE ALREADY IN:"
|
|
4220 PRINT " ";PH$
|
|
4230 GOSUB 70:REM GO->WAIT
|
|
4240 GOTO 3920:REM GO->JET
|
|
4250 REM->SUBWAY
|
|
4260 HOME
|
|
4270 GOSUB 360:REM GO->DAILY
|
|
4280 GOSUB 40:REM GO->TITLEBAR
|
|
4290 INVERSE:PRINT" SUBWAY ":NORMAL
|
|
4300 PRINT CHR$(10)
|
|
4310 GOSUB 540:REM GO->SUBWAYEVENTS
|
|
4320 PRINT CHR$(10)
|
|
4330 PRINT "WELCOME TO ";PH$
|
|
4340 PRINT CHR$(10)
|
|
4350 INPUT "PRESS ENTER TO CONTINUE. ";X$
|
|
4360 GOTO 1710:REM GO->MENU
|
|
4370 REM->NOTBRONX
|
|
4380 PRINT "YOU NEED TO HEAD TO THE BRONX"
|
|
4390 PRINT "TO TAKE CARE OF THIS BUSINESS."
|
|
4400 GOSUB 70:REM GO->WAIT
|
|
4410 GOTO 1710:REM GO->MENU
|
|
4420 REM->LOAN
|
|
4430 HOME
|
|
4440 GOSUB 40:REM GO->TITLEBAR
|
|
4450 INVERSE : PRINT " LOAN SHARK " :NORMAL
|
|
4460 PRINT CHR$(10)
|
|
4470 IF PH$ <> "THE BRONX" THEN GOTO 4380:REM GO->NOTBRONX
|
|
4480 PRINT "YOUR DEBT IS: $";LS
|
|
4490 PRINT "YOU HAVE: $";WA
|
|
4500 PRINT CHR$(10)
|
|
4510 INPUT "(R)EPAY, (B)ORROW, (L)EAVE: ";X$
|
|
4520 IF X$ = "R" THEN GOTO 4570:REM GO->PAYME
|
|
4530 IF X$ = "B" THEN GOTO 4660:REM GO->BORROW
|
|
4540 IF X$ = "L" THEN GOTO 1710:REM GO->MENU
|
|
4550 GOTO 4430:REM GO->LOAN
|
|
4560 REM->PAYME
|
|
4570 INPUT "REPAY HOW MUCH? ";PL
|
|
4580 IF WA<PL THEN PRINT "YOU DON'T HAVE THAT MUCH!" : INPUT "PRESS ENTER TO CONTINUE. ";X$ : GOTO 4430:REM GO->LOAN
|
|
4590 IF PL>LS THEN PRINT "YOU DON'T OWE THAT MUCH!" : INPUT"PRESS ENTER TO CONTINE. ";X$ : GOTO 4430:REM GO->LOAN
|
|
4600 WA=WA-PL
|
|
4610 LS=LS-PL
|
|
4620 PRINT "THANK YOU."
|
|
4630 GOSUB 70:REM GO->WAIT
|
|
4640 GOTO 1710:REM GO->MENU
|
|
4650 REM->BORROW
|
|
4660 INPUT "HOW MUCH DO YOU WANT? ";BL
|
|
4670 IF BL>5000 THEN PRINT "HE'S NOT THAT STUPID!" : GOTO 4660:REM GO->BORROW
|
|
4680 LS=LS+BL
|
|
4690 WA=WA+BL
|
|
4700 PRINT "HERE'S YOUR MONEY." : PRINT CHR$(10) : PRINT "REMEMBER, I BREAK THUMBS."
|
|
4710 GOSUB 70:REM GO->WAIT
|
|
4720 GOTO 1710:REM GO->MENU
|
|
4730 REM->BANK
|
|
4740 HOME
|
|
4750 GOSUB 40:REM GO->TITLEBAR
|
|
4760 INVERSE : PRINT " BANK O'MURICA ":NORMAL
|
|
4770 PRINT CHR$(10)
|
|
4780 IF PH$ <> "THE BRONX" THEN GOTO 4380:REM GO->NOTBRONX
|
|
4790 PRINT "YOUR BALANCE: $";SA
|
|
4800 PRINT "YOUR WALLET: $";WA
|
|
4810 PRINT CHR$(10)
|
|
4820 INPUT "(D)EPOSIT, (W)ITHDRAW, (L)EAVE: ";X$
|
|
4830 IF X$ = "D" THEN GOTO 4880:REM GO->DEPOSIT
|
|
4840 IF X$ = "W" THEN GOTO 4960:REM GO->MYMONEY
|
|
4850 IF X$ = "L" THEN GOTO 1710:REM GO->MENU
|
|
4860 GOTO 4740:REM GO->BANK
|
|
4870 REM->DEPOSIT
|
|
4880 INPUT "HOW MUCH? ";DL
|
|
4890 IF WA<DL THEN PRINT "YOU DON'T HAVE THAT MUCH CASH." : GOTO 4880:REM GO->DEPOSIT
|
|
4900 SA=SA+DL
|
|
4910 WA=WA-DL
|
|
4920 PRINT "THANK YOU FOR YOUR DEPOSIT."
|
|
4930 GOSUB 70:REM GO->WAIT
|
|
4940 GOTO 1710:REM GO->MENU
|
|
4950 REM->MYMONEY
|
|
4960 INPUT "HOW MUCH? ";DL
|
|
4970 IF SA<DL THEN PRINT "YOU DON'T HAVE SUFFICIENT FUNDS." : GOTO 4960:REM GO->MYMONEY
|
|
4980 SA=SA-DL
|
|
4990 WA=WA+DL
|
|
5000 PRINT "THANK YOU FOR YOUR BUSINESS."
|
|
5010 GOSUB 70:REM GO->WAIT
|
|
5020 GOTO 1710:REM GO->MENU
|
|
5030 REM->INSTRUCTIONS
|
|
5040 HOME
|
|
5050 GOSUB 40:REM GO->TITLEBAR
|
|
5060 PRINT CHR$(10)
|
|
5070 PRINT "WELCOME TO DRUGWAR//E"
|
|
5080 PRINT CHR$(10)
|
|
5090 PRINT CHR$(10)
|
|
5100 INPUT "WOULD YOU LIKE INSTRUCTIONS? (Y/N): ";Q$
|
|
5110 REM->INSERRORHANDLER
|
|
5120 IF Q$ = "Y" THEN GOTO 5340:REM GO->INST
|
|
5130 IF Q$ = "N" THEN GOTO 5170:REM GO->GAMESTART
|
|
5140 INPUT "I DON'T UNDERSTAND YOU. Y OR N ONLY. ";Q$
|
|
5150 GOTO 5120:REM GO->INSERRORHANDLER
|
|
5160 REM->GAMESTART
|
|
5170 WA=2000
|
|
5180 SA=0
|
|
5190 LS=5000
|
|
5200 D=0
|
|
5210 PH$="THE BRONX"
|
|
5220 GN=0
|
|
5230 DP=0
|
|
5240 IN=100
|
|
5250 CI=0
|
|
5260 HI=0
|
|
5270 AI=0
|
|
5280 WI=0
|
|
5290 SI=0
|
|
5300 LI=0
|
|
5310 GOSUB 360:REM GO->DAILY
|
|
5320 GOTO 1710:REM GO->MENU
|
|
5330 REM->INST
|
|
5340 HOME
|
|
5350 GOSUB 40:REM GO->TITLEBAR
|
|
5360 PRINT CHR$(10)
|
|
5370 PRINT "THIS IS A GAME OF BUYING AND SELLING."
|
|
5380 PRINT "YOUR GOAL IS TO PAY OFF YOUR DEBT AND"
|
|
5390 PRINT "MAKE AS MUCH MONEY AS POSSIBLE IN A ONE"
|
|
5400 PRINT "MONTH PERIOD. PRICES FLUCTUATE EVERY DAY"
|
|
5410 PRINT "AND INTEREST ON YOUR LOAN IS CALCULATED"
|
|
5420 PRINT "AS WELL. IF YOU DEAL TOO HEAVILY, YOU'LL"
|
|
5430 PRINT "ATTRACT THE ATTENTION OF THE POLICE.
|
|
5440 PRINT CHR$(10)
|
|
5450 PRINT "COMMANDS ARE USUALLY THE FIRST LETTER"
|
|
5460 PRINT "OF WHAT YOU WANT TO DO. Y = YES AND"
|
|
5470 PRINT "N = NO."
|
|
5480 INPUT "PRESS ENTER TO CONTINUE.";X$
|
|
5490 GOTO 5170:REM GO->GAMESTART
|
|
5500 REM->WEEDEND
|
|
5510 HOME
|
|
5520 GOSUB 40:REM GO->TITLEBAR
|
|
5530 INVERSE : PRINT " SMOKE WEED " : NORMAL
|
|
5540 PRINT "YOU HALLUCINATE ON THE WILDEST TRIP"
|
|
5550 PRINT "OF YOUR LIFE, STUMBLE ON TO THE TRACKS,"
|
|
5560 PRINT "AND GET CREAMED BY A TRAIN!"
|
|
5570 PRINT CHR$(10)
|
|
5580 PRINT CHR$(10)
|
|
5590 PRINT "JUST SAY NO TO DRUGS!"
|
|
5600 GOSUB 70:REM GO->WAIT
|
|
5610 GOTO 5850:REM GO->IRONICEND
|
|
5620 REM->SCORECALCULATE
|
|
5630 SC=(WA+SA)-LS
|
|
5640 IF SC<0 THEN SC=0 : RETURN
|
|
5650 SC=SQR((SC/31.5)+.5)
|
|
5660 SC=INT(SC)
|
|
5670 IF SC>100 THEN SC=100
|
|
5680 RETURN
|
|
5690 REM->ENDGAME
|
|
5700 HOME
|
|
5710 GOSUB 40:REM GO->TITLEBAR
|
|
5720 GOSUB 5630:REM GO->SCORECALCULATE
|
|
5730 INVERSE : PRINT " GAME OVER " : NORMAL
|
|
5740 PRINT CHR$(10)
|
|
5750 PRINT "YOUR SCORE ON A SCALE OF 1 TO 100: ";SC
|
|
5760 PRINT CHR$(10)
|
|
5770 INPUT "WOULD YOU LIKE TO PLAY AGAIN? (Y/N)";PA$
|
|
5780 IF PA$ = "Y" THEN GOTO 5170:REM GO->GAMESTART
|
|
5790 PRINT "THANKS FOR PLAYING."
|
|
5800 PRINT "REMEMBER...WATCH YOUR BACK."
|
|
5810 PRINT "HAVE A NICE DAY!"
|
|
5820 GOSUB 6030:REM GO->ANTICHEAT
|
|
5830 END
|
|
5840 REM->IRONICEND
|
|
5850 HOME
|
|
5860 GOSUB 40:REM GO->TITLEBAR
|
|
5870 GOSUB 5630:REM GO->SCORECALCULATE
|
|
5880 INVERSE : PRINT " GAME OVER " : NORMAL
|
|
5890 PRINT CHR$(10)
|
|
5900 PRINT "YOUR FINAL SCORE IS: ";SC
|
|
5910 PRINT CHR$(10)
|
|
5920 PRINT "BUT YOU DIED FROM SMOKING WEED? IN A"
|
|
5930 PRINT "GAME ABOUT DEALING DRUGS? BUDDY, NO"
|
|
5940 PRINT "SCORE CAN REDEEM THAT STUPIDITY."
|
|
5950 PRINT CHR$(10)
|
|
5960 INPUT "WOULD YOU LIKE TO PLAY AGAIN? ";PA$
|
|
5970 IF PA$= "Y" THEN GOTO 5170:REM GO->GAMESTART
|
|
5980 IF PA$= "N" THEN PRINT "I DON'T BLAME YOU." : END
|
|
5990 PRINT "WHAT? IF YOU'RE THAT DUMB, I'M LEAVING."
|
|
6000 GOSUB 6030:REM GO->ANTICHEAT
|
|
6010 END
|
|
6020 REM->ANTICHEAT
|
|
6030 WA=2000
|
|
6040 SA=0
|
|
6050 LS=5000
|
|
6060 D=0
|
|
6070 PH$="THE BRONX"
|
|
6080 GN=0
|
|
6090 DP=0
|
|
6100 IN=100
|
|
6110 CI=0
|
|
6120 HI=0
|
|
6130 AI=0
|
|
6140 WI=0
|
|
6150 SI=0
|
|
6160 LI=0
|
|
6170 RETURN
|