You cannot select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
594 lines
14 KiB
QBasic
594 lines
14 KiB
QBasic
10 REM DRUGWAR.BAS - 16/10/2018 - 00h06
|
|
20 REM DRUGWAR//E - BETA 8
|
|
30 REM COPYRIGHT 2018 JAY MOORE
|
|
40 REM RELEASED UNDER GPL V3
|
|
50 REM DRUGWAR2E.SOURCEFORGE.IO
|
|
60 REM TWITTER: _NQ4T
|
|
70 GOTO 4840
|
|
80 REM->TITLEBAR
|
|
90 PRINT ,"DRUGWAR//E",
|
|
100 RETURN
|
|
110 REM->WAIT
|
|
120 PRINT CHR$(10)
|
|
130 INPUT "PRESS ENTER TO CONTINUE.";X$
|
|
140 RETURN
|
|
150 REM->HOWMUCHBUY
|
|
160 PRINT "YOU CAN AFFORD ";J
|
|
170 PRINT "YOU CAN CARRY ";F
|
|
180 REM->HOWMANYBUY
|
|
190 PRINT CHR$(10)
|
|
200 INPUT "HOW MANY? (ENTER 0 CANCEL): ";K
|
|
210 IF K=0 GOTO 460
|
|
220 IF K>F THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!" : NORMAL : GOTO 190
|
|
230 IF K>J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!" : NORMAL : GOTO 190
|
|
240 RETURN
|
|
250 REM->HOWMUCHSELL
|
|
260 PRINT "YOU CAN SELL: ";J
|
|
270 PRINT CHR$(10)
|
|
280 REM->HOWMANYSELL
|
|
290 INPUT "HOW MANY? (ENTER 0 TO CANCEL.): ";K
|
|
300 IF K>J THEN PRINT "YOU DON'T HAVE THAT MANY!" : GOTO 290
|
|
310 IF K=0 GOTO 460
|
|
320 RETURN
|
|
330 REM->DAILY
|
|
340 C=INT(RND(1)*12000+16000.5)
|
|
350 H=INT(RND(1)*7000+5000.5)
|
|
360 A=INT((RND(1)*34+10)*100+.5)
|
|
370 Z=INT((RND(1)*42+33)*10+.5)
|
|
380 S=INT((RND(1)*15+7)*10+.5)
|
|
390 L=INT((RND(1)*4+1)*10+.5)
|
|
400 B=INT(RND(1)*20+.5)
|
|
410 D=D+1
|
|
420 REM->CHECKDAY
|
|
430 IF D >= 31 GOTO 5470
|
|
440 RETURN
|
|
450 REM->MENU
|
|
460 HOME
|
|
470 F=I-(M+N+O+U+T+Q)
|
|
480 GOSUB 90
|
|
490 INVERSE : PRINT "DAY:";D,P$, : NORMAL
|
|
500 PRINT CHR$(10)
|
|
510 PRINT "(C)HECK PRICES"
|
|
520 PRINT "(I)NVENTORY"
|
|
530 PRINT "(B)UY"
|
|
540 PRINT "(S)ELL"
|
|
550 PRINT "(J)ET"
|
|
560 PRINT "SEE (L)OAN SHARK"
|
|
570 PRINT "(V)ISIT BANK"
|
|
580 INPUT "PLEASE MAKE YOUR SELECTION: ";X$
|
|
590 IF X$ = "C" GOTO 680
|
|
600 IF X$ = "I" GOTO 820
|
|
610 IF X$ = "B" GOTO 960
|
|
620 IF X$ = "S" GOTO 1710
|
|
630 IF X$ = "J" GOTO 2550
|
|
640 IF X$ = "L" GOTO 4230
|
|
650 IF X$ = "V" GOTO 4540
|
|
660 GOTO 460
|
|
670 REM->PRICES
|
|
680 HOME
|
|
690 GOSUB 90
|
|
700 INVERSE:PRINT" PRICES ":NORMAL
|
|
710 PRINT CHR$(10)
|
|
720 PRINT"COCAINE:","$"C
|
|
730 PRINT"HEROIN:","$"H
|
|
740 PRINT"ACID:","$"A
|
|
750 PRINT"WEED:","$"Z
|
|
760 PRINT"SPEED:","$"S
|
|
770 PRINT"LUDES:","$"L
|
|
780 PRINT"WALLET:","$"W
|
|
790 GOSUB 120
|
|
800 GOTO 460
|
|
810 REM->INVENTORY
|
|
820 HOME
|
|
830 GOSUB 90
|
|
840 INVERSE:PRINT" INVENTORY ":NORMAL
|
|
850 PRINT CHR$(10)
|
|
860 PRINT"COCAINE:",M
|
|
870 PRINT"HEROIN:",N
|
|
880 PRINT"ACID:",O
|
|
890 PRINT"WEED:",U
|
|
900 PRINT"SPEED:",T
|
|
910 PRINT"LUDES:",Q
|
|
920 PRINT"FREE SPACE:",F
|
|
930 GOSUB 120
|
|
940 GOTO 460
|
|
950 REM->BUY
|
|
960 HOME
|
|
970 GOSUB 90
|
|
980 INVERSE:PRINT" BUY ":NORMAL
|
|
990 PRINT CHR$(10)
|
|
1000 PRINT"WHAT DO YOU WANT TO BUY?"
|
|
1010 PRINT CHR$(10)
|
|
1020 PRINT "(C)OCAINE"
|
|
1030 PRINT "(H)EROIN"
|
|
1040 PRINT "(A)CID"
|
|
1050 PRINT "(W)EED"
|
|
1060 PRINT "(S)PEED"
|
|
1070 PRINT "(L)UDES"
|
|
1080 INPUT "ENTER SELECTION: ";X$
|
|
1090 IF X$="C" GOTO 1170
|
|
1100 IF X$="H" GOTO 1260
|
|
1110 IF X$="A" GOTO 1350
|
|
1120 IF X$="W" GOTO 1440
|
|
1130 IF X$="S" GOTO 1530
|
|
1140 IF X$="L" GOTO 1620
|
|
1150 GOTO 460
|
|
1160 REM->COKEBUY
|
|
1170 HOME
|
|
1180 GOSUB 90
|
|
1190 INVERSE:PRINT" BUY COCAINE ":NORMAL
|
|
1200 PRINT CHR$(10)
|
|
1210 J=INT(W/C)
|
|
1220 GOSUB 160
|
|
1230 M=M+K : W=W-(C*K)
|
|
1240 GOTO 460
|
|
1250 REM->HERBUY
|
|
1260 HOME
|
|
1270 GOSUB 90
|
|
1280 INVERSE:PRINT" BUY HEROIN ":NORMAL
|
|
1290 PRINT CHR$(10)
|
|
1300 J=INT(W/H)
|
|
1310 GOSUB 160
|
|
1320 N=N+K : W=W-(H*K)
|
|
1330 GOTO 460
|
|
1340 REM->ACIDBUY
|
|
1350 HOME
|
|
1360 GOSUB 90
|
|
1370 INVERSE:PRINT" BUY ACID ":NORMAL
|
|
1380 PRINT CHR$(10)
|
|
1390 J=INT(W/A)
|
|
1400 GOSUB 160
|
|
1410 O=O+K : W=W-(A*K)
|
|
1420 GOTO 460
|
|
1430 REM->WEEDBUY
|
|
1440 HOME
|
|
1450 GOSUB 90
|
|
1460 INVERSE:PRINT" BUY WEED ":NORMAL
|
|
1470 PRINT CHR$(10)
|
|
1480 J=INT(W/Z)
|
|
1490 GOSUB 160
|
|
1500 U=U+K : W=W-(Z*K)
|
|
1510 GOTO 460
|
|
1520 REM->SPDBUY
|
|
1530 HOME
|
|
1540 GOSUB 90
|
|
1550 INVERSE:PRINT" BUY SPEED ":NORMAL
|
|
1560 PRINT CHR$(10)
|
|
1570 J=INT(W/S)
|
|
1580 GOSUB 160
|
|
1590 T=T+K : W=W-(S*K)
|
|
1600 GOTO 460
|
|
1610 REM->LUDBUY
|
|
1620 HOME
|
|
1630 GOSUB 90
|
|
1640 INVERSE:PRINT" BUY LUDES ":NORMAL
|
|
1650 PRINT CHR$(10)
|
|
1660 J=INT(W/L)
|
|
1670 GOSUB 160
|
|
1680 Q=Q+K : W=W-(L*K)
|
|
1690 GOTO 460
|
|
1700 REM->SELL
|
|
1710 HOME
|
|
1720 GOSUB 90
|
|
1730 INVERSE:PRINT" SELL ":NORMAL
|
|
1740 PRINT CHR$(10)
|
|
1750 PRINT "WHAT WOULD YOU LIKE TO SELL?"
|
|
1760 PRINT CHR$(10)
|
|
1770 PRINT "(C)OCAINE"
|
|
1780 PRINT "(H)EROIN"
|
|
1790 PRINT "(A)CID"
|
|
1800 PRINT "(W)EED"
|
|
1810 PRINT "(S)PEED"
|
|
1820 PRINT "(L)UDES"
|
|
1830 REM->SELLSEL
|
|
1840 INPUT "ENTER SELECTION: (0 TO CANCEL)";X$
|
|
1850 IF X$="C" GOTO 1950
|
|
1860 IF X$="H" GOTO 2050
|
|
1870 IF X$="A" GOTO 2150
|
|
1880 IF X$="W" GOTO 2250
|
|
1890 IF X$="S" GOTO 2350
|
|
1900 IF X$="L" GOTO 2450
|
|
1910 IF X$="0" GOTO 460
|
|
1920 PRINT "INVALID SELECTION!"
|
|
1930 GOTO 1840
|
|
1940 REM->COKESELL
|
|
1950 HOME
|
|
1960 GOSUB 90
|
|
1970 INVERSE:PRINT" SELL COCAINE ":NORMAL
|
|
1980 PRINT CHR$(10)
|
|
1990 J=M
|
|
2000 GOSUB 260
|
|
2010 M=M-K
|
|
2020 W=W+(C*K)
|
|
2030 GOTO 460
|
|
2040 REM->HERSELL
|
|
2050 HOME
|
|
2060 GOSUB 90
|
|
2070 INVERSE:PRINT" SELL HEROIN ":NORMAL
|
|
2080 PRINT CHR$(10)
|
|
2090 J=N
|
|
2100 GOSUB 260
|
|
2110 N=N-K
|
|
2120 W=W+(H*K)
|
|
2130 GOTO 460
|
|
2140 REM->ACIDSELL
|
|
2150 HOME
|
|
2160 GOSUB 90
|
|
2170 INVERSE:PRINT" SELL ACID ":NORMAL
|
|
2180 PRINT CHR$(10)
|
|
2190 J=O
|
|
2200 GOSUB 260
|
|
2210 O=O-K
|
|
2220 W=W+(A*K)
|
|
2230 GOTO 460
|
|
2240 REM->WEEDSELL
|
|
2250 HOME
|
|
2260 GOSUB 90
|
|
2270 INVERSE:PRINT" SELL WEED ":NORMAL
|
|
2280 PRINT CHR$(10)
|
|
2290 J=U
|
|
2300 GOSUB 260
|
|
2310 U=U-K
|
|
2320 W=W+(Z*K)
|
|
2330 GOTO 460
|
|
2340 REM->SPDSELL
|
|
2350 HOME
|
|
2360 GOSUB 90
|
|
2370 INVERSE:PRINT" SELL SPEED ":NORMAL
|
|
2380 PRINT CHR$(10)
|
|
2390 J=T
|
|
2400 GOSUB 260
|
|
2410 T=T-K
|
|
2420 W=W+(S*K)
|
|
2430 GOTO 460
|
|
2440 REM->LUDSELL
|
|
2450 HOME
|
|
2460 GOSUB 90
|
|
2470 INVERSE:PRINT" SELL LUDES ":NORMAL
|
|
2480 PRINT CHR$(10)
|
|
2490 J=Q
|
|
2500 GOSUB 260
|
|
2510 Q=Q-K
|
|
2520 W=W+(L*K)
|
|
2530 GOTO 460
|
|
2540 REM->JET
|
|
2550 HOME
|
|
2560 GOSUB 90
|
|
2570 INVERSE:PRINT" JET ":NORMAL
|
|
2580 PRINT CHR$(10)
|
|
2590 PRINT "(B)RONX"
|
|
2600 PRINT "(G)HETTO"
|
|
2610 PRINT "(C)ENTRAL PARK
|
|
2620 PRINT "(M)ANHATTEN"
|
|
2630 PRINT "CONEY (I)SLAND"
|
|
2640 PRINT "BROO(K)LYN"
|
|
2650 PRINT "(O)OPS...STAY!"
|
|
2660 INPUT "WHERE TO DUDE? ";X$
|
|
2670 IF X$="B" THEN Y$ = "THE BRONX" : GOTO 2760
|
|
2680 IF X$="G" THEN Y$ = "THE GHETTO" : GOTO 2760
|
|
2690 IF X$="C" THEN Y$ = "CENTRAL PARK" : GOTO 2760
|
|
2700 IF X$="M" THEN Y$ = "MANHATTEN" : GOTO 2760
|
|
2710 IF X$="I" THEN Y$ = "CONEY ISLAND" : GOTO 2760
|
|
2720 IF X$="K" THEN Y$ = "BROOKLYN" : GOTO 2760
|
|
2730 IF X$="O" THEN GOTO 460
|
|
2740 GOTO 2550
|
|
2750 REM->JETB
|
|
2760 IF Y$=P$ THEN GOTO 2800
|
|
2770 P$ = Y$
|
|
2780 GOTO 2890
|
|
2790 REM->ALREADYTHERE
|
|
2800 HOME
|
|
2810 GOSUB 90
|
|
2820 INVERSE:PRINT" JET ":NORMAL
|
|
2830 PRINT CHR$(10)
|
|
2840 PRINT "YOU'RE ALREADY IN:"
|
|
2850 PRINT " ";P$
|
|
2860 GOSUB 120
|
|
2870 GOTO 2550
|
|
2880 REM->SUBWAY
|
|
2890 HOME
|
|
2900 GOSUB 340
|
|
2910 V=INT(V*1.1+.5)
|
|
2920 E=INT(E*1.06+.5)
|
|
2930 GOSUB 90
|
|
2940 INVERSE:PRINT" SUBWAY ":NORMAL
|
|
2950 PRINT CHR$(10)
|
|
2960 IF B=1 THEN GOTO 3190
|
|
2970 IF B=2 THEN GOTO 3240
|
|
2980 IF B=3 THEN GOTO 3290
|
|
2990 IF B=4 THEN GOTO 3350
|
|
3000 IF B=5 THEN GOTO 3350
|
|
3010 IF B=6 THEN GOTO 3410
|
|
3020 IF B=7 THEN GOTO 3410
|
|
3030 IF B=8 THEN GOTO 3470
|
|
3040 IF B=9 THEN GOTO 3570
|
|
3050 IF B=10 THEN GOTO 3570
|
|
3060 IF B=11 THEN GOTO 3570
|
|
3070 IF B=12 THEN GOTO 3660
|
|
3080 IF B=13 THEN GOTO 3660
|
|
3090 IF B=14 THEN GOTO 3810
|
|
3100 IF B=15 THEN GOTO 3880
|
|
3110 IF B=16 THEN GOTO 3960
|
|
3120 IF B=17 THEN GOTO 4120
|
|
3130 PRINT CHR$(10)
|
|
3140 PRINT "WELCOME TO ";P$
|
|
3150 PRINT CHR$(10)
|
|
3160 INPUT "PRESS ENTER TO CONTINUE. ";X$
|
|
3170 GOTO 460
|
|
3180 REM->CHEAPLUDES
|
|
3190 PRINT "RIVAL DEALERS ARE SELLING CHEAP LUDES!"
|
|
3200 L=2
|
|
3210 GOSUB 120
|
|
3220 GOTO 460
|
|
3230 REM->CHEEPWEED
|
|
3240 PRINT "WEED PRICES HAVE BOTTOMED-OUT!"
|
|
3250 Z=122
|
|
3260 GOSUB 120
|
|
3270 GOTO 460
|
|
3280 REM->PIGHEROIN
|
|
3290 PRINT "PIGS ARE SELLING CHEAP HEROIN"
|
|
3300 PRINT "FROM LAST WEEK'S RAID!"
|
|
3310 H=INT((RND(1)*1150)+850.5)
|
|
3320 GOSUB 120
|
|
3330 GOTO 460
|
|
3340 REM->HEROINBUST
|
|
3350 PRINT "ADDICTS ARE BUYING HEROIN"
|
|
3360 PRINT "AT OUTRAGEOUS PRICES!"
|
|
3370 H=INT((RND(1)*25000)+18000.5)
|
|
3380 GOSUB 120
|
|
3390 GOTO 460
|
|
3400 REM->COKEBUST
|
|
3410 PRINT "PIGS MADE A BIG COKE BUST!"
|
|
3420 PRINT "PRICES ARE OUTRAGEOUS!!!!"
|
|
3430 C=INT((RND(1)*60000)+80000.5)
|
|
3440 GOSUB 120
|
|
3450 GOTO 460
|
|
3460 REM->MUGGED
|
|
3470 PRINT "YOU GOT MUGGED!"
|
|
3480 PRINT CHR$(10)
|
|
3490 J=INT(W/3)
|
|
3500 J=INT(J*2)
|
|
3510 K=INT(W-J)
|
|
3520 PRINT "YOU LOST $";K
|
|
3530 W=J
|
|
3540 GOSUB 120
|
|
3550 GOSUB 460
|
|
3560 REM->COPS
|
|
3570 K=M+N+U+O+T+P
|
|
3580 IF K<50 THEN RETURN
|
|
3590 PRINT "IT'S THE COPS!"
|
|
3600 PRINT CHR$(10)
|
|
3610 PRINT "JUST KIDDING!"
|
|
3620 PRINT "COPS HAVEN'T BEEN CODED YET."
|
|
3630 GOSUB 120
|
|
3640 GOTO 460
|
|
3650 REM->GUNBUY
|
|
3660 IF W < 500 THEN RETURN
|
|
3670 F=INT(I-(M+N+O+U+T+P))
|
|
3680 IF F < 5 THEN RETURN
|
|
3690 J=INT(RND(1)*2)
|
|
3700 IF J = 0 THEN Y$ = "BARETTA"
|
|
3710 IF J = 1 THEN Y$ = "SATURDAY NIGHT SPECIAL"
|
|
3720 IF J = 2 THEN Y$ = ".44 MAGNUM"
|
|
3730 PRINT "WILL YOU BUY A ";Y$
|
|
3740 INPUT "FOR $400? (Y/N)";X$
|
|
3750 IF X$ <> "Y" THEN GOTO 460
|
|
3760 G = INT(G+1)
|
|
3770 W = INT(W-400)
|
|
3780 I = INT(I-5)
|
|
3790 GOTO 460
|
|
3800 REM->DEDWEED
|
|
3810 PRINT "THERE'S SOME WEED HERE THAT SMELLS"
|
|
3820 PRINT "LIKE GOOD STUFF!!"
|
|
3830 PRINT CHR$(10)
|
|
3840 INPUT "WILL YOU SMOKE IT? (Y/N)";X$
|
|
3850 IF X$ = "Y" THEN GOTO 5280
|
|
3860 GOTO460
|
|
3870 REM->NEWCOAT
|
|
3880 IF W<300 THEN RETURN
|
|
3890 PRINT "WILL YOU BUY A NEW TRENCHCOAT"
|
|
3900 INPUT "WITH MORE POCKETS FOR $200? (Y/N)";X$
|
|
3910 IF X$ <> "Y" THEN GOTO 460
|
|
3920 I=INT(I+10)
|
|
3930 W=INT(W-200)
|
|
3940 GOTO 460
|
|
3950 REM->DEDGUY
|
|
3960 IF F<8 THEN RETURN
|
|
3970 J=INT((RND(1)*7)+1.5)
|
|
3980 K=INT(RND(1)*5+.5)
|
|
3990 IF K=0 THEN Q=Q+J : Y$ = "LUDES"
|
|
4000 IF K=1 THEN T=T+J : Y$ = "SPEED"
|
|
4010 IF K=2 THEN U=U+J : Y$ = "WEED"
|
|
4020 IF K=3 THEN O=O+J : Y$ = "ACID"
|
|
4030 IF K=4 THEN N=N+J : Y$ = "HEROIN"
|
|
4040 IF K=5 THEN M=M+J : Y$ = "COCAINE"
|
|
4050 PRINT "YOU FOUND ";J;" UNITS OF"
|
|
4060 PRINT " ";Y$
|
|
4070 PRINT "ON A DEAD DUDE IN THE SUBWAY!"
|
|
4080 PRINT CHR$(10)
|
|
4090 GOSUB 120
|
|
4100 GOTO 460
|
|
4110 REM->HOMEACID
|
|
4120 PRINT "THE MARKET HAS BEEN FLOODED"
|
|
4130 PRINT "WITH CHEAP HOME-MADE ACID!"
|
|
4140 A=INT((RND(1)*550)+250.5)
|
|
4150 GOSUB 120
|
|
4160 GOTO 460
|
|
4170 REM->NOTBRONX
|
|
4180 PRINT "YOU NEED TO HEAD TO THE BRONX"
|
|
4190 PRINT "TO TAKE CARE OF THIS BUSINESS."
|
|
4200 GOSUB 120
|
|
4210 GOTO 460
|
|
4220 REM->LOAN
|
|
4230 HOME
|
|
4240 GOSUB 90
|
|
4250 INVERSE : PRINT " LOAN SHARK ":NORMAL
|
|
4260 PRINT CHR$(10)
|
|
4270 IF P$ <> "THE BRONX" THEN GOTO 4180
|
|
4280 PRINT "YOUR DEBT IS: $";V
|
|
4290 PRINT "YOU HAVE: $";W
|
|
4300 PRINT CHR$(10)
|
|
4310 INPUT "(R)EPAY, (B)ORROW, (L)EAVE: ";X$
|
|
4320 IF X$ = "R" THEN GOTO 4370
|
|
4330 IF X$ = "B" THEN GOTO 4460
|
|
4340 IF X$ = "L" THEN GOTO 460
|
|
4350 GOTO 4230
|
|
4360 REM->PAYME
|
|
4370 INPUT "REPAY HOW MUCH? ";K
|
|
4380 IF K>W THEN PRINT "YOU DON'T HAVE THAT MUCH!" : INPUT "PRESS ENTER TO CONTINUE. ";X$ : GOTO 4230
|
|
4390 IF K>V THEN PRINT "YOU DON'T OWE THAT MUCH!" : INPUT"PRESS ENTER TO CONTINE. ";X$ : GOTO 4230
|
|
4400 W=W-K
|
|
4410 V=V-K
|
|
4420 PRINT "THANK YOU."
|
|
4430 GOSUB 120
|
|
4440 GOTO 460
|
|
4450 REM->BORROW
|
|
4460 INPUT "HOW MUCH DO YOU WANT? ";K
|
|
4470 IF K>5000 THEN PRINT "HE'S NOT THAT STUPID!" : GOTO 4460
|
|
4480 V=V+K
|
|
4490 W=W+K
|
|
4500 PRINT "HERE'S YOUR MONEY." : PRINT CHR$(10) : PRINT "REMEMBER, I BREAK THUMBS."
|
|
4510 GOSUB 120
|
|
4520 GOTO 460
|
|
4530 REM->BANK
|
|
4540 HOME
|
|
4550 GOSUB 90
|
|
4560 INVERSE : PRINT " BANK O'MURICA ":NORMAL
|
|
4570 PRINT CHR$(10)
|
|
4580 IF P$ <> "THE BRONX" THEN GOTO 4180
|
|
4590 PRINT "YOUR BALANCE: $";E
|
|
4600 PRINT "YOUR WALLET: $";W
|
|
4610 PRINT CHR$(10)
|
|
4620 INPUT "(D)EPOSIT, (W)ITHDRAW, (L)EAVE: ";X$
|
|
4630 IF X$ = "D" THEN GOTO 4680
|
|
4640 IF X$ = "W" THEN GOTO 4760
|
|
4650 IF X$ = "L" THEN GOTO 460
|
|
4660 GOTO 4540
|
|
4670 REM->DEPOSIT
|
|
4680 INPUT "HOW MUCH? ";J
|
|
4690 IF J>W THEN PRINT "YOU DON'T HAVE THAT MUCH CASH." : GOTO 4680
|
|
4700 E=E+J
|
|
4710 W=W-J
|
|
4720 PRINT "THANK YOU FOR YOUR DEPOSIT."
|
|
4730 GOSUB 120
|
|
4740 GOTO 460
|
|
4750 REM->MYMONEY
|
|
4760 INPUT "HOW MUCH? ";J
|
|
4770 IF J>E THEN PRINT "YOU DON'T HAVE SUFFICIENT FUNDS." : GOTO 4760
|
|
4780 E=E-J
|
|
4790 W=W+J
|
|
4800 PRINT "THANK YOU FOR YOUR BUSINESS."
|
|
4810 GOSUB 120
|
|
4820 GOTO 460
|
|
4830 REM->INSTRUCTIONS
|
|
4840 HOME
|
|
4850 GOSUB 90
|
|
4860 PRINT CHR$(10)
|
|
4870 PRINT "WELCOME TO DRUGWAR//E BETA 8"
|
|
4880 PRINT CHR$(10)
|
|
4890 PRINT CHR$(10)
|
|
4900 INPUT "WOULD YOU LIKE INSTRUCTIONS? (Y/N): ";X$
|
|
4910 REM->INSERRORHANDLER
|
|
4920 IF X$ = "Y" THEN GOTO 5110
|
|
4930 GOTO 4950
|
|
4940 REM->GAMESTART
|
|
4950 W=2000
|
|
4960 E=0
|
|
4970 V=5000
|
|
4980 D=0
|
|
4990 P$="THE BRONX"
|
|
5000 G=0
|
|
5010 I=100
|
|
5020 M=0
|
|
5030 N=0
|
|
5040 O=0
|
|
5050 U=0
|
|
5060 T=0
|
|
5070 Q=0
|
|
5080 GOSUB 340
|
|
5090 GOTO 460
|
|
5100 REM->INST
|
|
5110 HOME
|
|
5120 GOSUB 90
|
|
5130 PRINT CHR$(10)
|
|
5140 PRINT "THIS IS A GAME OF BUYING AND SELLING."
|
|
5150 PRINT "YOUR GOAL IS TO PAY OFF YOUR DEBT AND"
|
|
5160 PRINT "MAKE AS MUCH MONEY AS POSSIBLE IN A ONE"
|
|
5170 PRINT "MONTH PERIOD. PRICES FLUCTUATE EVERY DAY"
|
|
5180 PRINT "AND INTEREST ON YOUR LOAN IS CALCULATED"
|
|
5190 PRINT "AS WELL. IF YOU DEAL TOO HEAVILY, YOU'LL"
|
|
5200 PRINT "ATTRACT THE ATTENTION OF THE POLICE.
|
|
5210 PRINT CHR$(10)
|
|
5220 PRINT "COMMANDS ARE USUALLY THE FIRST LETTER"
|
|
5230 PRINT "OF WHAT YOU WANT TO DO. Y = YES AND"
|
|
5240 PRINT "N = NO."
|
|
5250 INPUT "PRESS ENTER TO CONTINUE.";X$
|
|
5260 GOTO 4950
|
|
5270 REM->WEEDEND
|
|
5280 HOME
|
|
5290 GOSUB 90
|
|
5300 INVERSE : PRINT " SMOKE WEED " : NORMAL
|
|
5310 PRINT "YOU HALLUCINATE ON THE WILDEST TRIP"
|
|
5320 PRINT "OF YOUR LIFE, STUMBLE ON TO THE TRACKS,"
|
|
5330 PRINT "AND GET CREAMED BY A TRAIN!"
|
|
5340 PRINT CHR$(10)
|
|
5350 PRINT CHR$(10)
|
|
5360 PRINT "JUST SAY NO TO DRUGS!"
|
|
5370 GOSUB 120
|
|
5380 GOTO 5620
|
|
5390 REM->SCORECALCULATE
|
|
5400 K=(W+E)-V
|
|
5410 IF K<0 THEN K=0 : RETURN
|
|
5420 K=SQR((K/31.5)+.5)
|
|
5430 K=INT(K)
|
|
5440 IF K>100 THEN K=100
|
|
5450 RETURN
|
|
5460 REM->ENDGAME
|
|
5470 HOME
|
|
5480 GOSUB 90
|
|
5490 GOSUB 5400
|
|
5500 INVERSE : PRINT " GAME OVER " : NORMAL
|
|
5510 PRINT CHR$(10)
|
|
5520 PRINT "YOUR SCORE ON A SCALE OF 1 TO 100: ";K
|
|
5530 PRINT CHR$(10)
|
|
5540 INPUT "WOULD YOU LIKE TO PLAY AGAIN? (Y/N)";X$
|
|
5550 IF X$ = "Y" THEN GOTO 4950
|
|
5560 PRINT "THANKS FOR PLAYING."
|
|
5570 PRINT "REMEMBER...WATCH YOUR BACK."
|
|
5580 PRINT "HAVE A NICE DAY!"
|
|
5590 GOSUB 5800
|
|
5600 END
|
|
5610 REM->IRONICEND
|
|
5620 HOME
|
|
5630 GOSUB 90
|
|
5640 GOSUB 5400
|
|
5650 INVERSE : PRINT " GAME OVER " : NORMAL
|
|
5660 PRINT CHR$(10)
|
|
5670 PRINT "YOUR FINAL SCORE IS: ";K
|
|
5680 PRINT CHR$(10)
|
|
5690 PRINT "BUT YOU DIED FROM SMOKING WEED? IN A"
|
|
5700 PRINT "GAME ABOUT DEALING DRUGS? BUDDY, NO"
|
|
5710 PRINT "SCORE CAN REDEEM THAT STUPIDITY."
|
|
5720 PRINT CHR$(10)
|
|
5730 INPUT "WOULD YOU LIKE TO PLAY AGAIN? ";X$
|
|
5740 IF X$= "Y" THEN GOTO 4950
|
|
5750 IF X$= "N" THEN PRINT "I DON'T BLAME YOU." : END
|
|
5760 PRINT "WHAT? IF YOU'RE THAT DUMB, I'M LEAVING."
|
|
5770 GOSUB 5800
|
|
5780 END
|
|
5790 REM->ANTICHEAT
|
|
5800 W=2000
|
|
5810 E=0
|
|
5820 V=5000
|
|
5830 D=0
|
|
5840 P$="THE BRONX"
|
|
5850 G=0
|
|
5860 I=100
|
|
5870 M=0
|
|
5880 N=0
|
|
5890 O=0
|
|
5900 U=0
|
|
5910 T=0
|
|
5920 Q=0
|
|
5930 RETURN
|