You cannot select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
556 lines
16 KiB
QBasic
556 lines
16 KiB
QBasic
1 REM DRUGWAR//E BETA6
|
|
2 REM COPYRIGHT 2018 JAY MOORE
|
|
3 REM RELEASED UNDER GPL V3
|
|
4 REM 8 OCT 2018
|
|
5 REM WRITTEN IN VIRTUAL BASIC
|
|
6 REM DEVELOPED ON WINDOWS 10
|
|
7 REM AND APPLEWIN EMULATOR
|
|
8 REM DRUGWAR2E.SOURCEFORGE.IO
|
|
9 REM TWITTER: _NQ4T
|
|
10 REM DEWDUDE(AT)GMAIL
|
|
20 GOTO 4480
|
|
30 REM ->TITLEBAR
|
|
40 PRINT " DRUGWAR//E "
|
|
50 RETURN
|
|
60 REM ->WAIT
|
|
70 PRINT CHR$ (10)
|
|
80 INPUT "PRESS ENTER TO CONTINUE.";X$
|
|
90 RETURN
|
|
100 REM ->HOWMUCHBUY
|
|
110 PRINT "YOU CAN AFFORD ";J
|
|
120 PRINT "YOU CAN CARRY ";FS
|
|
130 PRINT CHR$ (10)
|
|
140 INPUT "HOW MANY? (ENTER 0 CANCEL): ";K
|
|
150 GOSUB 260
|
|
160 RETURN
|
|
170 REM ->HOWMUCHSELL
|
|
180 PRINT "YOU CAN SELL: ";J
|
|
190 PRINT CHR$ (10)
|
|
200 REM ->HOWMANYSELL
|
|
210 INPUT "HOW MANY? (ENTER 0 TO CANCEL.): ";K
|
|
220 IF K > J THEN PRINT "YOU DON'T HAVE THAT MANY!": GOTO 210
|
|
230 GOSUB 260
|
|
240 RETURN
|
|
250 REM ->NOBUYSELL
|
|
260 IF K = 0 GOTO 1810
|
|
270 RETURN
|
|
280 REM ->STATUSBAR
|
|
290 INVERSE : PRINT "DAY: ";D,P$: NORMAL
|
|
300 PRINT CHR$ (10)
|
|
310 RETURN
|
|
320 REM ->FREESPACE
|
|
330 FS = INT (IN - (CI + HI + AI + WI + SI + LI) + (GN * 5))
|
|
340 RETURN
|
|
350 REM ->DAILY
|
|
360 C = INT ( RND (1) * 12000 + 16000.5)
|
|
370 H = INT ( RND (1) * 7000 + 5000.5)
|
|
380 A = INT (( RND (1) * 34 + 10) * 100 + .5)
|
|
390 W = INT (( RND (1) * 42 + 33) * 10 + .5)
|
|
400 S = INT (( RND (1) * 15 + 7) * 10 + .5)
|
|
410 L = INT (( RND (1) * 4 + 1) * 10 + .5)
|
|
420 B = INT ( RND (1) * 20 + .5)
|
|
430 D = D + 1
|
|
440 LS = INT (LS * 1.1 + .5)
|
|
450 SA = INT (SA * 1.06 + .5)
|
|
460 REM ->CHECKDAY
|
|
470 IF D > = 31 GOTO 5070
|
|
480 RETURN
|
|
490 REM ->SUBWAYEVENTS
|
|
500 IF B = 1 THEN GOTO 690
|
|
510 IF B = 2 THEN GOTO 740
|
|
520 IF B = 3 THEN GOTO 790
|
|
530 IF B = 4 THEN GOTO 850
|
|
540 IF B = 5 THEN GOTO 850
|
|
550 IF B = 6 THEN GOTO 910
|
|
560 IF B = 7 THEN GOTO 910
|
|
570 IF B = 8 THEN GOTO 970
|
|
580 IF B = 9 THEN GOTO 1070
|
|
590 IF B = 10 THEN GOTO 1070
|
|
600 IF B = 11 THEN GOTO 1070
|
|
610 IF B = 12 THEN GOTO 1160
|
|
620 IF B = 13 THEN GOTO 1160
|
|
630 IF B = 14 THEN GOTO 1300
|
|
640 IF B = 15 THEN GOTO 1370
|
|
650 IF B = 16 THEN GOTO 1450
|
|
660 IF B = 17 THEN GOTO 1610
|
|
670 RETURN
|
|
680 REM ->CHEAPLUDES
|
|
690 PRINT "RIVAL DEALERS ARE SELLING CHEAP LUDES!"
|
|
700 L = 2
|
|
710 GOSUB 70
|
|
720 GOTO 1810
|
|
730 REM ->CHEEPWEED
|
|
740 PRINT "WEED PRICES HAVE BOTTOMED-OUT!"
|
|
750 W = 122
|
|
760 GOSUB 70
|
|
770 GOTO 1810
|
|
780 REM ->PIGHEROIN
|
|
790 PRINT "PIGS ARE SELLING CHEAP HEROIN"
|
|
800 PRINT "FROM LAST WEEK'S RAID!"
|
|
810 H = INT (( RND (1) * 1150) + 850.5)
|
|
820 GOSUB 70
|
|
830 GOTO 1810
|
|
840 REM ->HEROINBUST
|
|
850 PRINT "ADDICTS ARE BUYING HEROIN"
|
|
860 PRINT "AT OUTRAGEOUS PRICES!"
|
|
870 H = INT (( RND (1) * 25000) + 18000.5)
|
|
880 GOSUB 70
|
|
890 GOTO 1810
|
|
900 REM ->COKEBUST
|
|
910 PRINT "PIGS MADE A BIG COKE BUST!"
|
|
920 PRINT "PRICES ARE OUTRAGEOUS!!!!"
|
|
930 C = INT (( RND (1) * 60000) + 80000.5)
|
|
940 GOSUB 70
|
|
950 GOTO 1810
|
|
960 REM ->MUGGED
|
|
970 PRINT "YOU GOT MUGGED!"
|
|
980 PRINT CHR$ (10)
|
|
990 MS = INT (WA / 3)
|
|
1000 MS = INT (MS * 2)
|
|
1010 ML = INT (WA - MS)
|
|
1020 PRINT "YOU LOST $";ML
|
|
1030 WA = MS
|
|
1040 GOSUB 70
|
|
1050 GOSUB 1810
|
|
1060 REM ->COPS
|
|
1070 WE = CI + HI + WI + AI + SI + LI
|
|
1080 IF WE < 50 THEN RETURN
|
|
1090 PRINT "IT'S THE COPS!"
|
|
1100 PRINT CHR$ (10)
|
|
1110 PRINT "JUST KIDDING!"
|
|
1120 PRINT "COPS HAVEN'T BEEN CODED YET."
|
|
1130 GOSUB 70
|
|
1140 GOTO 1810
|
|
1150 REM ->GUNBUY
|
|
1160 IF WA < 500 THEN RETURN
|
|
1170 GOSUB 330
|
|
1180 IF FS < 5 THEN RETURN
|
|
1190 GX = INT ( RND (1) * 2)
|
|
1200 IF GX = 0 THEN AX$ = "BARETTA"
|
|
1210 IF GX = 1 THEN AX$ = "SATURDAY NIGHT SPECIAL"
|
|
1220 IF GX = 2 THEN AX$ = ".44 MAGNUM"
|
|
1230 PRINT "WILL YOU BUY A ";AX$
|
|
1240 INPUT "FOR $400? (Y/N)";RE$
|
|
1250 IF RE$ < > "Y" THEN GOTO 1810
|
|
1260 GN = INT (GN + 1)
|
|
1270 WA = INT (WA - 400)
|
|
1280 GOTO 1810
|
|
1290 REM ->DEDWEED
|
|
1300 PRINT "THERE'S SOME WEED HERE THAT SMELLS"
|
|
1310 PRINT "LIKE GOOD STUFF!!"
|
|
1320 PRINT CHR$ (10)
|
|
1330 INPUT "WILL YOU SMOKE IT? (Y/N)";X$
|
|
1340 IF X$ = "Y" THEN GOTO 4950
|
|
1350 RETURN
|
|
1360 REM ->NEWCOAT
|
|
1370 IF WA < 300 THEN RETURN
|
|
1380 PRINT "WILL YOU BUY A NEW TRENCHCOAT"
|
|
1390 INPUT "WITH MORE POCKETS FOR $200? (Y/N)";X$
|
|
1400 IF X$ < > "Y" THEN GOTO 1810
|
|
1410 IN = INT (IN + 10)
|
|
1420 WA = INT (WA - 200)
|
|
1430 GOTO 1810
|
|
1440 REM ->DEDGUY
|
|
1450 IF FS < 8 THEN RETURN
|
|
1460 DG = INT (( RND (1) * 7) + 1.5)
|
|
1470 XG = INT ( RND (1) * 5 + .5)
|
|
1480 IF XG = 0 THEN LI = LI + DG:SS$ = "LUDES"
|
|
1490 IF XG = 1 THEN SI = SI + DG:SS$ = "SPEED"
|
|
1500 IF XG = 2 THEN WI = WI + DG:SS$ = "WEED"
|
|
1510 IF XG = 3 THEN AI = AI + DG:SS$ = "ACID"
|
|
1520 IF XG = 4 THEN HI = HI + DG:SS$ = "HEROIN"
|
|
1530 IF XG = 5 THEN CI = CI + DG:SS$ = "COCAINE"
|
|
1540 PRINT "YOU FOUND ";DG;" UNITS OF"
|
|
1550 PRINT " ";SS$
|
|
1560 PRINT "ON A DEAD DUDE IN THE SUBWAY!"
|
|
1570 PRINT CHR$ (10)
|
|
1580 GOSUB 70
|
|
1590 GOTO 1810
|
|
1600 REM ->HOMEACID
|
|
1610 PRINT "THE MARKET HAS BEEN FLOODED"
|
|
1620 PRINT "WITH CHEAP HOME-MADE ACID!"
|
|
1630 A = INT (( RND (1) * 550) + 250.5)
|
|
1640 GOSUB 70
|
|
1650 GOTO 1810
|
|
1660 REM ->LOAN
|
|
1670 HOME
|
|
1680 GOSUB 40
|
|
1690 PRINT CHR$ (10)
|
|
1700 PRINT "LOAN SHARK NOT IMPLEMENTED.
|
|
1710 GOSUB 70
|
|
1720 GOTO 1810
|
|
1730 REM ->BANK
|
|
1740 HOME
|
|
1750 GOSUB 40
|
|
1760 PRINT CHR$ (10)
|
|
1770 PRINT "BANK NOT IMPLEMENTED."
|
|
1780 GOSUB 70
|
|
1790 GOTO 1810
|
|
1800 REM ->MENU
|
|
1810 HOME
|
|
1820 GOSUB 40
|
|
1830 GOSUB 330
|
|
1840 INVERSE : PRINT " DAY:";D;" ";PH$: NORMAL
|
|
1850 PRINT "(C)HECK PRICES"
|
|
1860 PRINT "(I)NVENTORY"
|
|
1870 PRINT "(B)UY"
|
|
1880 PRINT "(S)ELL"
|
|
1890 PRINT "(J)ET"
|
|
1900 PRINT "SEE (L)OAN SHARK"
|
|
1910 PRINT "(V)ISIT BANK"
|
|
1920 INPUT "PLEASE MAKE YOUR SELECTION: ";T$
|
|
1930 IF T$ = "C" GOTO 2030
|
|
1940 IF T$ = "I" GOTO 2170
|
|
1950 IF T$ = "B" GOTO 2310
|
|
1960 IF T$ = "S" GOTO 3180
|
|
1970 IF T$ = "J" GOTO 4020
|
|
1980 IF T$ = "L" GOTO 1670
|
|
1990 IF T$ = "V" GOTO 1740
|
|
2000 PRINT "INVALID SELECTION"
|
|
2010 GOTO 1810
|
|
2020 REM ->PRICES
|
|
2030 HOME
|
|
2040 GOSUB 40
|
|
2050 INVERSE : PRINT " PRICES ": NORMAL
|
|
2060 PRINT CHR$ (10)
|
|
2070 PRINT "COCAINE:","$"C
|
|
2080 PRINT "HEROIN:","$"H
|
|
2090 PRINT "ACID:","$"A
|
|
2100 PRINT "WEED:","$"W
|
|
2110 PRINT "SPEED:","$"S
|
|
2120 PRINT "LUDES:","$"L
|
|
2130 PRINT "WALLET:","$"WA
|
|
2140 GOSUB 70
|
|
2150 GOTO 1810
|
|
2160 REM ->INVENTORY
|
|
2170 HOME
|
|
2180 GOSUB 40
|
|
2190 INVERSE : PRINT " INVENTORY ": NORMAL
|
|
2200 PRINT CHR$ (10)
|
|
2210 PRINT "COCAINE:",CI
|
|
2220 PRINT "HEROIN:",HI
|
|
2230 PRINT "ACID:",AI
|
|
2240 PRINT "WEED:",WI
|
|
2250 PRINT "SPEED:",SI
|
|
2260 PRINT "LUDES:",LI
|
|
2270 PRINT "FREE SPACE:",FS
|
|
2280 GOSUB 70
|
|
2290 GOTO 1810
|
|
2300 REM ->BUY
|
|
2310 HOME
|
|
2320 GOSUB 40
|
|
2330 INVERSE : PRINT " BUY ": NORMAL
|
|
2340 PRINT CHR$ (10)
|
|
2350 PRINT "WHAT DO YOU WANT TO BUY?"
|
|
2360 PRINT CHR$ (10)
|
|
2370 PRINT "(C)OCAINE"
|
|
2380 PRINT "(H)EROIN"
|
|
2390 PRINT "(A)CID"
|
|
2400 PRINT "(W)EED"
|
|
2410 PRINT "(S)PEED"
|
|
2420 PRINT "(L)UDES"
|
|
2430 INPUT "ENTER SELECTION: ";DB$
|
|
2440 IF DB$ = "C" GOTO 2520
|
|
2450 IF DB$ = "H" GOTO 2630
|
|
2460 IF DB$ = "A" GOTO 2740
|
|
2470 IF DB$ = "W" GOTO 2850
|
|
2480 IF DB$ = "S" GOTO 2960
|
|
2490 IF DB$ = "L" GOTO 3070
|
|
2500 GOTO 1810
|
|
2510 REM ->COKEBUY
|
|
2520 HOME
|
|
2530 GOSUB 40
|
|
2540 INVERSE : PRINT " BUY COCAINE ": NORMAL
|
|
2550 PRINT CHR$ (10)
|
|
2560 J = INT (WA / C)
|
|
2570 GOSUB 110
|
|
2580 IF K > FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!": NORMAL : GOTO 2520
|
|
2590 IF K < = J THEN CI = CI + K:WA = WA - (C * K)
|
|
2600 IF K > J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!": NORMAL : GOTO 2520
|
|
2610 GOTO 1810
|
|
2620 REM ->HERBUY
|
|
2630 HOME
|
|
2640 GOSUB 40
|
|
2650 INVERSE : PRINT " BUY HEROIN ": NORMAL
|
|
2660 PRINT CHR$ (10)
|
|
2670 J = INT (WA / H)
|
|
2680 GOSUB 110
|
|
2690 IF K > FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!": NORMAL : GOTO 2630
|
|
2700 IF K < = J THEN HI = HI + K:WA = WA - (H * K)
|
|
2710 IF K > J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!": NORMAL : GOTO 2630
|
|
2720 GOTO 1810
|
|
2730 REM ->ACIDBUY
|
|
2740 HOME
|
|
2750 GOSUB 40
|
|
2760 INVERSE : PRINT " BUY ACID ": NORMAL
|
|
2770 PRINT CHR$ (10)
|
|
2780 J = INT (WA / A)
|
|
2790 GOSUB 110
|
|
2800 IF K > FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!": NORMAL : GOTO 2740
|
|
2810 IF K < = J THEN AI = AI + K:WA = WA - (A * K)
|
|
2820 IF K > J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!": NORMAL : GOTO 2740
|
|
2830 GOTO 1810
|
|
2840 REM ->WEEDBUY
|
|
2850 HOME
|
|
2860 GOSUB 40
|
|
2870 INVERSE : PRINT " BUY WEED ": NORMAL
|
|
2880 PRINT CHR$ (10)
|
|
2890 J = INT (WA / W)
|
|
2900 GOSUB 110
|
|
2910 IF K > FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!": NORMAL : GOTO 2850
|
|
2920 IF K < = J THEN WI = WI + K:WA = WA - (W * K)
|
|
2930 IF K > J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!": NORMAL : GOTO 2850
|
|
2940 GOTO 1810
|
|
2950 REM ->SPDBUY
|
|
2960 HOME
|
|
2970 GOSUB 40
|
|
2980 INVERSE : PRINT " BUY SPEED ": NORMAL
|
|
2990 PRINT CHR$ (10)
|
|
3000 J = INT (WA / S)
|
|
3010 GOSUB 110
|
|
3020 IF K > FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!": NORMAL : GOTO 2960
|
|
3030 IF K < = J THEN SI = SI + K:WA = WA - (S * K)
|
|
3040 IF K > J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!": NORMAL : GOTO 2960
|
|
3050 GOTO 1810
|
|
3060 REM ->LUDBUY
|
|
3070 HOME
|
|
3080 GOSUB 40
|
|
3090 INVERSE : PRINT " BUY LUDES ": NORMAL
|
|
3100 PRINT CHR$ (10)
|
|
3110 J = INT (WA / L)
|
|
3120 GOSUB 110
|
|
3130 IF K > FS THEN INVERSE : PRINT "YOU CAN'T CARRY THAT MUCH!": NORMAL : GOTO 3070
|
|
3140 IF K < = J THEN LI = LI + K:WA = WA - (L * K)
|
|
3150 IF K > J THEN INVERSE : PRINT "YOU CAN'T AFFORD THAT MUCH!": NORMAL : GOTO 3070
|
|
3160 GOTO 1810
|
|
3170 REM ->SELL
|
|
3180 HOME
|
|
3190 GOSUB 40
|
|
3200 INVERSE : PRINT " SELL ": NORMAL
|
|
3210 PRINT CHR$ (10)
|
|
3220 PRINT "WHAT WOULD YOU LIKE TO SELL?"
|
|
3230 PRINT CHR$ (10)
|
|
3240 PRINT "(C)OCAINE"
|
|
3250 PRINT "(H)EROIN"
|
|
3260 PRINT "(A)CID"
|
|
3270 PRINT "(W)EED"
|
|
3280 PRINT "(S)PEED"
|
|
3290 PRINT "(L)UDES"
|
|
3300 REM ->SELLSEL
|
|
3310 INPUT "ENTER SELECTION: (0 TO CANCEL)";DB$
|
|
3320 IF DB$ = "C" GOTO 3420
|
|
3330 IF DB$ = "H" GOTO 3520
|
|
3340 IF DB$ = "A" GOTO 3620
|
|
3350 IF DB$ = "W" GOTO 3720
|
|
3360 IF DB$ = "S" GOTO 3820
|
|
3370 IF DB$ = "L" GOTO 3920
|
|
3380 IF DB$ = "0" GOTO 1810
|
|
3390 PRINT "INVALID SELECTION!"
|
|
3400 GOTO 3310
|
|
3410 REM ->COKESELL
|
|
3420 HOME
|
|
3430 GOSUB 40
|
|
3440 INVERSE : PRINT " SELL COCAINE ": NORMAL
|
|
3450 PRINT CHR$ (10)
|
|
3460 J = CI
|
|
3470 GOSUB 180
|
|
3480 CI = CI - K
|
|
3490 WA = WA + (C * K)
|
|
3500 GOTO 1810
|
|
3510 REM ->HERSELL
|
|
3520 HOME
|
|
3530 GOSUB 40
|
|
3540 INVERSE : PRINT " SELL HEROIN ": NORMAL
|
|
3550 PRINT CHR$ (10)
|
|
3560 J = HI
|
|
3570 GOSUB 180
|
|
3580 HI = HI - K
|
|
3590 WA = WA + (H * K)
|
|
3600 GOTO 1810
|
|
3610 REM ->ACIDSELL
|
|
3620 HOME
|
|
3630 GOSUB 40
|
|
3640 INVERSE : PRINT " SELL ACID ": NORMAL
|
|
3650 PRINT CHR$ (10)
|
|
3660 J = AI
|
|
3670 GOSUB 180
|
|
3680 AI = AI - K
|
|
3690 WA = WA + (A * K)
|
|
3700 GOTO 1810
|
|
3710 REM ->WEEDSELL
|
|
3720 HOME
|
|
3730 GOSUB 40
|
|
3740 INVERSE : PRINT " SELL WEED ": NORMAL
|
|
3750 PRINT CHR$ (10)
|
|
3760 J = WI
|
|
3770 GOSUB 180
|
|
3780 WI = WI - K
|
|
3790 WA = WA + (W * K)
|
|
3800 GOTO 1810
|
|
3810 REM ->SPDSELL
|
|
3820 HOME
|
|
3830 GOSUB 40
|
|
3840 INVERSE : PRINT " SELL SPEED ": NORMAL
|
|
3850 PRINT CHR$ (10)
|
|
3860 J = SI
|
|
3870 GOSUB 180
|
|
3880 SI = SI - K
|
|
3890 WA = WA + (S * K)
|
|
3900 GOTO 1810
|
|
3910 REM ->LUDSELL
|
|
3920 HOME
|
|
3930 GOSUB 40
|
|
3940 INVERSE : PRINT " SELL COCAINE ": NORMAL
|
|
3950 PRINT CHR$ (10)
|
|
3960 J = LI
|
|
3970 GOSUB 180
|
|
3980 LI = LI - K
|
|
3990 WA = WA + (L * K)
|
|
4000 GOTO 1810
|
|
4010 REM ->JET
|
|
4020 HOME
|
|
4030 GOSUB 40
|
|
4040 INVERSE : PRINT " JET ": NORMAL
|
|
4050 PRINT CHR$ (10)
|
|
4060 PRINT "(B)RONX"
|
|
4070 PRINT "(G)HETTO"
|
|
4080 PRINT "(C)ENTRAL PARK
|
|
4090 PRINT "(M)ANHATTEN"
|
|
4100 PRINT "CONEY (I)SLAND"
|
|
4110 PRINT "BROO(K)LYN"
|
|
4120 PRINT "(O)OPS...STAY!"
|
|
4130 INPUT "WHERE TO DUDE? ";JT$
|
|
4140 IF JT$ = "B" THEN PQ$ = "THE BRONX": GOTO 4230
|
|
4150 IF JT$ = "G" THEN PQ$ = "THE GHETTO": GOTO 4230
|
|
4160 IF JT$ = "C" THEN PQ$ = "CENTRAL PARK": GOTO 4230
|
|
4170 IF JT$ = "M" THEN PQ$ = "MANHATTEN": GOTO 4230
|
|
4180 IF JT$ = "I" THEN PQ$ = "CONEY ISLAND": GOTO 4230
|
|
4190 IF JT$ = "K" THEN PQ$ = "BROOKLYN": GOTO 4230
|
|
4200 IF JT$ = "O" THEN GOTO 1810
|
|
4210 GOTO 4020
|
|
4220 REM ->JETB
|
|
4230 IF PQ$ = PH$ THEN GOTO 4270
|
|
4240 PH$ = PQ$
|
|
4250 GOTO 4360
|
|
4260 REM ->ALREADYTHERE
|
|
4270 HOME
|
|
4280 GOSUB 40
|
|
4290 INVERSE : PRINT " JET ": NORMAL
|
|
4300 PRINT CHR$ (10)
|
|
4310 PRINT "YOU'RE ALREADY IN:"
|
|
4320 PRINT " ";PH$
|
|
4330 GOSUB 70
|
|
4340 GOTO 4020
|
|
4350 REM ->SUBWAY
|
|
4360 HOME
|
|
4370 GOSUB 360
|
|
4380 GOSUB 40
|
|
4390 INVERSE : PRINT " SUBWAY ": NORMAL
|
|
4400 PRINT CHR$ (10)
|
|
4410 GOSUB 500
|
|
4420 PRINT CHR$ (10)
|
|
4430 PRINT "WELCOME TO ";PH$
|
|
4440 PRINT CHR$ (10)
|
|
4450 INPUT "PRESS ENTER TO CONTINUE. ";X$
|
|
4460 GOTO 1810
|
|
4470 REM ->INSTRUCTIONS
|
|
4480 HOME
|
|
4490 GOSUB 40
|
|
4500 PRINT CHR$ (10)
|
|
4510 PRINT "WELCOME TO DRUGWAR//E"
|
|
4520 PRINT CHR$ (10)
|
|
4530 PRINT CHR$ (10)
|
|
4540 INPUT "WOULD YOU LIKE INSTRUCTIONS? (Y/N): ";Q$
|
|
4550 REM ->INSERRORHANDLER
|
|
4560 IF Q$ = "Y" THEN GOTO 4780
|
|
4570 IF Q$ = "N" THEN GOTO 4610
|
|
4580 INPUT "I DON'T UNDERSTAND YOU. Y OR N ONLY. ";Q$
|
|
4590 GOTO 4560
|
|
4600 REM ->GAMESTART
|
|
4610 WA = 2000
|
|
4620 SA = 0
|
|
4630 LS = 5000
|
|
4640 D = 0
|
|
4650 PH$ = "THE BRONX"
|
|
4660 GN = 0
|
|
4670 DP = 0
|
|
4680 IN = 100
|
|
4690 CI = 0
|
|
4700 HI = 0
|
|
4710 AI = 0
|
|
4720 WI = 0
|
|
4730 SI = 0
|
|
4740 LI = 0
|
|
4750 GOSUB 360
|
|
4760 GOTO 1810
|
|
4770 REM ->INST
|
|
4780 HOME
|
|
4790 GOSUB 40
|
|
4800 PRINT CHR$ (10)
|
|
4810 PRINT "THIS IS A GAME OF BUYING AND SELLING."
|
|
4820 PRINT "YOUR GOAL IS TO PAY OFF YOUR DEBT AND"
|
|
4830 PRINT "MAKE AS MUCH MONEY AS POSSIBLE IN A ONE"
|
|
4840 PRINT "MONTH PERIOD. PRICES FLUCTUATE EVERY DAY"
|
|
4850 PRINT "AND INTEREST ON YOUR LOAN IS CALCULATED"
|
|
4860 PRINT "AS WELL. IF YOU DEAL TOO HEAVILY, YOU'LL"
|
|
4870 PRINT "ATTRACT THE ATTENTION OF THE POLICE.
|
|
4880 PRINT CHR$ (10)
|
|
4890 PRINT "COMMANDS ARE USUALLY THE FIRST LETTER"
|
|
4900 PRINT "OF WHAT YOU WANT TO DO. Y = YES AND"
|
|
4910 PRINT "N = NO."
|
|
4920 INPUT "PRESS ENTER TO CONTINUE.";X$
|
|
4930 GOTO 4610
|
|
4940 REM ->WEEDEND
|
|
4950 HOME
|
|
4960 GOSUB 40
|
|
4970 INVERSE : PRINT " SMOKE WEED ": NORMAL
|
|
4980 PRINT "YOU HALLUCINATE ON THE WILDEST TRIP"
|
|
4990 PRINT "OF YOUR LIFE, STUMBLE ON TO THE TRACKS,"
|
|
5000 PRINT "AND GET CREAMED BY A TRAIN!"
|
|
5010 PRINT CHR$ (10)
|
|
5020 PRINT CHR$ (10)
|
|
5030 PRINT "JUST SAY NO TO DRUGS!"
|
|
5040 GOSUB 70
|
|
5050 GOTO 5210
|
|
5060 REM ->ENDGAME
|
|
5070 HOME
|
|
5080 GOSUB 40
|
|
5090 INVERSE : PRINT " GAME OVER ": NORMAL
|
|
5100 PRINT CHR$ (10)
|
|
5110 PRINT "THANKS FOR PLAYING."
|
|
5120 PRINT "AT THIS POINT I'M SUPPOSLISTED TO CALCULATE"
|
|
5130 PRINT "YOUR FINAL SCORE AND ALL THAT. BUT THIS"
|
|
5140 PRINT "IS AN ALPHA RELEASE. SO IT'S NOT DONE."
|
|
5150 PRINT CHR$ (10)
|
|
5160 PRINT "AT LEAST YOU DIDN'T DIE FROM SMOKING"
|
|
5170 PRINT "THAT WEED IN THE SUBWAY. GOOD JOB."
|
|
5180 GOSUB 5320
|
|
5190 END
|
|
5200 REM ->IRONICEND
|
|
5210 HOME
|
|
5220 GOSUB 40
|
|
5230 INVERSE : PRINT " GAME OVER ": NORMAL
|
|
5240 PRINT CHR$ (10)
|
|
5250 PRINT "OH WOW MAN. YOU DIED...FROM SMOKING POT"
|
|
5260 PRINT "IN A GAME ABOUT DRUG DEALING."
|
|
5270 PRINT CHR$ (10)
|
|
5280 PRINT "WELL, THANKS FOR PLAYING."
|
|
5290 GOSUB 5320
|
|
5300 END
|
|
5310 REM ->ANTICHEAT
|
|
5320 WA = 2000
|
|
5330 SA = 0
|
|
5340 LS = 5000
|
|
5350 D = 0
|
|
5360 PH$ = "THE BRONX"
|
|
5370 GN = 0
|
|
5380 DP = 0
|
|
5390 IN = 100
|
|
5400 CI = 0
|
|
5410 HI = 0
|
|
5420 AI = 0
|
|
5430 WI = 0
|
|
5440 SI = 0
|
|
5450 LI = 0
|
|
5460 RETURN
|